Discussion :

[Stéphane Olivier BERNARD]

Bonjour,

J'ai cherché à réaliser une table des matières en exploitant le code de Fabrice Constans mais je me heurte à un épineux problème à cause des doublons ...

http://loufab.developpez.com/tablemat/

En effet, le code prévoit l'écrasement des doublons.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
 
Sub fc_GenereTM(fc_Item As String, fc_Pge As Integer, fc_Typ As String)
Dim rst As Recordset
 
Set rst = CurrentDb.OpenRecordset("tbl_TableMat", dbOpenDynaset)
 
rst.FindFirst "tm_Item=""" & fc_Item & """"
 
If rst.NoMatch Then
   rst.AddNew                   ' ajout nouvel enregistrement
   rst!tm_item = fc_Item        ' écrit dans le champ
   rst!tm_page = fc_Pge
   rst!tm_type = fc_Typ
   rst.Update                       ' sauvegarde
Else
   If rst!tm_page < fc_Pge Then    ' problème signalé par
      rst.Edit
      rst!tm_page = fc_Pge         ' on met à jour la page
      rst.Update
   End If
End If
 
rst.Close                       ' ferme
 
End Sub

Cependant dans la table des matières que je souhaite réaliser des doublons existent. Comme il s'agit d'un ouvrage structuré, certains intitulés de sous chapitres ont la même dénomination bien qu'appartenant à des chapitres différents.

J'ai essayé de modifier le code mais soit mes "sous chapitres" n'apparaissent pas, soit ils apparaissent en un nombre bien supérieur à ce qu'ils devraient par rapport à l'état qui les génére, en somme je suis bloqué...


Est ce que quelqu'un a déjà opéré des modifications à ce code pour prendre en compte le cas particulier de sous "chapitres doublonnés"....

[loufab]

Bonjour,

L'écrasement des doublons permet d'avoir la fonction aperçu sans que cela perturbe la création de la table des matières.

Tu peux toujours faire un essai sans l'écrasement des doublons en enlevant la fonction d'aperçu de l'état.

Tu peux également vérifier que le sous-titre est unique en ajoutant un id unique pour les sous-titres.

Cordialement,

[mout1234]

Bonsoir,

Je n'ai pas étudié en détail le code de Fabrice mais je présume que le test (le FindFirst) a pour but de contourner les problèmes liés aux cas où une section est passée par manque de place à la page suivante (Fabrice ... si tu es là ... merci de me corriger )

Pour éviter de toucher à ce mécanisme, on peut peut être s'en sortir en ajoutant un champ à la table tbl_tableMat auquel tu devras attribuer une valeur unique pour chaque entrée de ta table des matières...


EDIT: salut Fabrice ... je fais 15 choses en même temps... du coup j'ai "un peu" trainé pour répondre

[Stéphane Olivier BERNARD]

Bonjour,

J'ai introduit un quatrieme paramètre "Niveau Sup" dans la fonction GenereChap et crée le champ Ad'hoc dans la table des "tbleMat".
J'ai remplacé le Findfirst par un Findfirst qui vérifie l'égalité entre les niveaux hierachiques des enregistrements crées dans "tbleMat" et désormais mes doublons "utiles" ne sont plus écrasés et l'aperçu de l'état toujours possible.

Merci à vous tous.

[Stéphane Olivier BERNARD]

Bonjour,

Pour être un peu plus explicite:

Dans les reports, les appels à la nlle fonction GeneChap (toujours 3 niveaux hierarchiques T/ST/I) se font par:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
 
'Ecriture du titre dans la table "Chapitrage"
Private Sub EntêteÉtat_Format(Cancel As Integer, FormatCount As Integer)
GenereChap Me.Titre.Caption, Me.Page, "T", ""
End Sub
 
'Ecriture des sous titres dans la table "Chapitrage"
Private Sub EntêteGroupe0_Format(Cancel As Integer, FormatCount As Integer)
GenereChap Me.[Fonction], Me.Page, "ST", Me.Titre.Caption
End Sub
 
'Ecriture des éléments dans la table "Chapitrage"
Private Sub Détail1_Format(Cancel As Integer, FormatCount As Integer)
GenereChap Me.[Tâche], Me.Page, "I", Me.[Fonction]
End Sub
 
Private Sub Report_Open(Cancel As Integer)
'Suppression des éléments de la table "Chapitrage"
SupprChap
End Sub

Oui, au fait "TableMat" est devenue "Chapitrage" dans ma Bdd...
Elle contient un champ supplémentaire [Niveau Sup] string

La nouvelle fonction GenereChap (plus tolérante envers les doublons utiles)

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
 
'Génération de la table "Chapitrage"
Sub GenereChap(fc_Elem As String, fc_Pge As Integer, fc_Typ As String, fc_Sup As String)
Dim rst As Recordset
 
Set rst = CurrentDb.OpenRecordset("Chapitrage", dbOpenDynaset)
 
rst.FindFirst "Elément=" & Chr(34) & fc_Elem & Chr(34) & _
                       " and [Niveau Sup]=" & Chr(34) & fc_Sup & Chr(34) & _
                       " and [Type élément]=" & Chr(34) & fc_Typ & Chr(34)
 
If rst.NoMatch Then
   rst.AddNew                   ' ajout nouvel enregistrement
   rst!Elément = fc_Elem        ' écrit dans le champ
   rst![Page N°] = fc_Pge
   rst![Type élément] = fc_Typ
   rst![Niveau Sup] = fc_Sup
   rst.Update                       ' sauvegarde
Else
   If rst![Page N°] <= fc_Pge And rst![Niveau Sup] = fc_Sup Then    ' problème signalé par
      rst.Edit
      rst![Page N°] = fc_Pge         ' on met à jour la page
      rst.Update
  End If
End If
 
rst.Close                       ' ferme
Set rst = Nothing
End Sub

Voilà, je crois que j'ai tout dit (et tout écrit)

Merci à vous tous et n'hésitez pas à poster si vous voyez une methode plus rapide, plus efficace ou plus légère.

PS le '<' est devenu '<=' car dans mon cas le pouvait '<' poser problème...