Discussion :

[NEC14]

Bonjour à tous,

Dans un fichier j'ai 2 feuilles de calcul. La première est nommée "Général" et la 2ème "Détail".
Dans la cellule A2 de détail je tape "P" ou "C" ou toute autre lettre dont j'aurai besoin.
Cette lettre correspond à une donnée saisie dans la feuille "Général" dans la colonne "G".
A partir de là, je souhaiterai que les informations qui sont sur la même ligne de la feuille "Général" soient rapatriées à partir de la colonne A de la feuille "Détail" et cela à chaque fois que l'on trouve "P" dans la colonne "G".
Les cinqs premières colonnes de la feuille "Général" correspondent aux cinqs premières colonnes de "Détail" (A pour A, B pour B, etc.). La colonne I de Général doit être en G de Détail, J dans H, L dans J et M dans K.
Si il y a 10 fois "P" dans la colonne "G", alors se créent 10 lignes dans la feuille "Détail".
J'espère avoir été clair sinon n'hésitez pas à me le dire.
J'ai cherché une formule Excel mais sans succés, donc je me rabat sur Vba.
Merci par avance pour votre aide

[mercatog]

Si tu as des entêtes de ligne, utilise un filtrage
ci joint proposition à mettre dans Change de feuille Détail

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
Private Sub Worksheet_Change(ByVal Target As Range)
Dim LastLig As Long, NewLig As Long, Nb As Long
If Target.Address = "$A$2" Then
   If Target <> "" Then
      With Sheets("Général")
         LastLig = .Cells(Rows.Count, "G").End(xlUp).Row
         With .Range("A1:M" & LastLig)
            .AutoFilter
            .AutoFilter field:=7, Criteria1:=Target
         End With
         Nb = .Range("A1:A" & LastLig).SpecialCells(xlCellTypeVisible).Count - 1
         If Nb > 0 Then
            NewLig = Cells(Rows.Count, "A").End(xlUp).Row + 1
            Range("A" & NewLig & ":E" & NewLig + Nb - 1).Value = .Range("A2:E" & LastLig).SpecialCells(xlCellTypeVisible).Value
            Range("G" & NewLig & ":H" & NewLig + Nb - 1).Value = .Range("I2:J" & LastLig).SpecialCells(xlCellTypeVisible).Value
            Range("J" & NewLig & ":K" & NewLig + Nb - 1).Value = .Range("L2:M" & LastLig).SpecialCells(xlCellTypeVisible).Value
         End If
         .Range("A1").AutoFilter
      End With
   End If
End If
End Sub

[NEC14]

Bonjour mercatog et merci ton code est exactement ce que je voulais faire.
Cependant, lorsque qu'il n'y a plus de lettre en A2 les données ne s'effacent pas.
Il est vrai que je ne l'ai pas précisé dans ma demande.
Comment dois-je procéder ?
Merci par avance

[mercatog]

C'est à dire?
quand A2 est vide, ta feuille détail doit se vider?

[NEC14]

Oui c'est ça. Lorsque j'efface le "P" en A2, le tableau se vide.
Tout simplement si je tape une autre lettre que "P", il ne faut que les données suivantes s'affichent en plus mais les remplacent.

Si je ne suis pas clair dis le moi

J'ai fais ce code avec l'éditeur de macro, mais vous en conviendrez ce n'est pas joli.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
    Range("A2").Select
'je supprime le contenu de A2
    Selection.ClearContents
'je sélectionne une série de cellule et je les efface
    Range("A4:H300").Select
    Selection.ClearContents
    Range("J4:K300").Select
    Selection.ClearContents
' je me positionne en A3
    Range("A3").Select

[mercatog]

Il fallait le dire dès le départ, nulle part! vu ton nombre de participations, je crois qu'il faut changer de méthode. au stade de nettoyer l'enregistreur de macro devrait être déjà franchi; mais bon!
ci-joint

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
Private Sub Worksheet_Change(ByVal Target As Range)
Dim LastLig As Long, NewLig As Long, Nb As Long
If Target.Address = "$A$2" Then
   Rows(3 & ":" & Rows.Count).ClearContents
   If Target <> "" Then
      With Sheets("Général")
         LastLig = .Cells(Rows.Count, "G").End(xlUp).Row
         With .Range("A1:M" & LastLig)
            .AutoFilter
            .AutoFilter field:=7, Criteria1:=Target
         End With
         Nb = .Range("A1:A" & LastLig).SpecialCells(xlCellTypeVisible).Count - 1
         If Nb > 0 Then
            Range("A3:E" & Nb + 2).Value = .Range("A2:E" & LastLig).SpecialCells(xlCellTypeVisible).Value
            Range("G3:H" & Nb + 2).Value = .Range("I2:J" & LastLig).SpecialCells(xlCellTypeVisible).Value
            Range("J3:K" & Nb + 2).Value = .Range("L2:M" & LastLig).SpecialCells(xlCellTypeVisible).Value
         End If
         .Range("A1").AutoFilter
      End With
   End If
End If
End Sub