Discussion :

[hichem94120]

Bonjour,

Voila, après moult essais infructueux, je commence à tourner en rond. J'essaye enfaite, d'élaborer une formule sous Excel laquelle doit :

1. Calculer un nombre de jours en faisant une différence de dates (en prenant en compte un facteur d'achèvement de la tâche (en cours, a commencer...))

2. Retourner une chaine de caractère genre 20 JOURS pour les tâches étant à 20 jours de leur échéance.

J'ai donné trois niveaux de plage temporelle ]- inf; 3] ; ]3;7] et ]7;20].
Voici la formule on ne peut moins bancale que j'ai réalisé :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=ET(SI(ET(7<$D2-AUJOURDHUI();$D2-AUJOURDHUI()<=20;OU($F2="En cours";$F2="A commencer";$F2="A venir")); "20 JOURS"; ""); SI(ET(3<$D2-AUJOURDHUI();$D2-AUJOURDHUI()<=7;OU($F2="En cours";$F2="A commencer";$F2="A venir")); "7 JOURS"; ""); SI($D2-AUJOURDHUI()<=3; "ECHEANCE"; ""))

Comme vous vous en doutez, cette formule ne me renvoi pas le résultat que j'attends. Merci d'avance pour vos aides!

[yanistelo]

salut,
si je comprends bien tu veux faire apparaitre dans ta formule aussi bien le résultat que du texte.
je te propose ceci

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=(ANNEE(AUJOURDHUI())-ANNEE(A1)&" jours"&" "&SI(ANNEE(AUJOURDHUI())-ANNEE(A1)>10;"terminé";"continuer"))

sinon envoie ton fichier je regarderai

[hichem94120]

Salut,

Merci pour ta réponse, mais elle ne prend pas en compte plusieurs critères que je recherche. J'ai encore essayé d'optimiser ma formule mais toujours pas satisfaisant :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=ET(OU($F3="En cours";$F3="A commencer";$F3="A venir");OU(SI(7<$I3&$I3<=20;$I3&" "&"jours";" ");SI(3<$I3&$I3<=7;$I3&" "&"jours";" ");SI($I3<=3;$I3&" "&"jours"&"ATTENTION";" ")))

En gros je vais chercher dans F3 si l'état est en cours, a venir ou a commencer.
Si le premier critère est satisfait, je vais chercher dans I3 une valeur correspond à une différence de date et en fonction de son appartenance à l'un des trois interval définit, une réponse en conséquence est renvoyée.

Interval:
7<x<=20
3<x<=7
x<=3

Au final, Excel me sort une erreur #VALEUR?

Une idées?

[carden752]

Bonjour,

C'est normal que tu es un #valeur, la valeur retournée dans tes OU correspond pas à une valeur binaire.

Il te faut donc commencer par un si suivi de ton ET selon la condition.
J'ai fait le cas inférieur à 3, bon courage pour le reste.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
 
=SI(ET(OU($F3="A commencer";$F3="A venir");$I3<=3);$I3&" "&"jours"&" "&"ATTENTION";"Cas > 3")

Cordialement,
Christophe

[hben1961]

Bonjour à tous,

Essayes avec la formule suivante:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=SI(ET($D2-AUJOURDHUI()>7;$D2-AUJOURDHUI()<=20;OU($F2="En cours";$F2="A commencer";$F2="A venir"));"20 JOURS";SI(ET($D2-AUJOURDHUI()>3;$D2-AUJOURDHUI()<=7;OU($F2="En cours";$F2="A commencer";$F2="A venir"));"7 JOURS";SI($D2-AUJOURDHUI()<=3;"ECHEANCE";"")))

Ou plus simple :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=SI($D2-AUJOURDHUI()<=3;"ECHEANCE";SI(OU($F2="En cours";$F2="A commencer";$F2="A venir");SI($D2-AUJOURDHUI()<=7;"7 JOURS";SI($D2-AUJOURDHUI()<=20;"20 JOURS";""))))

Cordialement

[hichem94120]

Hello,

Merci beaucoup pour vos réponses.

carden752, merci pour le commentaire concernant la syntaxe, ça me permettra de ne plus refaire l'erreur.

hben1961, merci énormément, la réponse est nickel.

Bonne continuation à tous.