Discussion :

[Catalaburro]

Bonjour,

Je dispose d'une table me permettant de rentrer les consultations mensuelles de ressources. Elle est composée de trois champs :
IdRes (identification d'une ressource)
Mois (en fait le premier jour de chaque mois sous la forme 01/mm/aaaa)
Consultations (le nombre de consultations).
L'état de mise à jour est différent selon les ressources. Par exemple, pour A elle est de 12/2006, pour B de 01/2007, pour C de 12/2006...
Je voudrais bidouiller une sorte d'autoincrémentation de la date depuis un formulaire : en cliquant sur le champ "consultations" la date "mois précédent+1" s'afficherait automatiquement.
J'ai pondu ça (qui fera sans doute blêmir d'effroi plus d'un ):

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
Private Sub Consultations_Click()
Dim strsql As String
Dim Moissuiv As Date
 
Moissuiv = DateAdd("m", 1, [TConsultations].[Mois])
strsql = "INSERT Moissuiv into TConsultations.Mois"
 
DoCmd.RunSQL strsql
 
End Sub

Quelle syntaxe pourrais-je utiliser ?

D'avance merci

[LedZeppII]

Bonjour,

en supposant que
- le champ [Mois] est bien de type Date et le contrôle associé sur le formulaire porte le même nom.
- le champ IdRes est de type numérique et le contrôle associé sur le formulaire porte le même nom

Code vb :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
Private Sub Consultations_Click() 
Dim IdRes As Long
Dim Moissuiv As Date   
 
IdRes = Me.IdRes
Moissuiv = DateAdd("m", 1, [Mois]) 
' crée nouvel enregistrement dans le formulaire
DoCmd.RunCommand acCmdRecordsGoToNew
' Ecrit nouvelle date et IdRes
Me.IdRes = IdRes
Me.Dt = MoisSuiv
' Sauve enregistrement
DoCmd.RunCommand acCmdSaveRecord
End Sub

En espèrant avoir bien compris
A+

[Catalaburro]

Bonjour LedZeppII, et merci pour ta réponse,

Je pense que ta solution fonctionnerait si ma façon de procéder n'était pas aussi tordue.
Ma table se présente de cette façon :
IdRes;Mois;Consultations
A1 ;12/06; 10
A1 ;01/07; 15
A1 ;02/07; 13
A2 ;12/06; 50
A2 ;01/07; 45
A3 ;12/06; 4
A3 ;01/07; 12

Cela me permet de saisir toutes mes infos dans une seule table et, par le biais d'une requête, d'obtenir des statistiques pour chaque ressource.
Cependant, rien ne peut permettre à Access de dire quelle sera la valeur suivante d'IdRes (A3? A4? retour à A1?), c'est à l'utilisateur de le renseigner. Je voulais contourner ce problème en mettant cette table dans un sous- formulaire dont le formulaire principal est créé d'après une autre table comprenant ce même champ IdRes, ainsi que d'autres infos.
On obtient alors quelquechose du type :

IdRes : A1
Mois; Consultations
12/06; 10
01/07; 15
02/07; 13
(puis une "fiche" pour chaque IdRes)

En appliquant ton code, j'obtiens alors une "erreur 94, utilisation incorrecte de Null". Je pense en fait qu'il considère que le champ IdRes n'est pas rempli, alors que la valeur Null n'est pas autorisée.

Afin que je puisse voir aussi de mon côté sans attendre que la solution me tombe du ciel, pourrais-tu me dire à quoi correspond "Me.", qui m'a l'air d'être une instruction à tout faire ?
Merci encore

[jean-paul lepetit]

Salut, Me correspond au formulaire appelant la procédure

Me.Moncontrol = Forms!Monform!Moncontrol, si la procédure se trouve dans le formulaire MonForm

[lucienkany]

Bonjour,

Me. permet de selectionner un contrôle sur le formulaire et d'y appliquer une action

ex

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Me.Idrs.Value = #01/01/07#

Pour répondre à ta question, moi j'ai une méthode assez tordue aussi;

J'utilise SérieDate pour déterminer le premier et le dernier jour du mois en cours

ex dans uns zone de texte ; valeur par défaut

=SérieDate([ANNEE];[MOIS];1) pour le premier jour

et dans un autre
=SérieDate([ANNEE];[MOIS]+1;1)-1 pour le dernier jour

Notes que [ANNEE] est une zone de texte cachée dont la source est

=Année([today])

et que [MOIS] est une zone de texte cachée dont la source est

=Mois([today]) Valeur par défaut =Date()-1

Bien à toi

[LedZeppII]

Bonjour,

Effectivement avec un sous-formulaire c'est plus pareil.

Dans le code ci-après la table s'appelle tblIdResConsult, elle a :
-un champ IdRes (Texte)
-un champ Mois (Texte) associé à un contrôle Mois
-un champ Consultations associé à un contrôle Consultations

Le code se déclenche sur double-click dans Consultations

Code vb :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
Private Sub Consultations_DblClick(Cancel As Integer)
Dim dtMoissuiv As Date, dtMois As Date
Dim strMoisSuiv As String, varLkup As Variant
 
If Not (Nz(Me.Mois) Like "??/??") Then Exit Sub
 
' Date pour le 1er du mois
dtMois = DateSerial(CInt("20" & Mid(Me.Mois, 4, 2)), _
                    CInt(Mid(Me.Mois, 1, 2)), 1)
' Ajouter un mois
dtMoissuiv = DateAdd("m", 1, dtMois)
strMoisSuiv = Format(dtMoissuiv, "mm/yy")
' Recheche si IdRes + Mois existent déjà
varLkup = DLookup("IdRes", "tblIdResConsult", "IdRes='" & Me.IdRes & "'" & _
                  " AND Mois='" & strMoisSuiv & "'")
' Si mm/aa n'existe pas déjà
If IsNull(varLkup) Then
   ' Créer nouvel enregistrement dans formulaire actif (le sous-formulaire)
   DoCmd.RunCommand acCmdRecordsGoToNew
   ' Remplir contrôle Mois
   Me.Mois = strMoisSuiv
   ' Sauver engerigtrement
   DoCmd.RunCommand acCmdSaveRecord
   Me.Consultations.SetFocus
End If
 
End Sub

Me fait référence au formulaire qui exécute le code.
Me.Mois et Me.Consultations font donc référence au contrôles Mois et Consultations du formulaire (et pour l'enregistrement en cours).

Nz(Me.Mois) renvoie une chaîne vide ("") si le champ est vide (Null).

Il faut que tu adaptes le code avec les noms de table, champs, contrôles que tu utilises.

Bon courage.