[VBA-E] Graphiques : dimensionnement/placement

**WagaSeb** · 02/02/2007, 09h08

Bonjour à tous,

Dans une de mes macros, j'ai besoin de créer un grand nombre de minigraphs.
Ces graphs doivent etre positionnés et dimensionnés.
Mais je n'arrive pas à placer/dimensionner car je butte :
.top ou autre ne fonctionne pas avec ActiveChart
Est ce que quelqu'un peut m'aider ?

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
Charts.Add
ActiveChart.Location _
    Where:=xlLocationAsObject, Name:="Bilan"
With ActiveChart
    .SetSourceData Range("B18:D20")
    .HasTitle = True
    .ChartType = xlColumnClustered
    .HasLegend = False
    .ApplyDataLabels Type:=xlDataLabelsShowValue
    .Axes(xlCategory).TickLabels.Orientation = xlHorizontal
    .ChartTitle.Font.Bold = True
    .ChartTitle.Font.Size = 12
    .PlotArea.Top = 0
    .PlotArea.Top = 20
    .PlotArea.Top = 100
    .PlotArea.Height = 300
    .Axes(xlValue).MaximumScale = 20
    '.Selection.Top = 200
    .ChartObjects.
    .Deselect
End With

Tant que j'y suis,

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

.Axes(xlValue).MaximumScale = Automatic

me donne une échelle abérante. Pourquoi ?

Merci d'avance
PS : Les questions me semblent idiotes mais je n'ai rien droivé pouvant m'aider ds les forums ...

**WagaSeb** · 02/02/2007, 09h44

C'est encore moi ...
En fait j'arrive à redimensionner et déplacer mon graph avec le code suivant :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
ActiveSheet.Shapes("Graphique 657").ScaleWidth 0.47, msoFalse, _
        msoScaleFromTopLeft

Le problème c'est que j'ai beaucoup de graph différents et que les noms changent.
Donc 2 solutions :
-Imposer le nom (je n'y arrive pas mais travaille dans cette voie)
-Utiliser la solution Activechart ...

Voila, c'était pour etre plus explicite ...
Je reste quand meme en attente d'une personne pouvant m'aider
Merci d'avance

**SilkyRoad** · 02/02/2007, 18h14

bonjour

j'espère que ces infos pourront t'aider

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
Dim NbGraph As Byte
 
Charts.Add 'ajout graphique
With ActiveChart
    .ChartType = xlLine
    .SetSourceData Source:=Sheets("Feuil1").Range("A1:B10"), PlotBy:=xlColumns
    .Location Where:=xlLocationAsObject, Name:="Feuil1"
End With
 
'compte le nombre de graphiques dans la feuille
NbGraph = ActiveSheet.ChartObjects.Count
'le nouveau graphique correspond à l'index le plus élevé
ActiveSheet.ChartObjects(NbGraph).Name = "Le nom du Graphique"
 
'repositionne et redimensionne e graphique
With ActiveSheet.ChartObjects("Le nom du Graphique")
    .Left = Range("E10").Left
    .Top = Range("E10").Top
    .Width = Range("E10:I10").Width
    .Height = Range("E10:E25").Height
End With

bon week end
michel

**WagaSeb** · 05/02/2007, 09h54

Génial !!

Je voulais à la base éviter de donner un nom au graph et placer le positionnement ds la commande With / End With

Encore une dernière question : j'essaye de remplacer le "Range("D16).top" par "Cells(16,4).top et ca me produit une erreur ... Pourquoi et comment faire ?
Merci