Discussion :

[drjacky]

Bonjour,

J'ai un classeur Excel auquel est attachée une barre d'outils X.
Lorsque je passe d'un environnement à un autre, càd quand je change de PC, le barre X ne s'affiche plus ou alors partiellement (il manque la quasi-totalité des boutons...)
Je suis obligé de la refaire pour chaque ordinateur où est utilisée mon application...

Y'a t-il une manoeuvre quelconque à faire pour éviter ce désagrément ?

D'avance merci !

Etienne

[meud007]

Tu peux créer une macro complémentaire (barre.xla) qui vérifie la présence de ta barre d'outils, et si besoin, la recrée ou ajoute les boutons manqants.
Tu installes cette macro sur les postes concernés.
Un exemple que j'utilise pour mes applis.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
Private Sub Workbook_Open()
 
    Controlebarre
 
End Sub

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
Private Sub Controlebarre()
 
 
    Dim MaBarre As CommandBar, MonMenu As CommandBarPopup, MonBouton As CommandBarControl
 
        On Error Resume Next
            Set MaBarre = Application.CommandBars("Macros Personnelles")
        On Error GoTo 0
 
        If MaBarre Is Nothing Then Set MaBarre = Application.CommandBars.Add(Name:="Macros personnelles")
        MaBarre.Visible = True
 
        Set MonMenu = MaBarre.FindControl(Type:=msoControlPopup, Tag:="Macros disponibles")
        If MonMenu Is Nothing Then Set MonMenu = MaBarre.Controls.Add(Type:=msoControlPopup)
        With MonMenu
            .Tag = "Macros disponibles"
            .Caption = "Macros disponibles"
        End With
 
        Set MonBouton = MaBarre.FindControl(Type:=msoControlButton, Tag:="Gestion", recursive:=True)
        If MonBouton Is Nothing Then Set MonBouton = MonMenu.Controls.Add(Type:=msoControlButton)
        With MonBouton
            .FaceId = 2174
            .Tag = "Gestion"
            .Caption = "Quantification et Gestion des CQs"
            .OnAction = "AppelBoites.Importation"
        End With
 
        Set MonBouton = MaBarre.FindControl(Type:=msoControlButton, Tag:="Manuel", recursive:=True)
        If MonBouton Is Nothing Then Set MonBouton = MonMenu.Controls.Add(Type:=msoControlButton)
        With MonBouton
            .FaceId = 1952
            .Tag = "Manuel"
            .Caption = "Saisie manuelle et Gestion des CQs"
            .OnAction = "AppelBoites.Manuelle"
        End With
 
 
        Set MonBouton = Nothing
        Set MonMenu = Nothing
        Set MaBarre = Nothing
 
End Sub

A adapter, évidement...

[drjacky]

Merci de ta réponse rapide !

J'adapte ça et je te tiens au courant.

Etienne