Discussion :

[Nemerle]

Yo, j'ai un petit fichier excel avec des boutons filtrant des lignes (i.e. rendant leur "Hidden" à true).

J'aimerai interdire le "glissé/laché" des colonnes dans cette WorkSheet, histoire qu'il n'y ait pas de gros patequès... sur les lignes cachées

Vous savez faire?

[flo_flo]

Bonjour,

Dans les outils de protection d'une feuille Excel, il existe une option "Interdire les ajouts de colonnes"...

Menu Outils, Protection, etc

[Nemerle]

non, non, ce n'est pas de ca dont je parle

tu prends la cellule A2 et en cliquant en bas à droite tu la glisses jusqu'en A5 histoire que ces cases prennent la valeur de A2

C'est cette "extension" que je veux interdire partout sur la feuille

[rtg57]

Si j'ai bien compris ce que tu demandes, la solution se trouve peut être dans:
Outils / Optionspuis onglet 'Modifications'.
Là tu as des cases à cocher 'Modification directe' ou 'Glissement-Déplacement de la cellule'.

[Nemerle]

A y est, j'ai tout ce qu'il faut:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
Sub DisableCopyCutAndPaste()
    EnableControl 21, False   ' cut
    EnableControl 19, False   ' copy
    EnableControl 22, False   ' paste
    EnableControl 755, False  ' pastespecial
    Application.OnKey "^c", ""
    Application.OnKey "^v", ""
    Application.OnKey "+{DEL}", ""
    Application.OnKey "+{INSERT}", ""
    Application.CellDragAndDrop = False
    Application.OnDoubleClick = ""
End Sub
 
Sub EnableCopyCutAndPaste()
    EnableControl 21, True   ' cut
    EnableControl 19, True   ' copy
    EnableControl 22, True   ' paste
    EnableControl 755, True  ' pastespecial
    Application.OnKey "^c"
    Application.OnKey "^v"
    Application.OnKey "+{DEL}"
    Application.OnKey "+{INSERT}"
    Application.CellDragAndDrop = True
    Application.OnDoubleClick = ""
End Sub
 
Sub EnableControl(Id As Integer, Enabled As Boolean)
Dim CB As CommandBar
Dim C As CommandBarControl
 
On Error Resume Next
For Each CB In Application.CommandBars
    Set C = CB.FindControl(Id:=Id, recursive:=True)
    If Not C Is Nothing Then C.Enabled = Enabled
Next
 
End Sub
 
Sub MessageInterdit()
    MsgBox "Le Copier / Coller et le clic droit sont désactivés sur ce classeur!", vbInformation, "Action interdite"
End Sub
 
Private Sub Workbook_Activate()
DisableCopyCutAndPaste
End Sub
 
Private Sub Workbook_Deactivate()
EnableCopyCutAndPaste
End Sub
 
Private Sub Workbook_SheetBeforeRightClick(ByVal Sh As Object, ByVal Target As Range, Cancel As Boolean)
Cancel = True
MessageInterdit
End Sub
 
Private Sub Workbook_SheetSelectionChange(ByVal Sh As Object, ByVal Target As Range)
Application.CutCopyMode = False
 
End Sub
 
Private Sub Workbook_WindowActivate(ByVal Wn As Window)
DisableCopyCutAndPaste
End Sub
 
Private Sub Workbook_WindowDeactivate(ByVal Wn As Window)
DisableCopyCutAndPaste
End Sub

Si ca peut servir à quelqu'un...