Discussion :

[ThonySp]

Bonjour à tous,

Je souhaite récupérer d'un fichier A des lignes qui sont à B46:AJN46 / B59:AJN59 / B72:AJN72 / B85:AJN85 / B97:AJN97. Vous avez remarqué que ces lignes se répètent par pas de 13.

Ensuite les coller par tranposage sur un fichier B aux colonnes : E10:E958 puis F10:F958 etc... (le pas ici est de 1).

Voici une partie du code :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
For I = 1 To 5
 
            m = 46 + 13 * (I - 1)
 
            'Sélectionne la plage
            Range("B" + CStr(m) + ":" + "AJN" + CStr(m)).Copy
 
            'Copie-colle la sélection sur un autre fichier
            ' Selection.Copy
 
            'Sélection de la plage réception
            Workbooks("Reception.xlsx").Activate
            Sheets("Test").Select
 
            'Conversion de la colonne
            ColR = Chr(I + 68)
 
            'Sélection de la colonne récepteur
            Range(ColR + "10:" + ColR + "958").Select
 
            'Colle par transpose
            Selection.PasteSpecial Paste:=xlPasteAll, Transpose:=True
            Application.CutCopyMode = False
 
            'Convertir les points en virgule
            Set plage = Range(ColR + "10:" + ColR + "958")
            For Each c In plage
                c.Value = Replace(c.Value, ".", ",")
            Next c
 
        Next

Le problème est que ça m'affiche :

Erreur d'exécution '1004' :
Cette sélection n'est pas valide.
Raisons possibles :
.Les zones de copie et de collage ne peuvent se superposer que si elles sont de dimension et de forme identiques.
.Si vous utilisez la commande Créer à partir de la sélection, la ligne ou la colonne contenant les noms proposés n'est pas incluse dans les (...)

La dernière phrase s'arrête là à cause du format réduit du message d'erreur.

Avez vous des idées du bug ?

Merci d'avance.

[a_diard]

Bonjour.

Il faut peut être resélectionner ton classeur d'origine à chaque next ??????

vu le message je pense que à la deuxième copie

tu colle de la feuille test vers la feuille test du classeur reception

[Menhir]

Il y a un problème d'algorithme dans ton code : tu ne donnes pas les parents (classeur et onglet) des cellules à copier ce qui fait que VBA utilise ceux par défaut. Or, plus loin dans la boucle, tu actives le classeur de destination (ce qui en fait le classeur par défaut) dans jamais revenir au classeur source.
Donc, au second tour, la copie se fait sur les cellules du classeur destination.

En plus, ton premier Copy ne sélectionne pas les cellules (il ne fait que les... copier, placer leur contenu dans le presse-papier) donc le second Copy appliqué à Selection a peu de chance de s'appliquer à ce que tu souhaites et en plus il écrase le premier.

Il y a aussi quelques autres broutilles dans la suite.

En fait, tu compliques trop ton code.
En voici une version simplifiée.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
Dim WSSource As Worksheet, WSDest As Worksheet
Dim I As Long
 
Set WSSource = ActiveSheet
Set WSDest = Workbooks("Reception.xlsx").Sheets("Test")
 
For I = 1 To 5
    WSSource.Range("B" & (33 + 13 * I) & ":AJN" & (33 + 13 * I)).Copy
    WSDest.Cells(10, 4 + I).PasteSpecial Paste:=xlPasteAll, Transpose:=True
Next I
 
Columns("E").Resize(, I - 1).Replace(".", ",")

[ThonySp]

Bonjour à tout le monde,

Effectivement c'est un problème de parent etc...

Depuis j'ai reformulé (et minimiser les Select en passant) et tout marche !!!

A présent j'ai un truc surement benêt pour vous : quand je fais tourner le macro à partir du fichier Excel (par un bouton) qui le supporte, les opérations me paraissent plus longues.

Si je fais tourner le macro à partir du codeur VBA et que le fichier Excel qui le supporte est réduit (non visible), les opérations sont plus rapides... Pourquoi cela ?

Merci d'avance !

[Menhir]

Si je fais tourner le macro à partir du codeur VBA et que le fichier Excel qui le supporte est réduit (non visible), les opérations sont plus rapides... Pourquoi cela ?

Parce que la réactialisation de l'affichage pompe une grosse partie du temps de traitement.

[ThonySp]

J'ai vu cela en parcourant les FAQ

Mais ça me fait gagner presque deux secondes (sans rafraichissement : 19'50 et avec rafraichissement : 17'80).

J'ai aussi mis :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
 
'Réduit la fenêtre Excel
Application.WindowState = xlMinimized
'Arrêt rafraichissement écran
Application.ScreenUpdating = False
 
... mon codage ...
 
'Retour rafraichissement écran
Application.ScreenUpdating = True
'Remet la fenêtre Excel
Application.WindowState = xlMaximized

Des idées pour mieux accélérer ? Sinon je vais devoir créer une copie Matlab qui est nettement plus rapide ...