Discussion :

[CalatheaWF]

Bonjour,

Je cherche un code qui me permet de remplir mes cellules vides comme si je faisais un ctrl+D. Si je fait un enregistrement de macro ça donne ça :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
    Cells.Find(What:="", After:=ActiveCell, LookIn:=xlFormulas, LookAt:= _
        xlPart, SearchOrder:=xlByRows, SearchDirection:=xlNext, MatchCase:=False _
        , SearchFormat:=False).Activate
    Selection.FillRight

Seulement je ne sais pas gérer les boucles (loop).
Après recherches j'ai pu trouver des bouts de codes :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
    Sheets("Report").Select
 
    'Renvoi le numéro de la dernière ligne avec du contenu (part du bas de la feuille, dernière ligne (1 048 576) et remonte jusqu'à la première cellule avec du contenu.
lastRow = Cells(Rows.Count, 2).End(xlUp).Row
 
'Boucle de la ligne 2 à la dernière ligne remplie de la colonne B
For i = 2 To lastRow
 
'Si La cellule Ai est vide, Ci conserve la valeur précedente, si elle est pleine on récupère la valeur de Ai
    If Cells(i, 1).Value = "" Then
    Cells(i, 3).Value = Cells(i - 1, 3).Value
    Else:  Cells(i, 3).Value = Cells(i, 1).Value
    End If
Next i

Mais je n'ai pas trouver comment l'adapté exactement parce que là, il me semble qu'il duplique la ligne vers le bas.
Voilà le type de données que j'ai :

Je veux que tout ce qui est vide prenne la valeur non vide la plus à gauche. Ca jusqu'en bas du tableau.
Bémol sur le fait que le tableau peux aller de la colonne AF à AI en fonction du nombre de jour dans le mois, si ça change quelque chose au code ou pas..

Par avance merci pour votre aide

[Franc]

Salut, comme ceci:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
Sub RemplirCellulesVides()
    Dim PlageTotale As Range
    Dim PlageVides As Range
    Dim Cellule As Range
 
    Set PlageTotale = Range("A1:J10") ' Remplacez "A1:J10" par la plage souhaitée
 
    ' Sélectionner uniquement les cellules vides de cette plage
    On Error Resume Next
    Set PlageVides = PlageTotale.SpecialCells(xlCellTypeBlanks)
    On Error GoTo 0
 
    ' Vérifier si la plage contient des cellules vides
    If Not PlageVides Is Nothing Then
        For Each Cellule In PlageVides
            ' Remplir la cellule vide avec la valeur de la cellule à gauche
            Cellule.Value = Cellule.Offset(0, -1).Value
        Next Cellule
    Else
        MsgBox "Aucune cellule vide dans la plage spécifiée.", vbInformation
    End If
End Sub

[Invité]

Un truc du genre :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
Dim lastRow, cVide
Application.ScreenUpdating = False
With Sheets("Report")
  lastRow = .Cells(Rows.Count, 1).End(xlUp).Row
  On Error GoTo Fin
  For Each cVide In .Range("B2:AH" & lastRow).SpecialCells(xlCellTypeBlanks)
     cVide.Value = .Cells(cVide.Row, 1).Value
  Next
Fin:
End With
Application.ScreenUpdating = True

[CalatheaWF]

rMist2024 du coup ça écrit ce que j'ai en colonne A de la ligne sur laquelle ça écrit, et non la première cellule remplie à gauche (ça aurait donc du écrire S1) :


Franc c'est parfait !!
Est-il possible de définir plutôt le tableau que de faire par plage ? Aujourd'hui j'ai 75 lignes mais demain ça pourrait évoluer. Il faudrait que ça prenne de la colonne E jusqu'en bout de tableau (à droite) et jusqu'en bas

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
    ' Définition de la plage
    Set PlageTotale = Range("E2:AI75")

[tototiti2008]

Bonjour,

oui, remplacer

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Set PlageTotale = Range("E2:AI75")

par

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Set PlageTotale = Listobjects("MonTableau").databodyrange

[Franc]

Si tu travailles avec un tableau structuré, la solution de tototiti2008 est la bonne, si ce n'est pas le cas, voici une autre solution:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
Sub RemplirCellulesVides()
    Dim DerniereLigne As Long
    Dim DerniereColonne As Long
    Dim PlageTotale As Range
    Dim PlageVides As Range
    Dim Cellule As Range
 
    ' Identifier la dernière ligne et dernière colonne à partir de E2
    DerniereLigne = Cells(Rows.Count, "E").End(xlUp).Row
    DerniereColonne = Cells(2, Columns.Count).End(xlToLeft).Column
 
    ' Définir la plage dynamique de E2 à la dernière cellule en bas à droite
    Set PlageTotale = Range("E2", Cells(DerniereLigne, DerniereColonne))
 
    ' Sélectionner uniquement les cellules vides de cette plage
    On Error Resume Next
    Set PlageVides = PlageTotale.SpecialCells(xlCellTypeBlanks)
    On Error GoTo 0
 
    ' Vérifier si la plage contient des cellules vides
    If Not PlageVides Is Nothing Then
        For Each Cellule In PlageVides
            ' Remplir la cellule vide avec la valeur de la cellule à gauche
            Cellule.Value = Cellule.Offset(0, -1).Value
        Next Cellule
    Else
        MsgBox "Aucune cellule vide dans la plage dynamique.", vbInformation
    End If
End Sub

[CalatheaWF]

C'est parfait, merci à tous !!