Discussion :

[leons]

Salut
je suis nouveau sur le forum, je ne suis pas très doué en info et j'ai un problème en Fortran : j'essaye en fait de créer une fonction qui a pour argument un réel et un vecteur et qui retourne un vecteur mais je n'y arrive pas. Voici mon code :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
program fonction 
  real k(2),x,y(2),f
  x=1
  y(1)=2
  y(2)=3
  k=f(x,y)
  write(*,*) k
end 
  function f(r,s)
 real s(2),f(2)
  f(1)=2*s(1)*(1-s(2))
  f(2)=s(2)*(-1+s(1))
 end function

Si quelqu'un peut m'aider ce serait sympa

[Ehouarn]

Bonjour,

En Fortran, une fonction sert à renvoyer une valeur. S'il y a plus d'informations à échanger il est préférable d'utiliser des subroutines (c.f. n'importe quel cours fortran, par ex. http://fortran.developpez.com/).

Bonne continuation.

[Sylvain Bergeron]

Complément à la réponse précédente.

En F77, il n'est pas possible que le résultat d'une fonction soit un vecteur. Cette fonctionnalité a été introduite en F90.

En F90, pour retourner autre chose qu'un scalaire de type natif (real, integer,..), tu dois utiliser une interface explicite. Une interface implicite est une interface F77: le code appelant ne sait rien de l'appelé, sauf le type du résultat. Une interface explicite est fournie par un des moyens suivants :

• un module
• un interface block
• une fonction contenue dans le programme appelant

Peut-être que ton compilateur supporte déjà F90 ou plus, mais que tu n'as pas fourni d'interface. Essayes le code suivant :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
program fonction 
  implicit none
  real k(2),x,y(2)
  x=1
  y(1)=2
  y(2)=3
  k=f(x,y)
  write(*,*) k
!end   
contains
  function f(r,s)
 real s(2),f(2),r
  f(1)=2*s(1)*(1-s(2))
  f(2)=s(2)*(-1+s(1))
 end function
 end program

[genteur slayer]

sinon, une solution avec un bloc interface:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
 
program fonction 
implicit none
  real(kind=kind(1.d0)),dimension(2) :: k,y  ! deux tableaux
  real(kind=kind(1.d0))                      x     ! une valeur
interface
  function f(r,s)
    real(kind=kind(1.d0)),dimension(2) :: f
    real(kind=kind(1.d0)),dimension(2),intent(in):: s
    real(kind=kind(1.d0)),intent(in):: r
  end function f
end interface
  x=1.d0
  y(1)=2.d0
  y(2)=3.d0
  k=f(x,y)
  write(*,*) k
end program fonction  
 
function f(r,s)
  real(kind=kind(1.d0)),dimension(2) :: f
  real(kind=kind(1.d0)),dimension(2),intent(in):: s
  real(kind=kind(1.d0)),intent(in):: r
  f(1)=2.d0*s(1)*(1.d0-s(2))
  f(2)=s(2)*(-1.d0+s(1))
end function f