Discussion :

[JLuc69]

Bonjour le groupe,

Ca fait déjà pas mal de temps que je ne suis pas venu, mais j'aurais besoin de vous.

Dans un fichier .ini que je récupère d'une machine, j'ai plein d'infos dont je me débarrasse pour ne garder que quelques ligne.
Mais dans ces quelque lignes, je voudrais ne récupérer qu'une partie du texte :

Dans la cellule, j'ai :
$TC_TP2[113]="6T20MEKC"

Je voudrais récupérer juste cette valeur :
6T20MEKC

J'ai fais une macro pour purger ce qui ne me va pas, mais pour tronquer la valeur, j'ai tenté une regex mais sans succès

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
Sub Purge()
    Set regex_nom = New RegExp
 
    dernier_ligne = Sheets("TO_INI").Cells(65000, 1).End(xlUp).Row
    For x = dernier_ligne To 1 Step -1
        If (Left(Sheets("TO_INI").Cells(x, 1), 8) <> "$TC_TP2[") Then
            Sheets("TO_INI").Cells(x, 1).Delete Shift:=xlUp
        Else
            regex_nom.Pattern = "=.(.*)."
            Set Nom_outils = regex_nom.Execute(Sheets("TO_INI").Cells(x, 1))
            For Each Nom_outil In Nom_outils
                Nom = Nom_outil.Value
            Next Nom_outil
            Sheets("TO_INI").Cells(x, 4) = Nom
        End If
    Next
End Sub

Est il possible qu'une âme charitable me vienne en aide ?
Merci d'avance
JLuc

[deedolith]

Salut,

As-tu essayé avec la regex suivante ?

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

"([A-Z\d]+)"

Tu peux faire des simulations ici:
https://regex101.com/

[JLuc69]

J'ai essayé avec un truc de ce genre : regex_nom.Pattern = ".*"(.*)""
Mais il y a erreur avec les doubles cote (")
du coup, je ne sais pas comment gérer ça
En mettant un espion sur la variable Nom_outil et avec le pattern dans ma macro plus haut, en dépliant j'ai [item 1] qui contient le texte que je veux, mais je ne sais pas comment l'atteindre

[joe.levrai]

Bonjour,


exemple sur la cellule active

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

t = Split(ActiveCell.Value, """")(1)

[jurassic pork]

Hello,
voici une macro qui utilise une regex qui capture ce qui est entre guillemets dans les cellules d'une plage et qui met le résultat dans la cellule à côté :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
Sub FiltreRegex()
   Dim ws As Object, Rng As Object, regex As Object, matches As Object, cell As Object
   Dim pattern As String
    Set ws = ThisWorkbook.Sheets("FeuilJLuc") '
    Set Rng = ws.Range("A1:A2") '
    Set regex = CreateObject("VBScript.RegExp")
    pattern = """(.*)"""        ' on capture ce qui est entre guillemets
    regex.pattern = pattern
    For Each cell In Rng
        On Error GoTo Nextcell
        Set matches = regex.Execute(cell.Value)
        Debug.Print matches(0).submatches(0)
        cell.Offset(0, 1).Value = matches(0).submatches(0)
Nextcell:
    Next cell
 End Sub

Dans le cas présent la solution avec regex ne s'impose pas et la solution à joe.levrai est suffisante.

Ami calmant, J.P

[deedolith]

A l'intérieur d'une chaines, les doubles cottes doivent être échappée, ou doublée car la double cotte est aussi le caractère d'échappement en VB.
Quelques exemples:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
Dim Data As String
Data = "chaine avec "" à l'intérieur"    '// On double la double quote au milieu de la chaine
Data = """ double cotte au début"
Data = "Double cotte a la fin"""
Data = """"    '// double cotte seule

Ta regex peut fonctionner, mais comme .* capture tout et n'importe quoi, assures-toi qu'elle ne soit pas trop naïve.
Perso, je préfère être le plus restrictif possible.