Discussion :

[Shikam]

Bonjour,

J'ai essayé pas mal de truc mais la je sèche

Le principe est simple, j'ai 2 colonnes

2 1
3 2
5 9
6 11
9 14


Il faut savoir si chaque valeur de la cellule de la colonne 1 est contenu dans la colonne 2, si ce n'est pas dans la colonne 2 alors supprimé la ligne, le résultat que ça doit me donner pour l'exemple est le suivant

2 1
9 14

Voila ce que j'ai essayé

Private Sub Comparer2()

NbLigne1 = Sheets("Feuil1").UsedRange.Rows.Count
Nb = NbLigne1
Nb2 = Nb
For k = Nb To 1 Step -1
ValeurA = Cells(k, 1).Value
a = 0
For g = 1 To Nb
ValeurB = Cells(g, 2).Value
If ValeurA <> ValeurB Then
a = a + 1
End If
Next g
If a = Nb2 Then
Rows(k).Delete
Nb2 = Nb2 - 1
End If
Next k



End Sub

[sabzzz]

bonjour Shikam,

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
Sub Comparer2()
Dim tb(), i As Integer, x As Integer, y As Integer, a As Integer
x = Range("A65536").End(xlUp).Row
 
  For i = 1 To x
    If IsError(Application.Match(Range("A" & i), Range("B:B"), 0)) Then
      ReDim Preserve tb(y)
      tb(y) = i
      y = y + 1
    End If
 Next
 
 For a = UBound(tb) To LBound(tb) Step -1
    Rows(tb(a)).Delete
 Next
 
End Sub

[Shikam]

Merci ça marche niquel, par contre je comprend pas trop, est -il possible de commenter ce bout de codes?

[sabzzz]

bonjour Shikam,

voilà,

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
Sub Comparer2()
Dim tb(), i As Integer, x As Integer, y As Integer, a As Integer
'x sera = au numéro de ligne de la derniere cellule renseigné de la colonne A
x = Range("A65536").End(xlUp).Row
 
  For i = 1 To x
'Match est l'équivalent vba  de la fonction EQUIV de la feuille de calcul
'on vérifie que la fonction ne retourne pas une valeur d'erreur
'exactement comme le fait la fonction ESTERREUR de la feuille de calcul
    If IsError(Application.Match(Range("A" & i), Range("B:B"), 0)) Then
'redimentionner le tableau tb à la valeur y, le premier item d'un tableau de
' variable commence toujours à 0, si on prévoi 10 items ce sera de 0 à 9
      ReDim Preserve tb(y)
'inscrire dans le tabeau le numéro de ligne i trouvé
      tb(y) = i
      y = y + 1
    End If
 Next
 'pour toutes les valeurs du tableau tb en commancant par la derniere jusqu'a la premiere 
'U pour "Up" et L pour "Low" donc borne supérieur et borne inférieur
 For a = UBound(tb) To LBound(tb) Step -1
'effacer le numéro de ligne inscrit dans le tableau
    Rows(tb(a)).Delete
 Next
 
End Sub

[Shikam]

Merci c'est parfait