Discussion :

[Arrow_V]

Salut le forum,

je cherche une façon de combiner une liste de données.

Supposons dans la plage A2:A7 6 données différentes.

En établissant une valeur, je souhaite combiner les données de la façon suivante :

Si par exemple valeur = 2 (les combinaisons se répètent deux fois)

Données 1 - Données 2
Données 1 - Données 2
Données 1 - Données 3
Données 1 - Données 3
...
Données 5 - Données 6
Données 5 - Données 6

Je suppose qu'en combinant des boucles, j'y parviendrais mais je n'ai pas les connaissances pour aller jusque-là.

Merci pour votre aide.

[pgz]

Bonjour.

Voici une idée de code, à adapter

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
Dim ias integer, j as integer, k as integer, h as integer
const NbRepete as integer = 2
Const NbVal as integer = 6
 
For i = 1 to NbVal-1
    For j = i+1 to NbVal
        for k = 1 to NbRepete
            Resultat(h+k) = Donnees(i) & Donnees(j)
        Next k
        h= h+NbRepete
    Next j
Next i

En espérant que cela t'aide et cordialement,

PGZ

[Arrow_V]

Salut pgz et merci à toi pour cette réponse.

Cependant, j'ai deux questions :

1- à quoi correspond la valeur h?
2- dois-je définir Resultat et Donnees dans mes variables?

[pgz]

Salut, cousin.

1- à quoi correspond la valeur h?
2- dois-je définir Resultat et Donnees dans mes variables?

h est le numéro de ligne dans le tableau des résultats
Donnees est le tableau des données à combiner, Resultat est le tableau des résultats

En fait le bout de code voulait te montrer l'écriture des boucles. Dans la pratique, tes données initiales sont dans une feuille (en colonne), et tu vas certainement vouloir ranger les résultats dans une autre zone de la feuille, ou du classeur. Le nombre de répétitions devra être saisi d'une façon ou d'une autre.

Voici maintenant une procédure complète

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
Sub subCombine(ByRef RngDonnees As Excel.Range, ByRef rngResult As Excel.Range, ByVal NbRepete As Integer)
Dim i As Long, j As Long, k As Integer, h As Long 'variables des boucles
Dim varD As Variant, NbVal As Long, Result()  As String, NbResult As Long
 
'chargement des données
varD = RngDonnees.Value
 
'nombre de valeurs, nombre de combinaisons, redimensionnement du tableau de résultats
NbVal = UBound(varD) - LBound(varD) + 1
NbResult = NbVal * (NbVal - 1) * NbRepete
ReDim Result(1 To NbVal * (NbVal - 1) * NbRepete, 1 To 1)
 
'initialisation (inutile, juste pour la clarté) de h
h = 0
 
'élaboration des combinaisons
For i = 1 To NbVal - 1
    For j = i + 1 To NbVal
        For k = 1 To NbRepete
            Result(h + k, 1) = varD(i, 1) & " - " & varD(j, 1)
        Next k
        h = h + NbRepete
    Next j
Next i
 
'rangement du résultat
rngResult.Worksheet.Range(rngResult.Cells(1, 1), rngResult.Cells(1, 1).Offset(NbResult - 1, 0)) = Result
 
End Sub

Pour utiliser cette procédure il faut choisir la zone des données, la zone de rangement du résultat (il suffit de désigner 1 cellule et les résultats se rangent à partir de cette cellule et vers le bas) et le nombre de répétitions. Par exemple A2:A7, résultats à partir de B3, répétitions = 2

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
Sub subEssaisubCombine()
Call subCombine(Application.ThisWorkbook.Sheets(1).Range("A2:A7"), Application.ThisWorkbook.Sheets(1).Range("B3"), 2)
End Sub

Cordialement,

PGZ

[Arrow_V]

Merci pour ton aide.