Discussion :

[rocsylcanar]

Bonjour, j'ai longuement hésité à m'inscrire ici, vu que pour le moment j'arrivais à jongler suffisamment sur Internet pour resoudre mes problèmes sous SAS.

Donc voilà :

Je dispose d'une table, nommée ventes. Seulement, elle est trop volumineuse, et je souhaite créer autant de tables-filles qu'il existe de modalités pour une variable (ACTIVITE). Il existe plusieurs centaines d'activités, c'est pourquoi je souhaite la création de plusieurs centaines de tables.

La solution "kimarche" étant fastidieuse, est celle de faire des macros, et de donner en macro-variable le nom de chaque activité. Le problème, c'est la multitude de modalités de la variable ACTIVITE qui m'obligerait à créer plusieurs centaines d'appels de macro. Cela marche ainsi, mais point de vue code, je ne trouve pas ça optimal.

Je préfère une solution ou SAS reconnait les codes activités et crée automatique une table en sortie, dont le nom contient au minima le nom de l'activité.

Structure de la table :
ACTIVITE : caractères (5)
PERIODE : caractères (4)
CAHT : numérique

Peut-être une solution du côté de la proc SQL edit : ou de l'utilisation de call symput ? J'ai déjà utilisé le call symput auparavant, mais là je sèche un peu

Merci pour votre réponse.

edit 2 : tant que j'y suis, connaissez-vous un moyen de forcer la création d'un répertoire windows lors d'un libname, même si ce répertoire n'existe pas encore ?

[datametric]

Pourquoi ce n'est pas optimal ?

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
filename mprint 'c:\temp\code en clair.txt';
options mfile mprint;
 
 
/* reconnaissance des activités*/
Proc sort data=table (keep=activite) nodupkey out=activite;
by activite;
 
/*enregistrement des activités */
data _null_;
set activite ;
call symputx( cats('act',_n_) , activite);
call symputx( 'nbobs' , _n_);
run;
 
/* Split */
data  %do i = 1 %to &nbobs ; fille_&&act&i %end; ; 
set table ;
 
if activite = "&act1" then output fille_&act1 ;
 
%do i = 2 %to &nbobs ;
  else if activite = "&&act&i" then output fille_&&act&i ;
%end;
 
run;

[rocsylcanar]

Merci pour la réponse je l'épluche demain matin.

[Bruno.Thevenin]

Bonjour,

En ce qui concerne la question subsidiaire, tu trouveras un macro-programme de steelspirit DirExist qui devrait t'inspirer !

Bon courage !

[datametric]

Attention, la création d'un répertoire sous windows 2003 server demande à avoir des droits supplémentaires sur cmd.exe du serveur : si tu as des erreurs là où il ne devrait pas y en avoir, c'est à cause de cela.

[rocsylcanar]

Pourquoi ce n'est pas optimal ?

Parce que je cherche à faire fonctionner un programme qui mette le moins de temps possible à l'exécution.

Merci pour direxist, mais je pensais qu'il y avait une option plus simple, à l'instar de REPLACE dans une proc export qui permet de remplacer un fichier existant.

[rocsylcanar]

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
filename mprint 'c:\temp\code en clair.txt';
options mfile mprint;
 
 
/* reconnaissance des activités*/
Proc sort data=table (keep=activite) nodupkey out=activite;
by activite;
 
/*enregistrement des activités */
data _null_;
set activite ;
call symputx( cats('act',_n_) , activite);
call symputx( 'nbobs' , _n_);
run;
 
/* Split */
data  %do i = 1 %to &nbobs ; fille_&&act&i %end; ; 
set table ;
 
if activite = "&act1" then output fille_&act1 ;
 
%do i = 2 %to &nbobs ;
  else if activite = "&&act&i" then output fille_&&act&i ;
%end;
 
run;

2 questions me viennent à l'esprit :

- Le double & : je ne l'ai jamais utilisé, mais je suppose qu'il agit comme une macro-variable double (ou meta) ?
- le programme s'exécute seulement au sein d'une macro, à cause de la boucle %do ?

[olivier.decourt]

Pour optimiser encore la solution de Datametric (qui limite la lecture de la grosse table à 2 passages, un pour la proc Sort et un pour l'étape Data), on pourrait utiliser une proc Freq au lieu de la proc Sort et un SELECT WHEN au lieu du IF THEN ELSE : en ordonnant les WHEN par fréquences décroissantes, on évite les tests inutiles.

Edit : uniquement dans un macro-programme à cause du %DO, exact.
Edit : pour les &&, les règles de lecture sont les suivantes :

• &nomMv --> valeur de la macro-variable nomMV
• &nomMV. --> valeur de la macro-variable nomMV
• && --> &
• texte --> texte
• s'il reste des & après la vague de transformations, on fait un autre passage

En mettant que i vaut 1, qu'il existe une macro-variable ACT qui vaut TOTO et une macro-variable ACT1 qui vaut 350, alors
act&i --> act1
&act&i --> TOTO1
&&act&i --> &act1 --> 350 en 2 lectures successives (&&-->&, act-->act, &i --> 1 pour la 1e lecture)

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
/* reconnaissance des activités*/
ODS EXCLUDE ALL ;
ODS OUTPUT oneWayFreqs=activite;
Proc FREQ DATA=TABLE (keep=activite) ORDER=FREQ 
TABLE activite;
RUN ;
ODS SELECT ALL ;
/*enregistrement des activités */
DATA _null_;
SET activite ;
call symputx( cats('act',_n_) , activite);
call symputx( 'nbobs' , _n_);
run;
 
/* Split */
DATA  %do i = 1 %TO &nbobs ; fille_&&act&i %end; ; 
SET TABLE ;
SELECT (activite) ; 
%do i = 1 %TO &nbobs ;
  WHEN ("&&act&i") output fille_&&act&i ;
%end;
OTHERWISE ;
END ; 
run;

Olivier

PS : pourquoi hésiter longuement à s'inscrire ? On n'est pas obligé de ne faire que poser des questions, on peut aussi proposer des réponses ! Ca sert aussi à ça de s'inscrire et je suis sûr que tu auras de très bonnes contributions.

[rocsylcanar]

Longuement hésité, le temps d'acquérir une culture SAS, maintenant c'est fait, je peux apporter ma pierre à l'édifice !

[datametric]

Merci Olivier.

Remarque : Je ne dirais pas que je n'évite pas les test inutiles, mais que je priorise les tests de sorte à remplir les conditions les plus fréquentes en premier.

Le case /when des étapes DATA est plus optimisé que le IF/ELSE IF au niveau algo interne de SAS car il a été écrit plus tard mais le principe reste le même puisque les conditions renvoient TRUE/FALSE pour pouvoir fonctionner.
Dans le deux cas, les conditions sont testées jusqu'à obtenir la bonne, en positionnant la plus fréquentes en amont, SAS passe à la ligne suivante plus rapidement.

Ce résultat est plus spectaculaire si l'on compare au IF/THEN. Dans ce cas, toutes les conditions sont testés sur chaque ligne.