Discussion :

[nonaparus]

Bonjour,

Si je suis positionnée dans une cellule qui se trouve à la page 1, j'aimerais récupérer ce numéro de page en vba.

est-ce possible ?

Merci

JM

[LeXo]

oui


...


t'as un objet de type Range tu remontes sur la sheet et tu lui demande son index

alors ça devrait donner

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

rg.parent.Index

[fring]

Bonjour tlm,

J'ai un doute quant à la question de nonaparus.

Tu veux récupérer le numéro de la feuille (onglet) ?
Ou, la feuille pouvant être divisée en plusieurs pages pour l'impression, c'est ce numéro de page là que tu veux récupérer ?

[SilkyRoad]

bonjour

ci joint une procédure de Laurent Longre

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
Sub numeroPageCelluleActive()
 
    Application.ScreenUpdating = False
    ActiveWindow.View = xlPageBreakPreview
 
    MsgBox numeroPage(ActiveCell)
 
    ActiveWindow.View = xlNormalView
    Application.ScreenUpdating = True
 
End Sub
 
 
Function numeroPage(Cellule As Range) As Integer
    'Auteur:
    'Laurent Longre
  Dim VPC As Integer, HPC As Integer
  Dim VPB As VPageBreak, HPB As HPageBreak
  Dim Wksht As Worksheet
  Dim Col As Integer, Ligne As Long
 
  Set Wksht = Cellule.Worksheet
  Ligne = Cellule.Row
  Col = Cellule.Column
 
  If Wksht.PageSetup.Order = xlDownThenOver Then
    HPC = Wksht.HPageBreaks.Count + 1
    VPC = 1
  Else
    VPC = Wksht.VPageBreaks.Count + 1
    HPC = 1
  End If
 
  numeroPage = 1
 
  For Each VPB In Wksht.VPageBreaks
    If VPB.Location.Column > Col Then Exit For
    numeroPage = numeroPage + HPC
  Next VPB
 
  For Each HPB In Wksht.HPageBreaks
    If HPB.Location.Row > Ligne Then Exit For
    numeroPage = numeroPage + VPC
  Next HPB
End Function

bonne journée
michel

[nonaparus]

Je veux parler de lafeuille pouvant être divisée en plusieurs pages pour l'impression

c'est ce numéro de page que je veux récupérer

Merci

[Jean-Pierre49]

Bonjour

Je pense que SilkyRoad avait bien compris (HPageBreak)

[nonaparus]

je teste ça dans les prochains jour

un gros merci