Discussion :

[chris_chrolls]

Bonjour,

j'aimerais faire un système de recherche pour un tableau.
Le but est de faire une recherche d'une valeur dans une colonne précise et ensuite remonter les informations de la ligne dans un formulaire.

Pour le moment je bug dans la recherche voici mon code :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
 
Private Sub CommandButton1_Click()
 
'Déclaration des variables'
Dim RechercheTrouve As Range
Dim Résultat As Variant
 
'Activation de la feuille Suivi_2010'
Worksheets("Suivi_2010").Activate
Range("C2").Activate
'On donne une valeur a la variable résultat'
Résultat = TextBox1.Value
 
Set RechercheTrouve = Cells.Find(What:=Résultat, After:=ActiveCell, LookIn:=xlValues, LookAt:= _
                                            xlWhole, SearchOrder:=xlByColumns, SearchDirection:=xlNext, MatchCase:= _
                                            False, SearchFormat:=False).Activate
 
'Si la recherche est négatif, un messagebox previent'
If RechercheTrouve Is Nothing Then
MsgBox "Le numéro d'OS n'existe pas", vbCritical
Else
Cells.Find(What:=Résultat).Activate
End If
 
End Sub

Si je retire le .Activate au find, il ne recherche pas dans la colonne souhaiter.

Merci d'avance pour votre aide.

[Golork]

Regarde dans l'aide de vba !
-> sélectionne avec ta souris "Cells.Find" dans ton éditeur et appuie sur "F1".

[mercatog]

Je ferai comme ceci

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
Private Sub CommandButton1_Click()
Dim RechercheTrouve As Range
Dim Lig As Long
 
With Worksheets("Suivi_2010")
    If Me.TextBox1.Value <> "" Then
        Set RechercheTrouve = .Range("C:C").Find(Me.TextBox1.Value, LookIn:=xlValues, LookAt:=xlWhole)
        If RechercheTrouve Is Nothing Then
            MsgBox "Le numéro d'OS n'existe pas", vbCritical
        Else
            Lig = RechercheTrouve.Row 'La ligne trouvée
            MsgBox Lig
            'suite du code avec lig
        End If
    End If
End With
End Sub

[chris_chrolls]

Merci Mercatog ca fonctionne.
J'arrive a récupérer le numéro de la ligne de ma recherche.


Allez il me reste plus cas rechercher toutes les informations de cette ligne dans mon ancien userform (un formulaire)