Discussion :

[albibak]

Bonjour,

Tout d'abord, je ne sais pas du tout faire de macro Excel. Voilà, le décor est planté.

Sinon, je cherche, pour mon boulot, à faire la chose suivante:

J'ai un repertoire que l'on nommera : "Bilan", lequel contient X fichiers Excel, ayant le même contenu (je parle niveau colonne, pas le contenu des cellules). Chaque fichier Excel a un nom différent, mais commençant toujours de la même façon "bilan_xxxxx"
Ces fichiers Excel ont des données uniquement sur la première feuille.

Je cherche, via une macro (car le nombre de fichier est important), à copier la feuille 1 de chaque fichier dans un fichier unique.
A savoir que la copie de la feuille 1 du classeur 1 ne doit biens ur pas être effacer par la feuille 1 du classeur 2.
Tout doit se retrouver les uns en dessous des autres.

Par avance merci pour votre aide.

[rvtoulon]

Slt,
peut-être un début de réponse ici :http://www.developpez.net/forums/d85...seul-classeur/

A+

[albibak]

Oui cela à l'air de correspondre à ce que je veux faire.

Reste à comprendre ces lignes là

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
 
       Ligne = .Range("A65536").End(xlUp).Row + 1
        Set wbk = Workbooks.Open("C:\classeurs\" & Fich)
        wbk.Sheets("Feuil1").Range("A7", wbk.Sheets("Feuil1").Range("H65536").End(xlUp)).Copy .Cells(Ligne, 1) 'wbk.Sheets("Feuil1") à adapter en fonction du nom de la feuille à copier

[rvtoulon]

slt,
j'ai remis le code de mercatog du lien que je t'avais donné avec quelques explications

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
Sub test()
Dim wbk As Workbook, awbk As Workbook
Dim wsh As Worksheet
Dim Fich As String
Dim Ligne As Double
 
Application.ScreenUpdating = False
'définie le classeur de destination, le classeur d'ou la macro est lancée
Set awbk = ThisWorkbook
'définie la feuille de destination
Set wsh = awbk.Sheets(1)
 
'définie le répertoire ou se trouve les fichiers à copier
Fich = Dir("C:\Bilan\*.xls")
'dans chaque fichier
Do While Fich <> ""
    With wsh
        'définie a partir de la colonne A la dernière ligne vide
        Ligne = .Range("A65536").End(xlUp).Row + 1
 
        'définie et ouvre le fichier source
        Set wbk = Workbooks.Open("C:\Bilan\" & Fich)
        'copie une plage de cellule ici "A7:H" & dernière ligne pleine de la colonne H
        'dans la feuille de destination à la première ligne vide à partir de la colonne A
        'TU DEVRAS ADAPTER LA PLAGE A TES BESOINS ici : (range ("A7", wbk.etc...)
        wbk.Sheets("Feuil1").Range("A7", wbk.Sheets("Feuil1").Range("H65536").End(xlUp)).Copy .Cells(Ligne, 1)
    End With
    'ferme le classeur source
    wbk.Close False
    Fich = Dir
    'remet à zéro la variable qui ouvre le fichier source
    Set wbk = Nothing
Loop
Set wsh = Nothing
Set awbk = Nothing
Application.ScreenUpdating = True
End Sub

si tu as des questions :
A+