Discussion :

[O'Camarade]

Bonjour à tous,

Je vous sollicite quelques instants car je suis confronté au problème suivant :

Je développe une application vba/excel, et j'ai notamment un simple bouton d'import. Ce bouton est censé m'importer un fichier excel, fichier excel qui sera forcément préfixé de la même façon, disons "toto" pour le moment.

Je sais que pour afficher la fenêtre excel d'ouverture de fichier en vba, il faut faire appel à la fonction getOpenFilename. Dans les paramètres, j'ai vu qu'il était possible d'afficher par exemple tous les fichiers se terminant par exemple par .xls
Dans mon cas, je souhaiterais à la fois afficher sur cette fenêtre d'ouverture les fichiers xls, mais également préfixés par "toto".

Cela est-il possible ?

Merci d'avance de votre aide

[casavba]

Bonjour,
Pour répondre, tout va dépendre en fait de ton utilisation.
Veux-tu réellement ouvrir le fichier selectionné ou non ?

Getopenfilename --> Cette méthode affiche la boîte de dialogue standard Ouvrir et lit un nom de fichier tapé par l'utilisateur sans réellement ouvrir les fichiers. (source aide microsoft)

Ta réponse conditionnera ma réponse

[kiki29]

Salut, utilise plutôt FileDialog si Excel >= 2002, à adapter au contexte

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
Option Explicit
 
Sub Lecture()
Dim FD As FileDialog
Dim i As Integer
 
    ChDir ThisWorkbook.Path
    Set FD = Application.FileDialog(msoFileDialogFilePicker)
    With FD
        .InitialFileName = "toto*.xls"
        .AllowMultiSelect = True
        .ButtonName = "Sélection fichier(s)"
        .Title = "Sélectionner un ou plusieurs fichier(s)"
    End With
 
    If FD.Show = True Then
        Application.ScreenUpdating = False
 
        For i = 1 To FD.SelectedItems.Count
            'Lire FD.SelectedItems(i)
        Next i
 
        Application.ScreenUpdating = True
    End If
 
    Set FD = Nothing
End Sub

[O'Camarade]

Bonjour,
Pour répondre, tout va dépendre en fait de ton utilisation.
Veux-tu réellement ouvrir le fichier selectionné ou non ?

Getopenfilename --> Cette méthode affiche la boîte de dialogue standard Ouvrir et lit un nom de fichier tapé par l'utilisateur sans réellement ouvrir les fichiers. (source aide microsoft)

Ta réponse conditionnera ma réponse

Oui je souhaite l'ouvrir.
Je me suis mal exprimé. Je sais que la fonction getopenfilename affiche la boite de dialogue standart ouvrir. Dans cette boite de dialogue, on peut afficher que les .xls si on le souhaite (enfin si on l'a paramétré dans la fonction getopenfilename). Pour ma part, je souhaite uniquement proposer à l'utilisateur les fichier .xls dont le nom commence par "toto" par exemple.

[casavba]

Dans ce cas, ma réponse sera comme suit :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
Sub OpenFenet()
Dim strString As String
strString = "eco" ' Ouvre la fenêtre en affichant seulement
'les classeurs dont le nom débute par "eco"
'Choix du lecteur
CurDir "c:"
'Pour sélectionner le répertoire à l'ouverture
ChDir "c:\"
Application.Dialogs(xlDialogOpen).Show strString & ".xls"
 
End Sub

[kiki29]

re, ou , pour info

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
Option Explicit
 
Sub Lecture()
Dim FD As FileDialog
Dim i As Integer
 
    ChDir ThisWorkbook.Path
    Set FD = Application.FileDialog(msoFileDialogFilePicker)
    With FD
        .InitialFileName = "toto*.xls"
        .AllowMultiSelect = False
        .ButtonName = "Sélection fichier"
        .Title = "Sélectionner le fichier"
    End With
 
    If FD.Show = True Then
        Application.ScreenUpdating = False
        Workbooks.Open Filename:=FD.SelectedItems(1)
        Application.ScreenUpdating = True
    End If
 
    Set FD = Nothing
End Sub

Voir également http://excel.developpez.com/faq/?page=FenetresExcel

[O'Camarade]

ça fonctionne parfaitement, merci beaucoup !