Discussion :

[coincoin22]

Bonjour,

J'aimerai utiliser une macro me permettant de parcourir tous les onglets. Lorsqu'une cellule (range A120) d'un onglet possède une police rouge >> Couleur de cet onglet en rouge.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
 Sub Check_xls()
 
Dim Ws As Worksheet
 
 For Each Ws In ActiveWorkbook.Worksheets
      Dim CurCell As Object
      For Each CurCell In Range("A1:D20")
         If CurCell.Font.ColorIndex = 3 Then ActiveWorkbook.Sheets.Tab.ColorIndex = 3
  Next
  Next Ws
 
End Sub

Merci de votre aide précieuse...

[Gorfael]

Salut coincoin22 et le forum

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
Sub Check_xls()
Dim Ws As Worksheet
Dim CurCell As Object
For Each Ws In Sheets
    For Each CurCell In Ws.Range("A1:D20")
        If CurCell.Font.ColorIndex = 3 Then
            Ws.Tab.ColorIndex = 3
            Exit For
        Else
            Ws.Tab.ColorIndex = xlNone
        End If
    Next CurCell
  Next Ws
End Sub

Qelques remarques :
Les déclarations peuvent être n'importe où dans le code, mais il est préférable de les regrouper au début de ta macro : elle devient plus lisible, et tu sais où chercher les déclarations.

Il faut expliquer toutes les manips que tu veux lui faire exécuter à Excel. C'est évident pour toi, que si tu parcoures les feuilles, c'est pour travailler sur toutes les feuilles. Mais pas pour Excel => il faut lui dire
Quand tu n'expliques pas, il rajoute devant Activeworkbook.Activesheet (ce qui peut conduire à des problèmes).

Si tu colories à partir d'un test, il faut penser quoi faire en cas de réponse négative du test.

Le fait qu'une seule cellule soit bonne suffit à colorer => pas la peine de tester 80 cellules si c'est A1 : du temps de perdu (mais sur 80, c'est faible), et si la dernière cellule de la plage donne une réponse négative, il faut quand même passer l'onglet en rouge => il faut une variable de stockage à tester après la dernière cellule qui donne la couleur de l'onglet. Mais ici elle n'est pas nécessaire.
A+

[coincoin22]

Merci beaucoup pour ta réactivité !!

Je suis novice sur les macros et j'en apprends chaque jour davantage grâce à des explications claires comme les tiennes !!

Merci !