Discussion :

[xXxWALTER WHITExXx]

Bonjour à tous,

Je vais essayer d'être le plus clair possible....j'aurais besoin d'une formule qui me calculerais le nombre de jours entre 2 dates (en tenant compte des jours ouvrés et fériés). jusque la c'est plutot simple...la complexité arrive :
Exemple :
Je souhaiterais savoir du
17/02/2023 au 22/02/2023 combien de jours au 1er trimestre
17/02/2023 au 28/04/2023 combien de jours au 1er et 2eme trimestre
17/02/2023 au 15/08/2023 combien de jours au 1er, 2eme et 3 eme trimestre
17/02/2023 au 28/11/2023 combien de jours dans le 1er trimestre, dans le second, le 3eme et le dernier trimestre

j'ai des milliers de lignes avec des dates donc dans l'Ideal il me faudrait 4 formules à double cliquer (une par trimestre)
....
j'espère avoir été assez clair
Le but est de savoir combien de jour la personne a été arrêté au 1er trimestre, au second etc...sur une période donnée !
merci pour votre aide !

[Raccourcix]

Bonjour

pour le Trimestre 1

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=NB.JOURS.OUVRES(MAX([@[Date Début abs]];DATE(2024;1;1));MIN([@[Date fin abs]];DATE(2024;3;31));Jours_Fériés)

avec Jours_Fériés une plage contenant les jours fériés de l'année et en considérant que les données sont sous forme de tableau structuré.

A adapter pour les autres trimestres

Stéphane

[Pierre Dumas]

Bonjour

J'avais prévu de poster quasiment la même chose que Raccourcix, mais je n'ai pas eu le temps ce matin.
Ma seule différence était que pour l'année de la fonction DATE, je la déduisais de l'année de la date de début.

Et tout pareil pour mettre les données et les jours fériés sous forme de Tableau Structuré.

On est donc (au moins) deux à penser pareil, cela ne doit donc pas être loin de la vérité

En espérant que cela aide

Pierre Dumas

[xXxWALTER WHITExXx]

Bonjour ,
Je vous remercie pour votre retour mais cela ne fonctionne pas du moins cela devrait mais j'ai du mal avec les caractères @ les crochets etc....vous serait il possible de mettre la formule avec colonne et ligne ? ppur trimestre 1 par exemple...

Bonjour

pour le Trimestre 1

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=NB.JOURS.OUVRES(MAX([@[Date Début abs]];DATE(2024;1;1));MIN([@[Date fin abs]];DATE(2024;3;31));Jours_Fériés)

avec Jours_Fériés une plage contenant les jours fériés de l'année et en considérant que les données sont sous forme de tableau structuré.

A adapter pour les autres trimestres

Stéphane

[Nain porte koi]

Si ça ne fonctionne pas c'est que vous n'avez pas un tableau structuré et c'est vraiment dommage car ça simplifie ENORMEMENT de choses et pas besoin de dupliquer la formule sur des milliers de lignes, c'est automatique

Autrement : remplacez les [@[Date début abs]] par l'adresse de la cellule et ajouter une plage nommé "Jours_Fériés" contenant les jours féries

PS : plutôt qu'une image qui oblige le répondeur à recréer votre tableau pour tester sa formule, un fichier d'exemple est plus facile pour vous répondre selon ce que vous avez fait réellement avec

[Pierre Dumas]

Bonsoir

La solution dans la pièce jointe : Exemple pour formule.xlsx

Exemple pour le trimestre 2 :

Code formule :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
=SI(OU([@[Date Début abs.]]>DATE(ANNEE([@[Date Début abs.]]);6;30);[@[Date Fin abs.]]<DATE(ANNEE([@[Date Début abs.]]);4;1));
0;
NB.JOURS.OUVRES(MAX([@[Date Début abs.]];DATE(ANNEE([@[Date Début abs.]]);4;1));MIN([@[Date Fin abs.]];DATE(ANNEE([@[Date Début abs.]]);6;30));Tableau2[JOURS FERIES]))

J'ai rajouté des SI pour les trimestres 2, 3 et 4 afin d'éviter les nombres négatifs.
On pourrait améliorer les formules en utilisant la fonction LET afin de mettre en variable les dates de début et fin de période.

Sinon, concernant les @ et les [, on ne les tape pas au clavier.
Comme vous êtes en tableau structuré, quand on est en cellule R2 par exemple, que l'on démarre une formule et que l'on clique sur la cellule D2, Excel met tout seul [@[Date Début abs.]].

Le premier crochet indique : dans ce tableau
Le @ signifie : sur cette ligne
le deuxième crochet n'est présent que parce que le titre de colonne comporte des espaces.

En espérant que cela aide

Pierre Dumas

[xXxWALTER WHITExXx]

Merciiiiiii beaucoup c'est parfait !!!!!!!