Discussion :

[serar]

Bonjour,

Je souhaite masquer des colonnes en fonction d'un valeur presente dans une case. Feuil1 B7=3 afficher les 3 premieres colonnes de la feuille 2.

Voici mon code:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
Private Sub Worksheet_Change(ByVal Target As Range)
 
Dim Plage As Range, Intersection As Range
Dim nb_classeur As Integer
 
Set Plage = Range("B7:B7")
Set Intersection = Intersect(Target, Plage)
 
If Not (Intersection Is Nothing) Then
'MsgBox "Dans la plage"
nb_classeur = ActiveSheet.Cells(7, 2)
Sheets("Feuil2").Select
Columns("B:D").Select
Selection.EntireColumn.Hidden = True
Sheets("Feuil1").Select
 
End If
End Sub

J'ai une erreur sur la ligne

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Columns("B:D").Select,

Erreur 1004 La méthode Select de la classe Range à échoué

Merci de votre aide.
Cdlt.

[fring]

Bonjour,

Tout ceci

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
Sheets("Feuil2").Select
Columns("B:D").Select
Selection.EntireColumn.Hidden = True
Sheets("Feuil1").Select

Peut-être remplacé par

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Sheets("Feuil2").Columns("B:D").Hidden = True

sans passer par tout les "Select" qui ne font que ralentir le processus et transformer ton écran en sapin de Noel

[CinePhil]

Corrige ton message en mettant les tags de code parce que columns("B[smiley très souriant]") c'est pas top.
Bon on comprend qu'en fait c'est :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

columns("B:D")

Ne faudrait-il pas mettre plutôt les numéros des colonnes ? (ça fait un bail que je n'ai pas fait de VB)

[Invité]

Bonjour,

Avec ce code cela fonctionne :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
If Not (Intersection Is Nothing) Then
'MsgBox "Dans la plage"
nb_classeur = ActiveSheet.Cells(7, 2)
Sheets("Feuil2").Columns("B:D").EntireColumn.Hidden = True
 
End If

La ligne (avant End If) :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Sheets("Feuil1").Select

devient à priori inutile.

[Gorfael]

Salut serar et le forum

Je souhaite masquer des colonnes en fonction d'un valeur presente dans une case. Feuil1 B7=3 afficher les 3 premieres colonnes de la feuille 2.

Tu est dans un module de classe lié à ta feuille : dans ce cas, les métodes SELECT et ACTIVATE ne sont autorisées que sur la feuille liée au module.
Soit tu emploies Workbook_SheetChange du module ThisWorkBook
soit tu supprimes les SELECT.

P'tites critiques de ton code :
Définir une plage pour en définir une autreme semble superflu.
Tu n'as pas de gardes-fous pour un nombre inférieur à 1 en B7
Je te conseillerais d'éviter les noms pouvant préter à confusion, ça évite les erreurs.
Ton code n'étant pas complet, je suppose que tu utilises que tu mets en variable ? le nombre.
Chez moi, ta macro donnerais à peu prés ça :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
Private Sub Worksheet_Change(ByVal Target As Range)
Dim Plage_T As Range
Dim Nb_classeur As Integer
If Intersect(Target, Range("B7")) Is Nothing Then Exit Sub
'Si la cellule B7 ne fait pas partie des cellules modifiées, sortir
If 0 < Range("B7") And Cells(7, "B") < 256 Then
'Si 0 < B7 < 256 (de 1 à 255, de B à IV)
    MsgBox "Pour les colonnes ""B:" & _
            Left(Cells(1, [B7] + 1).Address(0, 0), _
            Len(Cells(1, [B7] + 1).Address(0, 0)) - 1) & """  "
    Nb_classeur = [B7]
    Sheets("Feuil2").Columns("B:" & Left(Cells(1, [B7] + 1).Address(0, 0), _
            Len(Cells(1, [B7] + 1).Address(0, 0)) - 1)).Hidden = True
End If
End Sub

A+

[serar]

Merci pour vos réponses.