Discussion :

[facteur]

Bonjour
Je viens vers vous pour enrichir mon code vba sur l'extraction de données d'un tableau Excel.
Je précise que ce tableau n'est pas le mien . C'est un tableau que je recois tous les matin.

Ce tableau contient plusieurs colonne dont certaines sans entetes. Et j'aimerais renommer ces colonnes en fonctions des données qui s'y trouvent.
Par exemple:
Si une colonne contient uniquement des nombre alors je nommerai cette colonne "donnees"
Si une colonne contient des a la fois du texte et des nombre (alphanumerique) alors que je nommerai cette colonne " NOM"
ect.. jusquà la dernier colonne du tableau

Mon code commencerait ainsi

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
With ActiveWorkbook.Worksheets("feuil1")
Dim PlageColonne As Range
Set Plagecolonne = .Range("A1").CurrentRegion

ensuite je bloque .

Un coup de main serait le bienvenu

[BENNASR]

Bonjour
dans l'hypothèse ou la ligne 1 est vide pour insérer "Donnée" ou "nom" et que les données commence depuis la ligne 2 tu peux tester ce bricolage avec prudence

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
Sub VérifIerMembres()
Application.ScreenUpdating = False
    Dim Cellule As Range, Plage As Range
    Dim nbLignes As Long, nbColonnes As Long
    nbColonnes = Cells.Find("*", , , , xlByColumns, xlPrevious).Column
     For C = 1 To nbColonnes
     nbLignes = Cells(Rows.Count, C).End(xlUp).Row
     For i = 2 To nbLignes
        If IsNumeric(Cells(i, C)) Then X = X + 1
    Next i
    If X = i - 2 Then Cells(1, C) = "Donnée" Else Cells(1, C) = "NOM"
    X = 0
    Next C
Application.ScreenUpdating = True
End Sub

[Franc]

Bonjour, une variante de la macro de BENNASR (que je salue) qui devrait être plus rapide en cas de grand nombre de lignes car je ne vérifie pas forcément toutes les cellules d'une colonne.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
Sub VérifIerMembres()
    Application.ScreenUpdating = False
    Dim nbLignes As Long, nbColonnes As Long
    Dim ColonneNum As Boolean
    Dim C As Long, i As Long
 
    nbColonnes = Cells.Find("*", , , , xlByColumns, xlPrevious).Column
 
    For C = 1 To nbColonnes
        nbLignes = Cells(Rows.Count, C).End(xlUp).Row
        ColonneNum = True  ' On part du principe que la colonne est numérique
 
        For i = 2 To nbLignes
            If Not IsNumeric(Cells(i, C)) Then
                ColonneNum = False
                Exit For  ' On arrête dès qu'on trouve une valeur non numérique
            End If
        Next i
 
        ' Mise à jour du titre de la colonne
        If ColonneNum Then
            Cells(1, C).Value = "Donnée"
        Else
            Cells(1, C).Value = "NOM"
        End If
    Next C
 
    Application.ScreenUpdating = True
End Sub

[BENNASR]

Très bien vu franc .. bravo 👍👍 inutile de continuer la vérification si cellule n est pas un nombre