Discussion :

[Antoniom]

Hello le Forum,

Je souhaite concatener la colonne A et B sans la colonne C.

J'ai fait (une de mes premières svp indulgence) une macro, mais je ne sais pas pourquoi ça ne joue pas ou alors je suis à côté de la plaque

Voyez le fichier joint, les explications dedans sont plus claires je crois.

Si toutefois vous ne parvenez pas à prendre le fichier joint (ça m'arrive parfois dans ce forum) le code de ma macro est

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
Sub ConcatenerColonneAetB()
Dim Noms As Range
Dim Prenoms As Range
Dim Conc As Range
 
Sheets(1).Activate
 
For Each Prenoms In Range("B2:B" & Range("B65536").End(xlUp).Row)
Next Prenoms
 
For Each Conc In Range("C2:C" & Range("C65536").End(xlUp).Row)
Next Conc
 
For Each Noms In Range("A2:A" & Range("A65536").End(xlUp).Row)
    If Noms.Value <> "" And Prenoms.Value <> "" Then
        Conc.Value = Noms.Value & " - " & Prenoms.Value
    End If
Next Noms
Range("A2").Select
End Sub

et le code dont j'aimerais que ma macro fasse le même résultat

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
Sub Macro1()
    Range("C2").Select
    ActiveCell.FormulaR1C1 = "=RC[-2]& "" - "" &RC[-1]"
    Selection.AutoFill Destination:=Range("C2:C11"), Type:=xlFillDefault
    Calculate
    Range("A2").Select
End Sub

Si un génie pouvait m'aider, par avance un grand merci.

Cdt, Anto.

[Invité]

Bonjour,

Est-ce que cela vous conviendrait :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
 
Sub ConcatenerColonneAetB()
Sheets(1).Activate
dl = Range("A65536").End(xlUp).Row
For i = 2 To dl
Cells(i, 3) = Cells(i, 1) & Cells(i, 2)
Next i
Range("A2").Select
End Sub

Bien sûr vous pouvez affecter les valeurs à des variables, mais dans ce cas ce n'est pas nécessaire et en tout cas pas obligatoire.

Si vous avez des cellules non remplies dans la plage vous pouvez utiliser :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
 
Sub ConcatenerColonneAetB()
Sheets(1).Activate
dl = Range("A65536").End(xlUp).Row
For i = 2 To dl
   If Cells(i, 1) <> "" and Cells(i, 2) <> "" then
   Cells(i, 3) = Cells(i, 1) & Cells(i, 2)
   end If
Next i
Range("A2").Select
End Sub

[Gorfael]

Salut Antoniom et le forum
Je souhaite concatener la colonne A et B sans la colonne C.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
For Each Prenoms In Range("B2:B" & Range("B65536").End(xlUp).Row)
Next Prenoms

Pour chaque cellule(qui prendra le nom de variable "Prenoms") de la colonne B de ligne 2 à dernière
cellule suivante
Belle boucle, mais elle ne fait rien
Une proposition

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
Sub ConcatenerColonneAetB()
Dim Cel As Range
For Each Cel In Range("A2:A" & Range("A65536").End(xlUp).Row)
    If Cel <> "" And Cel.Offset(0, 1) <> "" Then _
       Cel.Offset(0, 2) = Cel & " - " & Cel.Offset(0, 1)
Next Cel
End Sub

A+

[Antoniom]

Hello,

Hm j'étais aux fraises quoi

Impeccable Jean-Jaques et Gorfael, les deux méthodes (même trois) sont excellentes !

Un grand merci.

Cdt, Hulk.

[laetitia]

bonjour Antoniom jacques_jean Gorfael le forum

en modifiant ta macro1 une autre possibilite

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
Sub Macro1()
[c2].Select: ActiveCell.FormulaR1C1 = "=RC[-2]& "" - "" &RC[-1]"
Range("c2:c" & Cells.Find("*", , , , , xlPrevious).Row).FillDown: [a2].Select
End Sub

[Antoniom]

Re,

Ok Laetitia merci, pas mal aussi, j'y classe dans mon tiroir

Merci et au plaisir.

Bon WE à tous, Anto.

[Antoniom]

Hello le Forum,

Je reviens là dessus, car suite aux solutions trouvées hier, j'ai encore une petite question.

J'ai finalement opté pour la solution à Gorfael et j'espère que vous ne m'en voudrez pas Laetitia et Jean-Jaques.

Donc à partir du code à Gorfael, comment puis-je faire pour que tout (lettres, chiffres, caractères) ce qui se trouve à gauche du tiret soit en rouge, et tout ce qui se trouve à droite du tiret en vert.

Exemples :

tutu - ssdd

ou

Reft%&343 - fgt

ou

lsd233l - 345

Bref, tout ce qui est à gauche du tiret en rouge et tout ce qui est à droite du tiret en vert... Possible ça ?

J'ai bien essayé avec les Right et Len, mais je ne connais pas vraiment ces fonctions en vba.. Quelqu'un peut-il m'aider svp.

Par avance merci.

Bon dimanche, Antoniom.

[Gorfael]

Salut Antoniom et fle forum
Texte en A1.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
Sub Macro1()
'Déclaration ===============
Dim X As Long
'Recherche séparateur ======
X = InStr([A1], "-")
'colorage ==================
[A1].Characters(Start:=1, Length:=X).Font.ColorIndex = 3
[A1].Characters(Start:=X, Length:=Len([A1]) + 1 - X).Font.ColorIndex = 43
End Sub

C'est du brut : faudrait vérifier la présence du tiret avant de colorier, mais ça donne le principe
A+