Discussion :

[Mordeth]

Bonjour à tous,

Voilà ce que je voudrais faire :
Dans un fichier contenant des colonnes (de nombres) de taille différentes, j'aurais besoin d'éliminer disons 2/3 d'une colonne en particulier (passer de 60000 à 20000 lignes)
Je ne connais presque rien à VB, mais j'avais trouvé la solution la plus évidente :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
Sub Régime
For compteur = 1 To 20000
Selection.Offset(1,0).Select
Selection.Delete
Selection.Delete
Next
End Sub

Et ça marche ... mais ça prend 2 heures, même en désactivant la mise à jour de l'écran. Quelqu'un pourrait m'indiquer une solution plus élégante et moins comsomatrice de temps ?

Merci d'avance

[Invité]

Bonsoir Mordeth,

Une 1ère possibilité :

votre fichier comprend de nombreuses formules ?

Si oui, essayez d'inclure ce code au début :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
With Application
        .Calculation = xlManual
End With

et à la fin

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
With Application
        .Calculation = xlAutomatic
End With

[LeForestier]

Ca m'étonnerai quand même qu'avec

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
For compteur = 1 To 20000
Selection.Offset(1,0).Select
Selection.Delete
Selection.Delete
Next

même après 2 heures, que cela fonctionne, à moins qu'Excel soit fatigué..
mais essaye avec

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
Range("A1:A20000").select
Selection.delete

Faut évidemment voir où tu démarre.
A+
EDIT:
ou si tu veux éliminer toute les lignes après 20000

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
    Rows("20001:60000").Select
    Selection.ClearContents

[Mordeth]

Désolé, je n'ai pas été assez clair :

@ LeForestier
je ne veux pas éliminer les 20000 premiers ou derniers points, mais 2 points sur trois. Tel quel, j'ai trop de précisions (si c'est pas malheureux ) et excel a du mal à suivre.

@jacques_jean
En l'occurence, il s'agit de valeurs expérimentales et non de formules

Merci quand même à tous les deux

[bidou]

les concours de vitesse, tout une époque

La plus lente

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
Public Sub MethodeLourde()
 
    Dim Plage As Range, compteur As Long
 
    Application.ScreenUpdating = False
    With ThisWorkbook.Worksheets(1)
        Set Plage = .Range(.Cells(1, 1), .Cells(.Rows.Count, 1).End(xlUp))
    End With
    For compteur = Plage.Rows.Count + 1 To 1 Step -3
        Plage.Rows(compteur).Offset(1).Resize(2).Delete xlShiftUp
    Next compteur
 
End Sub

La plus habituelle

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
Public Sub MethodeExcel()
 
    Dim PlageSource As Range, PlageCible As Range, compteur As Long
 
    Application.ScreenUpdating = False
    With ThisWorkbook.Worksheets(1)
        Set PlageSource = .Range(.Cells(1, 1), .Cells(.Rows.Count, 1).End(xlUp))
    End With
    Set PlageCible = PlageSource.Offset(1, 2).Resize(PlageSource.Rows.Count \ 3 - 1)
    PlageCible.Offset(-1).Resize(1).Value = PlageSource.Cells(1).Value
    PlageCible.FormulaR1C1Local = "=DECALER(L1C1;LIGNE()*2+LIGNE()-3;0)"
    PlageCible.Value = PlageCible.Value
    PlageSource.Offset(1).Delete xlShiftUp
    PlageCible.Offset(, -2).Value = PlageCible.Value
    PlageCible.Offset(-1).Resize(PlageCible.Rows.Count + 1).ClearContents
 
End Sub

La plus rapide (enfin de mon temps )

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
Public Sub MethodeTableau()
 
    Dim Plage As Range, compteur As Long, OldVals As Variant, NewVals As Variant, lgTime As Long
 
    Application.ScreenUpdating = False
    With ThisWorkbook.Worksheets(1)
        Set Plage = .Range(.Cells(1, 1), .Cells(.Rows.Count, 1).End(xlUp))
    End With
    OldVals = Plage.Value
    Plage.Delete xlShiftUp
    ReDim NewVals(1 To UBound(OldVals) \ 3, 1 To 1)
    For compteur = 1 To UBound(OldVals) Step 3
        NewVals((compteur \ 3) + 1, 1) = OldVals(compteur, 1)
    Next compteur
    Set Plage = ThisWorkbook.Worksheets(1).Cells(1, 1).Resize(UBound(NewVals))
    Plage.Value = NewVals
 
End Sub

[Mordeth]

Merci pour ta réponse, Bidou (les concours de vitesse, c'est pour les pro, je veux juste qqchose d'utilisable)
Néanmoins, tel quel, ça ne marche pas ^^
Il suffit surement d'un rien pour que ça fonctionne, alors est-ce que tu pourrais me faire de l'explication de texte ?

methode tableau
erreur d'exécution 13, incompatibilité de type
==> ReDim NewVals(1 To UBound(OldVals) \ 3, 1 To 1)

methode excel
erreur d'exécution 1004, erreur définie par l'application ou par l'objet
==> Set PlageCible = PlageSource.Offset(1, 2).Resize(PlageSource.Rows.Count \ 3 - 1)
#offset(2,1) plutôt#

methode lourde : rien ?