Discussion :

[stefan69]

Bonjour,

Je voudrais effectuer une recherche au fur et à mesure de la saisie depuis la textbox d'une userfom.
J'arrive à faire cette recherche mais qu'avec le mot complet.
Voilà ce que j'ai pondu avec l'aide de qqes forum. (voir code à la fin)

Est-ce que vous auriez une idée de comment faire ?
Il me semble avoir vu qqe chose la dessus sur internet, mais je n'arrive pas à remettre l'oeil dessus.

Merci pour votre aide.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
 
    ' s'il y a une saisie j'attaque la recherche
    If TextBox <> "" Then
        ' je vais chercher la dernière ligne écrite
        Dercell = Worksheets("FichesClient").Range("A65536").End(xlUp).Address
        'j'initialise ma plage de recherche
        Set Plage = Worksheets("FichesClient").Range("A3:" & Dercell)
 
        For Each Cellule In Plage
          If Cellule.Value <> "" Then
            Posit = Application.WorksheetFunction.Find(TextBox.Value, Cellule.Value, 1)
            If Posit > 0 Then
                ' incrémentation num liste
                NumeroLigne = NumeroLigne + 1
                'je charge la liste
                With ListBoxClient
                    .ColumnCount = 2
                    .ColumnWidths = "22;190"
                    .AddItem NumeroLigne
                    .List(.ListCount - 1, 1) = Cellule.Value
                End With
            End If
          End If
        Next
 
    End If

[LeForestier]

Bonjour,
Si j'ai bien compris ce que tu veux faire...

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
Dim Dercell As Long
Dim Plage as Range
 
'Inutile de refaire cela à chaque fois, le mettre dans initialize
Private Sub UserForm_Initialize()
    With ListBoxClient
        .ColumnCount = 2
        .ColumnWidths = "22;190"
    End With
    Dercell = Worksheets("FichesClient").Range("A65536").End(xlUp).Row
    Set Plage = Worksheets("FichesClient").Range("A3:A" & Dercell)
End Sub
 
Private Sub TextBox1_Change()
    ListBoxClient.Clear
    ' s'il y a une saisie j'attaque la recherche
    If TextBox1 <> "" Then
        ' je vais chercher la dernière ligne écrite
        'j'initialise ma plage de recherche
 
        For Each cellule In Plage
          If cellule.Value <> "" Then
            If Left(cellule, Len(TextBox1)) = TextBox1 Then
                ' incrémentation num liste
                NumeroLigne = NumeroLigne + 1
                'je charge la liste
                With ListBoxClient
                    .AddItem NumeroLigne
                    .List(.ListCount - 1, 1) = cellule.Value
                End With
            End If
          End If
        Next
    End If
End Sub

Pas tester, je n'ai pas ton UF ni ton classeur
A+

[mercatog]

Bonjour,
un exemple, j'ai dans un userform Userform1 TextBox1 et ListBox1
je récupère dans ListBox1 tous les mots contenus en colonne A de la feuille active començant par les lettres contenu dans textbox1

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
Private Sub TextBox1_Change()
Dim i As Long
Me.ListBox1.Clear
For i = 1 To LastLig
    If Range("A" & i).Value Like Me.TextBox1.Value & "*" Then Me.ListBox1.AddItem Range("A" & i).Value
Next i
End Sub
 
Private Sub UserForm_Initialize()
LastLig = Cells(Rows.Count, 1).End(xlUp).Row
End Sub

avec dans un module général

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Public LastLig As Long

peut être, il y a mieux

[Gorfael]

Salut stefan69 et le forum
Un code qui ne fonctionne pas n'est pas des plus utiles. Un essais

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
Private Sub TextBox_Change()
Dim F As Worksheet, Cel As Range
Set F = Worksheets("FichesClient")
If TextBox <> "" Then
    Set Cel = F.Range(F.[A3], F.[A65536].End(xlUp)).Find(What:=Me.TextBox, LookAt:=xlPart)
    If Cel Is Nothing Then
        MsgBox "pas de correspondance trouvée"
    Else
        MsgBox "la cellule " & Cel.Address(0, 0) & " contient les lettres """ & Me.TextBox & """"
    End If
End If
End Sub

A+

[laetitia]

bonsoir les amis le forum un exemple de recherche utilisant un "tablo" quasi instantane sur 20000 lignes plus possibilitees de recherche sur toutes les colonnes avec un module de classe. eventuellement on peut "affiner" le code pour modifier , supprimer & ajouter les données. j'ai construis mon exemple sur 9 colonnes on peut simplifier. pas trop le temps de vous voir en ce moment études obligent!!! bonne soirée leti a+