Discussion :

[frunch]

Bonjour à tous,
J'ai une page de recettes qui reprend leurs ingredients, ce qui fait plusieurs fois des lignes pour la même recette.
J'ai aussi plusieurs recettes qui commencent par les premiéres lettres, comme omelette au lard, champignons...
Pour diriger l'utilisateur sur la 1ere ligne d'une recette, j'ai pris une listbox qui me filtre les recettes sur les 1eres lettres. Cà fonctionne.
Mais pas de sélection, çà l'affiche juste dans la barre de formule, sans y aller.
Auriez-vous une idée ?
Merci
forum.xlsm

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
     Dim drl3%, i%, ws1 As Worksheet, cpt%
    Application.ScreenUpdating = False
    Set ws1 = Sheets("Repas")
    drl1 = ws1.Range("A" & Rows.Count).End(xlUp).Row
    For i = 2 To drl1
        For j = 0 To Me.LisRec.ListCount - 1
             If Me.LisRec.Selected(j) And ws1.Range("A" & i).Value = Me.LisRec.List(j, 0) Then
                Sheets("Repas").Activate
                Range("A" & i).Select
                Exit For
             End If
        Next j
    Next i
    Unload Me
    Application.ScreenUpdating = True

[Franc]

Bonjour, j'ai testé et ton code fonctionne, simplement si la cellule sélectionnée se situe sur une ligne située plus bas que la dernière ligne de l'écran, tu ne la vois pas. De plus ton code sélectionne la dernière ligne de la recette.
J'ai retravaillé la macro pour éviter la double boucle for, me positionner sur la première ligne de la recette et faire défiler la page pour qu'elle se positionne sur la première ligne à l'écran.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
Private Sub LisRec_Click()
Dim ws1 As Worksheet
Dim firstCell As Range
Set ws1 = Sheets("Repas")
If Me.LisRec.ListIndex <> -1 Then
    Set firstCell = ws1.Range("A:A").Find(What:=Me.LisRec.Value, LookIn:=xlValues, LookAt:=xlWhole)
    If Not firstCell Is Nothing Then
        ws1.Activate
        firstCell.Select
        ActiveWindow.ScrollRow = firstCell.Row
    End If
End If
Unload Me
End Sub

[frunch]

Bonjour Franc,
Super travail
Il me reste à résoudre ces doublons, mais bon c'est moins important.
Merci beaucoup