Discussion :

[Jeanvaljean44]

Salut le Forum!!!

Je rencontre un petit souci sur une frame. Dès que je click sur un bouton situé sur ma frame, la procédure Sub UserForm_QueryClose se lance

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
Private Sub UserForm_Initialize()
 
CmdCreationBL.SetFocus
 
End Sub
 
Private Sub CmdCreationBL_Click()
 
Unload FmAccueilUtilisateur
FmOrdreFabrication.Show
 
End Sub
Private Sub CmdGestionEncours_Click()
 
Unload FmAccueilUtilisateur
FmIdentificationGE.Show
 
End Sub
Private Sub UserForm_QueryClose(Cancel As Integer, CloseMode As Integer)
 
Dim Rep As Byte
 
Rep = MsgBox("Etes-vous sûr de vouloir quitter l'accès aux Encours en Production?", vbYesNo + vbQuestion, "Quitter l'accès aux données techniques?")
If Rep = vbYes Then
    Workbooks("EncoursProduction.xlsm").Close False
    End
End If
 
End Sub

Quelqu'un aurait-il une ptite idée sur le sujet???

@+ Jean

[fring]

Bonjour,

Si tu ne précises pas dans l'événement que tu veux vérifier si l'on ferme le UserForm via la petite croix, les procédures "UnLoad" actionneront également l'événement QueryClose.

Essaye ceci :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
Private Sub UserForm_QueryClose(Cancel As Integer, CloseMode As Integer)
Dim Rep As Byte
 
If CloseMode = vbFormControlMenu Then
    Rep = MsgBox("Etes-vous sûr de vouloir quitter l'accès aux Encours en Production?", vbYesNo + vbQuestion, "Quitter l'accès aux données techniques?")
    If Rep = vbYes Then
        Workbooks("EncoursProduction.xlsm").Close False
    Else
        Cancel = True
    End If
End If
 
End Sub

[Jeanvaljean44]

Bonjour Fring,

Parfait ça fonctionne,

Merci beaucoup!!!

Jeanvaljean