Discussion :

[stargates01]

Salut le Forum,

Je me permet de vous soumettre un problème archi-traité, mais malgré toutes les discussions consultées et l'excellent guide DAO, je n'ai pas résolu mon problème

J'ai une table Test02 dont je voudrais modifier le format d'affichage d'un champ en vba. J'ai essayé avec le code suivant mais j'ai une erreur 3421 - erreur de conversion de type de données lors de la méthode CreateProperty.

Lorsque j'ouvre ma table (pas en vba cette fois) en mode création je constate que je peux changer le format pour le mettre en standard sachant que le type du champ que je veux changer est Réel Double. Je n'arrive pas à répliquer cette action apparemment simple en vba... Avez vous une idée ?

Merci pour votre aide.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
 
Sub DD()
 Dim Tbl As DAO.TableDef
Dim Pr As DAO.Property
 
Set Db = DBEngine.Workspaces(0).Databases(0)
 
Set Tbl = Db.TableDefs("Test02")
Set Pr = Tbl.Fields("Champ2").CreateProperty("Format", dbDouble, "# ##0.00")
Tbl.Fields("Champ2").Properties.Append Pr
 
End Sub

[stargates01]

Bon j'ai un peu progressé, mais ça plante toujours. J'ai modifié les arguments de CreateProperty, ce qui me permet de passer à la ligne suivante. C'est là que ça plante, à la méthode Append, avec un message Erreur d'exécution '3394' - Impossible d'enregistrer la propriété, car il s'agit d'une propriété Schéma. Savez-vous ce qu'est une propriété schéma ? je ne trouve pas de littérature là-dessus.

Merci

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
 
Sub DD()
Dim Tbl As DAO.TableDef
Dim Pr As DAO.Property
 
Set Db = DBEngine.Workspaces(0).Databases(0)
 
Set Tbl = Db.TableDefs("Test02")
Set Pr = Tbl.Fields("Champ2").CreateProperty("Format", dbText, "Standard")
Tbl.Fields("Champ2").Properties.Append Pr
 
End Sub

[stargates01]

Après quelques heures de recherche, j'ai fini par trouver un code qui marche (sur la communauté Microsoft US). J'en fait profiter le Forum

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
 
Sub DD()
Dim Tbl As DAO.TableDef
Dim Pr As DAO.Property
Dim Fld as DAO.Field
 
Set Db = CurrentDb
Set Tbl = Db.TableDefs("Test02")
Set Fld = Tbl.Fields("Champ2")
Call SetDAOProperty(Fld, "Format", dbText, "Standard")
 
End Sub
 
 
Function SetDAOProperty( _
    WhichObject As Object, _
    PropertyName As String, _
    PropertyType As Integer, _
    PropertyValue As Variant _
) As Boolean
On Error GoTo ErrorHandler
Dim prp As DAO.Property
    WhichObject.Properties(PropertyName) = PropertyValue
    WhichObject.Properties.Refresh
    SetDAOProperty = True
Cleanup:
    Set prp = Nothing
    Exit Function
ErrorHandler:
    Select Case Err.Number
        Case 3270 ' "Property not found"
            Set prp = WhichObject.CreateProperty( _
                PropertyName, _
                PropertyType, _
                PropertyValue _
            )
            WhichObject.Properties.Append prp
            WhichObject.Properties.Refresh
            SetDAOProperty = True
        Case Else
            MsgBox Err.Number & ": " & Err.Description
            SetDAOProperty = False
    End Select
    Resume Cleanup
 
End Function