Discussion :

[cadabricadabra]

Bonjour à tous,

je suis entrain de devélopper une application de gestion clients sur excel 2003. Il se trouve q'il y a des données sur DB2 dont j'ai impérativement besoin.

Ma question est la suivante : A l'aide d'une macro (codes vba), comment ce connecter à une base DB2 et extraire les données pour les insérer dans un tableau excel?

Merci de m'aider.

Bon dev...

[Mercure]

Si DB2/400, créer un onglet "DownLoad" dans une feuille de calcul et coller le module ci-dessous dans VBA

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
Private Sub DownLoad_From_iSeries()

Dim Con As New ADODB.Connection
Dim Cmd As New ADODB.Command
Dim rs As ADODB.Recordset

Dim rowCount As Integer
Dim colCount As Integer
Dim text As String
Dim Number As Long
Dim val As Variant

Con.Open "provider=IBMDA400;data source=MonDNS; USER ID=...; PASSWORD=...;"

Set Cmd.ActiveConnection = Con
Cmd.CommandText = "SELECT * FROM MaLib.MaTable Where ..."

Set rs = Nothing
Set rs = Cmd.Execute()
Worksheets("Download").Activate

rowCount = 10        ' Ligne début

' Libellés d'en-tête de colonne
For colCount = 0 To rs.Fields.Count - 1  'colonne début = A
Worksheets("Download").Cells(rowCount, colCount + 1).Value = rs.Fields(colCount).Name
Next colCount

' Data
While Not rs.EOF
    rowCount = rowCount + 1
    For colCount = 0 To rs.Fields.Count - 1

    If rs.Fields(colCount).ActualSize = -1 Then
        text = ""
    Else
        val = rs.Fields(colCount).Value
        If VarType(val) = vbNull Then
            text = ""
        Else
            text = val
        End If
    End If

    Worksheets("Download").Cells(rowCount, colCount + 1).Value = text

    Next colCount
    rs.MoveNext
Wend

Set rs = Nothing
Con.Close
End Sub

[cadabricadabra]

Merci....!!!! ça marche impécablement......

[sempire]

Bonjour,
Je déterre ce sujet au lieu d'en créer un autre.
J'aimerais pouvoir faire la même chose sur db2 SDK 7.2.
Déjà, quelle est la différence avec db2 400 ?

Par quoi la valeur MonDNS du code cité plus haut doit-elle être remplacée sachant que je me connecte à une base se trouvant sur un serveur distant pour lequel j'ai une adresse ip etc. ?

Merci d'avance pour toute aide,

[Mercure]

Je ne connais pas db2 SDK 7.2 mais ça ne coûte rien d'essayer.

A la place de "MONDNS", mets l'adresse IP et, si tu n'as pas Client Access installé sur ta machine client, indique également à la place de "IBMDA400" le nom du fournisseur de ton driver ODBC pour accéder à ta BDD DB2 SDK 7.2. Ceci sans aucune garantie que ça fonctionne. Aussi, tu peux aller voir également cette page, car je pense que ça pourrait t'aider.

[Trycias]

Bonjour,

Je tente de faire mon premier fichier excell connecté.
J'ai pris le code indiqué ci-dessus.
Je l'ai mis dans la feuille Download dans Microsoft Visual Basic.

Et je me pose des questions :
1- monDNS doit être remplacé par quoi ?
Parce que je connait aps chaine de connexion
-> jdbc:db2://monServeur:monPort/database
2- comment tester ma connexion ?
J'ai essayer de lancer une macro.
Mais il ne me propose aucune macro.


Bref, merci d'avance pour l'aide que vous pourriez m'apporter.
P.S. J'utilise office 2003 sur win XP.
Trycias