Discussion :

[Albatros47]

Bonsoir à tous,

Lorsque j'effectue une saisie, les données interventions sont écrites sur la Feuille "Données" et l'intervenant et ses heures sur la feuille "heures".

Lorsque j'effectue une nouvelle saisie d'intervention le même jour, je voudrai éviter les doublons sur la feuille "Heures" pour un même intervenant.

Merci d'avance pour le coup de main.

JL

[Pierre Fauconnier]

Bonjour

On imagine tes données en A pour les travailleurs et en B pour l'heure de début d'intervention.

On va intercepter le changement de valeur dans une cellule et vérifier que cette cellule appartient à une des colonnes A ou B

On va mémoriser dans deux variables les valeurs des cellules en A et B pour la ligne considérée

On va utiliser SOMMEPROD en VBA et voir si cette fonction renvoie un nombre > 1 => déjà saisi

Si déjà saisi, on annule

Pour éviter un code risquant de boucler, on désactive la gestion d'évènements, et on la remet en fin de macro.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
Private Sub Worksheet_Change(ByVal Target As Range)
  If Not Intersect(Target, Range("a:b")) Is Nothing Then VerifierDoublons Target
End Sub
 
Sub VerifierDoublons(Target As Range)
  Dim Plage1 As String
  Dim Plage2 As String
  Dim Travailleur As String
  Dim Heure As Date
 
  On Error GoTo Fin
 
  Application.EnableEvents = False
 
  If Target.Cells.Count = 1 Then
    Plage1 = Range("a2:a" & Range("a" & Rows.Count).End(xlUp).Row).Address
    Plage2 = Range("b2:b" & Range("a" & Rows.Count).End(xlUp).Row).Address
    Travailleur = Range("a" & Target.Row)
    Heure = Range("b" & Target.Row)
    If Evaluate("sumproduct((" & Plage1 & "=""" & Travailleur & """)*(" & Plage2 & "=" & Heure * 1 & "))") > 1 Then
      MsgBox "Déjà saisi"
      Application.Undo
    End If
  End If
 
Fin:
  Application.EnableEvents = True
End Sub

[EDIT] J'ai oublié de préciser que ce code se place dans le module de la feuille considérée [EDIT]

[Albatros47]

Bonsoir,

Merci pour le coup de main, il ne me reste plus qu'a mettre en application.

A plus sur le forum