Discussion :

[mlww]

bonjour,
je désirais remplir une listbox dans un userform avec un tableau filtrée

Le code suivant fonction bien, mais pas sur les filtres
mais je n'ai pas arrivé a trouvé
j'ai cherche aussi du coté de SpecialCells(xlCellTypeVisible)
si quelqu'un aurait une idée
merci d'avance

Private Sub UserForm_Initialize()
Dim MonTableau As ListObject
Set MonTableau = Worksheets("Country").ListObjects("Tableau1")
With Me.ListBox1
.ColumnHeads = True
.ColumnCount = MonTableau.ListColumns.Count
.ColumnWidths = "85;40;50;50;70;70"
.RowSource = MonTableau.DataBodyRange.Address
End With
End Sub

[Philippe Tulliez]

Bonjour,
Voici une fonction générique qui charge les lignes visibles d'un objet Range dans un ListBox

Code de la fonction nommée LoadVisibleRows

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
Function LoadVisibleRows(oListBox As MSForms.ListBox, oRange As Range)
  ' Charge les lignes visible de oRange dans un oListBox
  ' Philippe Tulliez (www.magicoffice.be)
  ' Déclaration
  Dim Row As Range
  Dim Col As Range
  Dim c As Integer
  '
  With oListBox
   For Each Row In oRange.Rows
    If Row.Hidden = False Then
      .AddItem   ' Ajouter un nouvel élément
      c = 0
      For Each Col In Row.Cells
        .List(.ListCount - 1, c) = Col.Value
        c = c + 1
      Next
    End If
   Next
  End With
  Set Row = Nothing: Set Col = Nothing
End Function

Exemple d'un code qui l'invoque

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
Sub t()
  Const TableName As String = "t_Facturier" ' Nom du tableau
  Dim Rng As Range
  Set Rng = Range(TableName)
  '
  With UserForm1
   With .ListBox1
   .Clear
   .ColumnCount = Rng.Columns.Count
   .ColumnWidths = GetColumnWidths(oRange:=Rng)     ' Voir lien du billet
   End With
   LoadVisibleRows oListBox:=.ListBox1, oRange:=Rng ' Charge les lignes visibles
  .Show
  End With
  '
  Set Rng = Nothing
End Sub

Lien du billet : à propos de la fonction GetColumnWidths

Illustration

[mlww]

Bonsoir Monsieur Philippe

Merci infiniment pour ces codes, je vais les tester ce soir