Discussion :

[Berzerk_]

Bonjour,

J'essaie de changer les couleurs des bulles d'un graphique en fonction des valeurs stockées dans un tableau dans un autre onglet.
Je souhaite que les couleurs s'actualisent dès que je sélectionne l'onglet porteur du graphique.

J'utilise le code suivant :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
Private Sub Worksheet_Activate()
'
' Worksheet_Activate Macro
' Macro enregistrée le 26/08/2010 par ***
'
 
' Cette Macro change la couleur des bulles du graphique en fonction du paramètre risque sélectionné
 
    Set Opportunite = 0
    Dim Risque As Integer
    Dim MaCellule As Range
 
    For Each MaCellule In Select_Evaluation.Range("AG5:AG16")
        Risque = MaCellule.Value
 
        .ChartObjects("Chart 1").Activate 'Sélection du graphique
        ActiveChart.SeriesCollection(Opportunite).Select 'Sélection de la bulle correspondant au scénario
 
        With Selection.Interior
             Select Case Risque 'Choix de la couleur
                 Case 1
                     .ColorIndex = 4
                 Case 2
                     .ColorIndex = 45
                 Case 3
                     .ColorIndex = 3
                 Case Else
                     .ColorIndex = 1
             End Select
             .PatternColorIndex = 2
             .Pattern = xlSolid
         End With
 
         Opportunite = Opportunite + 1
 
    Next
 
End Sub

Deux problèmes:

• Lorsque j'associe cette macro à un onglet "normal", la macro est bien lancée dès que je sélectionne l'onglet, mais m'affiche un message d'erreur :

  Erreur de compilation : Objet requis

• Lors que j'associe cette macro à l'onglet graphique, la macro ne se lance pas lorsque je sélectionne l'onglet.

Pourriez-vous m'aider à résoudre ce problème ?

Merci d'avance,
Fabrice.

[mercatog]

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Set Opportunite = 0

syntaxe bizarre
F1 sur Set

Set, instruction


Attribue une référence d'objet à une variable ou à une propriété.

Je propose
déclare toutes tes variables convenablement (Opportunité est un integer, enlève la ligne avec le fameux Set)

[Berzerk_]

Merci beaucoup, cela répond à mon premier point.

Par contre ma macro refuse toujours de s'exécuter lorsqu'elle est associée à un onglet de type graphique.

[mercatog]

au lieu de

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Private Sub Worksheet_Activate()

mets

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Private Sub Chart_Activate()

PS

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

        .ChartObjects("Chart 1").Activate 'Sélection du graphique

j'ai des doutes sur cette ligne; la ChartObject se rapporte à quoi?

[Berzerk_]

Merci pour la correction, maintenant la macro se lance.

Mais tu as raison d'avoir un doute sur

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

.ChartObjects("Chart 1").Activate 'Sélection du graphique

parce que ça ne passe pas.

Comme l'indique le commentaire, j'essaie de sélectionner le graphique présent sur cet onglet, puis à la ligne suivante de sélectionner la bulle dont je souhaite modifier la couleur.

[mercatog]

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
Private Sub Chart_Activate()
Dim Opportunite As Integer
Dim Risque As Double
Dim MaCellule As Range
 
Application.ScreenUpdating = False
For Each MaCellule In Select_Evaluation.Range("AG5:AG16")
    Opportunite = Opportunite + 1
    Risque = MaCellule.Value
    With ActiveChart.SeriesCollection(1).Points(Opportunite).Interior     'Sélection de la bulle correspondant au scénario
        Select Case Risque                            'Choix de la couleur
            Case 1
                .ColorIndex = 4
            Case 2
                .ColorIndex = 45
            Case 3
                .ColorIndex = 3
            Case Else
                .ColorIndex = 1
        End Select
        .PatternColorIndex = 2
        .Pattern = xlSolid
    End With
Next MaCellule
End Sub

[Didier Gonard]

Bonjour,

Berzerk, vois dans l'aide VBA la distinction entre Sheets et WorkSheets (collections), c'est essentiel et souvent méconnu.

cordialement,

Didier

[Berzerk_]

mercatog, j'ai appliqué tes recommandations comme ceci :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
Private Sub Chart_Activate()
'
' Worksheet_Activate Macro
' Macro enregistrée le 26/08/2010 par ***
'
 
' Cette Macro change la couleur des bulles du graphique en fonction du paramètre risque sélectionné
    MsgBox "Lancement"
 
    Dim Opportunite As Integer
    Dim Risque As Integer
    Dim MaCellule As Range
 
    Application.ScreenUpdating = False
 
    For Each MaCellule In Select_Evaluation.Range("AG5:AG16")
        Opportunite = Opportunite + 1
        Risque = MaCellule.Value
 
        With ActiveChart.SeriesCollection(1).Points(Opportunite).Interior 'Sélection de la bulle correspondant au scénario
             Select Case Risque 'Choix de la couleur
                 Case 1
                     .ColorIndex = 4
                 Case 2
                     .ColorIndex = 45
                 Case 3
                     .ColorIndex = 3
                 Case Else
                     .ColorIndex = 1
             End Select
             .PatternColorIndex = 2
             .Pattern = xlSolid
         End With
 
    Next MaCellule
 
    MsgBox "Fin"
End Sub

Mais j'ai toujours une erreur

Erreur de compilation : Objet requis

qui apparemment se produit à la ligne "For Each MaCellule In Select_Evaluation.Range("AG5:AG16")"


Ormonth, de ce que je comprends de l'aide, Sheet est plus générique que WorkSheets, puisqu'il englobe ce type.
Donc est-ce que j'utilise Worksheets par défaut dans tous les cas ou est-ce qu'il y a un intérêt à spécifier ?

[mercatog]

C'est quoi ton Select_Evaluation?
c'est le nom de ta feuille ou son codename
peut être remplace la ligne en question par

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

For Each MaCellule In Sheets("Select_Evaluation").Range("AG5:AG16")

[Berzerk_]

C'est quoi codename ? On peut donner un nom de code à un onglet ?
C'est pratique, ça m'éviterait de modifier le code VBA à chaque fois que je renomme un onglet !

Select_Evaluation est le nom de l'onglet (celui qui apparaît en bas de la fenêtre Excel).

J'ai appliqué ta modification et maintenant j'ai une erreur à la ligne

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

With ActiveChart.SeriesCollection(1).Points(Opportunite).Interior

Il me dit :

Paramètre non valide

Edit : Je crois que j'ai compris, ta formule me fait parcourir une série, mais il me semble que j'ai une bulle par série. Je vais essayer de la modifier.

Edit bis : C'était bien ça, j'avais juste à permuter "Opportunite" et '1'. Merci à vous deux pour votre aide !

[Didier Gonard]

Ormonth, de ce que je comprends de l'aide, Sheet est plus générique que WorkSheets, puisqu'il englobe ce type.
Donc est-ce que j'utilise Worksheets par défaut dans tous les cas ou est-ce qu'il y a un intérêt à spécifier ?

Il y a toujours intérêt à spécifier, la preuve, ça t'a mis sur la piste d'un problème, mais en toute connaissance de cause, on peut avoir à traiter le collection générale..

cordialement,

Didier