Discussion :

[gelwc]

Bonjour à tous,

j'ai un petit soucis.
Je voudrais dans une listbox ajouter des items qui sont contenues sur 2 colonnes différentes d'une même feuille. Je voudrait que ces 2 items soit sur la même ligne dans la liste box.

J'ai essayé un truc du genre :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
 
Private Sub UserForm_Initialize()
Dim i As Byte, x As Byte
i = Sheets("tables").Range("C65536").End(xlUp).Row
For x = 2 To i
    With Catégorie1
        .AddItem Sheets("tables").Range("C" & x & ":" & "D" & x)
 
    End With
Next x
End Sub

-> ça ne fonctionne pas

Je précise que les items a insérer sont sur la même ligne et sur colonnes collées.

Merci d'avance pour l'aide.

[fring]

Bonjour,

Premièrement, il faut fixer la propriété ColumnCount de ta ListBox sur 2

Ensuite le remplissage via AddItem s'effectue de cette manière

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
Private Sub UserForm_Initialize()
Dim i As Byte, x As Byte
i = Sheets("tables").Range("C65536").End(xlUp).Row
For x = 2 To i
    With Catégorie1
        .AddItem Sheets("tables").Range("C" & x) '<-- 1ère colonne
        .List(.ListCount - 1, 1) = Sheets("tables").Range("D" & x) '<-- 2ème colonne
    End With
Next x
End Sub

Une autre possibilité est d'utiliser la méthode RowSource

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
Private Sub UserForm_Initialize()
Dim i As Byte
 
i = Sheets("tables").Range("C65536").End(xlUp).Row
Catégorie1.RowSource = "tables!C2:D" & i
End Sub

[gelwc]

merci pour ta réponse fring, j'essaie tout ça aujourd'hui

si ça marche je reviens et je met le sujet en "résolu"

Bon journée

edit : la première solution marche impeccablement on peut régler l'espacement des 2 items dans la list box avec la propriété columnwidth

merci encore