Discussion :

[Djohn]

Bonjour,

Je possede un tableau constitué d'une unique colonne A, avec une centaine de ligne
une boucle se charge de stocker chaque element dans une variable String.

Mon objectif est de stocker chaque element, sauf si l'element y est deja présent.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
 
Dim Stock As String
Dim n As Integer
n = 1
 
While Cells(n, 1) <> ""
' il faudrait ici creer un controle qui vérifie si l'élement contenu 
' dans la  cellule est déja apparu dans la colonne
Stock = Stock & ";" & Cells(n, 1)
n = n+1
Wend

si vous avez une idée pas trop lourde a mettre en place, et surtout sans faire de filtre préalablement.
Merci

[mercatog]

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
Sub test()
Dim LastLig As Long, j As Long
Dim Kol As New Collection
Dim Stock  As String
 
LastLig = Cells(Rows.Count, "A").End(xlUp).Row
For j = 1 To LastLig
    On Error Resume Next
    Kol.Add Range("A" & j).Value, CStr(Range("A" & j).Value)
Next j
 
For j = 1 To Kol.Count
    Stock = Stock & ";" & Kol.Item(j)
Next j
Stock = Mid(Stock, 2)
MsgBox Stock
End Sub

[JPierreM]

Un autre essai avec Dictionary

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
 
Sub sc()
Dim mondico As Object
Dim cellule As Range
Dim temp As Variant
Dim alitems As Variant
Dim i
 
    Set mondico = CreateObject("Scripting.Dictionary")
        For Each cellule In Range([A2], [A65536].End(xlUp))
            mondico.Item(cellule.Value) = cellule.Value
        Next cellule
 
    alitems = mondico.Items
 
        For i = 0 To UBound(alitems)
            temp = temp & alitems(i) & ", "
        Next i
 
    [D2] = temp
 
End Sub

[pgz]

Bonjour.

Une autre idée

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
Dim Stock As String
Dim n As Integer
n = 1
 
While Cells(n, 1) <> ""
    if not stock like "*;" & cells(n,1) & "*" Then Stock = Stock & ";" & Cells(n, 1)
n = n+1
Wend
Stock = mid$(stock,2)

Cordialement,

PGZ

[Djohn]

merci bcp,
par curiosité, j'ai testé tous les codes, et ca ma permis d'apprendre des choses interessantes.
j'ai finalement retenu le code de PGZ (le plus court

merci