[VBA-Excel]Probleme Mailing via Excel

**Mugette** · 06/10/2006, 17h58

Bonjour,

Voici mon probleme:
Je rentre plusieurs parametres dans ma feuille1(titre, listedif,...)
Je genere un modele de contenu de mail dans ma feuille2.
Je voudrais copier la range "model" de la feuille 2 dans le body du mail.
est-ce possible ?
Voici le code que j'utilise qui marche pas...

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
Dim textMail As String, lorigine As String, adresseMail As String, lesujet As String, retour As Integer

Function mail(adresse As String, sujet As String, myrange As String, origine As String)
' Fonction de mail

        Set MonOutlook = CreateObject("Outlook.Application")
        Set MonMessage = MonOutlook.CreateItem(0)
        'MonMessage.From = origine
        MonMessage.To = adresse
        MonMessage.Subject = sujet
        'MonMessage.Body =message
        Worksheets("Feuil2").range(myrange).Paste Destination:=Body
        MonMessage.Send

End Function

Voici comment je l'appelle :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
 
Private Sub CommandButton1_Click()
    Dim textMail As String, lorigine As String, adresseMail As String, lesujet As String, retour As Integer
    textMail = "A1:I30"
    adresseMail = "kiki@koko.fr"
    lesujet = "sujet du mail"
    retour = mail(adresseMail, lesujet, textMail, lorigine)
End Sub

Ce code plante à la ligne :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Worksheets("Feuil2").range(myrange).Paste Destination:=Body

Message d'erreur --> Ppté ou méthode non géré par cet objet.

Merci à vous

**SilkyRoad** · 06/10/2006, 19h42

bonsoir

j'espere que cette adaptation pourra t'aider

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
Private Sub CommandButton1_Click()
    Dim textMail As String, Lorigine As String
    Dim adresseMail As String, leSujet As String
    Dim Retour As Integer
 
    textMail = "A1:I30"
    adresseMail = "kiki@koko.fr"
    leSujet = "sujet du mail"
 
    Retour = mail(adresseMail, leSujet, textMail, Lorigine)
End Sub
 
 
Function mail(Adresse As String, Sujet As String, myRange As String, _
    Origine As String)
    ' Fonction de mail
    Dim strHTML As String
    Dim i As Byte, j As Byte
    Dim MonOutlook As Object
    Dim MonMessage As Object
 
    strHTML = ""
    strHTML = strHTML & "<HEAD>"
    strHTML = strHTML & "<BODY>"
    strHTML = strHTML & "<TABLE BORDER>"
 
    For i = 1 To Range(myRange).Rows.Count 'nombre de lignes
        strHTML = strHTML & "<TR halign='middle'nowrap>"
        For j = 1 To Range(myRange).Columns.Count 'nombre de colonnes
            strHTML = strHTML & _
            "<TD bgcolor='yellow'align='center'><FONT COLOR='blue'SIZE=3>" _
                    & Cells(i, j) & "</FONT></TD>"
        Next j
        strHTML = strHTML & "</TR>"
    Next i
 
    strHTML = strHTML & "</TABLE>"
 
    strHTML = strHTML & "<BR><BR>Cordialement<BR>" & Environ("username")
    strHTML = strHTML & "</BODY>"
    strHTML = strHTML & ""
 
    Set MonOutlook = CreateObject("Outlook.Application")
    Set MonMessage = MonOutlook.CreateItem(0)
    'MonMessage.From = origine
    MonMessage.To = Adresse
    MonMessage.Subject = Sujet
    'MonMessage.Body =message
    MonMessage.HTMLBody = strHTML
    'MonMessage.Display
    MonMessage.Send
 
End Function

bon week end
michel

**Mugette** · 09/10/2006, 14h08

merci michel.
ca marche nickel.
j'ai plus qu'a mettre ma propre mise en forme du html et c'est good.
j'avais un truc ressemblant mais je passais par un fichier temporaire et la ca plantait au moment de le publier.

Merci encore.
Ciao

[VBA-Excel]Probleme Mailing via Excel

Macros et VBA Excel

Vue hybride

Discussions similaires

Partager

Partager