Discussion :

[jijie]

Bonjour à tous,

Voila je voudrais rechercher un texte d'un combobox ds une feuille et récupérer la cellule d'à côté pour que mon textbox soit égal à cette cellule.

Exemple ds mon combobox je sélectionne Toto
ds la feuil4 toto est en "ba10"
et en "bb10" il y a jojo
il faut que mon textbox soit = jojo

j'ai récupéré ce code à michel et essayer de l'arranger mais mon souci c'est de trouver la "BB10" ds cet exemple

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
Private Sub CommandButton17_Click()
'Nom du produit a chercher
cpt = ComboBox1.Text
'recherche du cpt dans la colonne BA
Set c = Sheets("feuil4").Columns("BA:BA").find(What:=cpt)
 
'Si le cpt n'existe pas alors on vas à la première ligne vide
'on lui donne le nom du cpt et on sélectionne la cellule
If c Is Nothing Then
 derlign = Sheets("feuil4").Range("ba1").End(xlDown).Row + 1
 Range("ba" & derlign).Value = cpt
 Range("ba" & derlign).Activate
 
'Si le produit existe on sélectionne la cellule
Else
 
TextBox12.Text = Sheets("feuil4").Cells(c + 1)
End If

Merci

[mercatog]

bonsoir, tu y étais presque

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

TextBox12.Text = c.offset(0,1)

[jijie]

merci à toi!!

il est bien vrai qu'il manquait peu de chose!!

encore merci

[mercatog]

Si tu prends l'habitude dès maintenant de déclarer tes variables, ça serait mieux

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
Private Sub CommandButton17_Click()
Dim DerLign As Long
Dim Cpt As String
Dim c As Range
 
Cpt = ComboBox1.Text
If Len(Cpt) > 0 Then  'si l combo n'est pas vide
    With Sheets("feuil4")
        Set c = .Columns("BA:BA").Find(Cpt, LookIn:=xlValues, lookat:=xlWhole)
        If c Is Nothing Then
            DerLign = .Cells(.Rows.Count, 53).End(xlUp).Row + 1
            .Range("BA" & DerLign).Value = Cpt
        Else
            TextBox12.Text = c.Offset(0, 1).Value
            Set c = Nothing
        End If
    End With
End If
End Sub