Discussion :

[adngft]

Bonjour à la communauté,

Je mets ici mon premier post, soyez indulgeant !

Voila j'essaie de me créer un tableur qui me permet, via un Userform, d'exporter les feuilles sélectionnées vers Word. Le soucis, c'est que je m'aperçois que lorsque je sélectionne plusieurs feuilles, j'ai l'impression qu'il copie/colle la première feuille, puis "efface" et recolle par dessus la deuxième feuille sélectionnée.

En fait, j'aimerais que le contenu des feuilles sélectionnées soit coller à la suite sur le document Word...J'espère avoir été clair dans mes explications.

Je précise que ce sont mes tout premiers codes VBA, ne soyez pas trop sévère avec moi

Si vous avez d'autres idées ou techniques afin de rédiger un rapport à partir d'Excel, ou même des tableurs, je suis preneur !

Merci à tous ceux qui aident au quotidien, vous êtes parfais les gars et j'espère pouvoir le faire à mon tour un jour.

Prenez soin de vous

[E KERGRESSE]

Bonjour,

J'ai ajouté une checkbox sur l'usf pour indiquer s'il faut faire un saut de page entre les contenus.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
 
Private Sub ExporterFeuillesVersWord()
    ' Exporte les feuilles sélectionnées vers Word
 
    Dim ObjWord As Object 'Word.Application
    Dim WordDoc As Object 'Word.Document
    Dim WordSelect As Object 'Word.Selection
 
    Dim Feuille As Worksheet
    Dim I As Integer
    Dim Cell As Range
    Dim Contenu As String
 
    ' Vérifier si Word est ouvert
    On Error Resume Next
    Set ObjWord = GetObject(, "Word.Application")
    On Error GoTo 0
 
    If ObjWord Is Nothing Then
        ' Si Word n'est pas déjà ouvert, le démarrer
        Set ObjWord = CreateObject("Word.Application")
        ObjWord.Visible = True ' Vous pouvez changer cela en fonction de vos besoins
    End If
 
    Set WordDoc = ObjWord.Documents.Add
    Set WordSelect = ObjWord.Selection
 
 
    ' Exporter chaque feuille sélectionnée vers Word
    For I = 0 To ListBoxFeuilles.ListCount - 1
 
        If ListBoxFeuilles.Selected(I) Then
 
            Set Feuille = ThisWorkbook.Sheets(ListBoxFeuilles.List(I))
            ' Construire le contenu à partir des cellules de la feuille
            For Each Cell In Feuille.UsedRange
                Contenu = Contenu & Cell.Value & vbTab ' Utilisez un tableau pour séparer les cellules
            Next Cell
 
            With WordSelect
                 .Text = Contenu
                 .InsertParagraphAfter
                 .EndKey unit:=6, Extend:=0
                 If CheckBoxSautDePage Then .InsertBreak Type:=7
            End With
            Contenu = "" ' Réinitialiser le contenu
            Set Feuille = Nothing
 
        End If
 
    Next I
 
    ' Nettoyer
    Set ObjWord = Nothing: Set WordDoc = Nothing: Set WordSelect = Nothing
    Unload Me
 
End Sub

[adngft]

Bonjour,

Super E KERGRESSE, je te remercie beaucoup !!

Que penses tu de mon code VBA sinon? Aurais tu fais différemment?

Bonne journée,

[E KERGRESSE]

Bonjour,

La réponse est dans mon code. Dans Word, l'objet Sélection a beaucoup d'importance, c'est pour cela que j'ai remplacé ton WordRange par la variable WordSelect.
Sinon, le code qui vient mettre à jour le document Word aurait été dans un module standard et l'initialisation du userform aurait été dans la procédure de lancement dans le module standard, mais là il s'agit seulement d'une habitude.

Cordialement.

[adngft]

D'accord merci pour ce retour.

Merci beaucoup de m'avoir aidé aussi.

En revanche, sais-tu s'il y à possibilité de garder la mise en forme du tableur lorsque l'opération "copier/coller" est réalisée? Car finalement il n'y à juste un copier coller du texte mais la mise en forme disparait sur Word. As-tu une idée de ce que je devrais modifier pour maintenir la mise en page lors de l'export?

Bonne journée, merci

[E KERGRESSE]

Au lieu de prendre le contenu, il faut copier les cellules :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
Private Sub ExporterFeuillesVersWord()
    ' Exporte les feuilles sélectionnées vers Word
 
    Dim ObjWord As Object
    Dim WordDoc As Object
    Dim WordSelect As Object
 
    Dim Feuille As Worksheet
    Dim I As Integer
    Dim Cell As Range
 
    ' Vérifier si Word est ouvert
    On Error Resume Next
    Set ObjWord = GetObject(, "Word.Application")
    On Error GoTo 0
 
    If ObjWord Is Nothing Then
        ' Si Word n'est pas déjà ouvert, le démarrer
        Set ObjWord = CreateObject("Word.Application")
        ObjWord.Visible = True ' Vous pouvez changer cela en fonction de vos besoins
    End If
 
    Set WordDoc = ObjWord.Documents.Add
    Set WordSelect = ObjWord.Selection
 
 
    ' Exporter chaque feuille sélectionnée vers Word
    For I = 0 To ListBoxFeuilles.ListCount - 1
 
        If ListBoxFeuilles.Selected(I) Then
 
            Set Feuille = ThisWorkbook.Sheets(ListBoxFeuilles.List(I))
            ' Construire le contenu à partir des cellules de la feuille
            Feuille.UsedRange.Copy
            With WordSelect
                 .Paste
                 .InsertParagraphAfter
                 .EndKey unit:=6, Extend:=0
                 If CheckBoxSautDePage Then .InsertBreak Type:=7
            End With
            Contenu = "" ' Réinitialiser le contenu
            Set Feuille = Nothing
 
        End If
 
    Next I
 
    ' Nettoyer
    Set ObjWord = Nothing: Set WordDoc = Nothing: Set WordSelect = Nothing
    Unload Me
 
End Sub