Discussion :

[AimKaa]

Bonjour à tous,

Je sollicite votre aide pour une petite adaptation dans la mesure du possible
Mon classeur est composé de plusieurs onglets. Chaque onglet représente une fiche de suivi pour divers dossiers. Via ma page principale, j'ai un bouton qui recherche les actions à effectuer (TO DO) parmi tous les onglets et affiche le nombre via une msgbox. Cependant, j'aurais souhaité savoir s'il était possible dans la msgbox de stipuler dans quels onglets il y a une action à effectuer (donc en nommant le noms des différents onglets où il y a le terme "TO DO") afin de ne pas devoir chercher parmi les différents onglets :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
Sub Bouton3_Cliquer()
 
Dim sel As Object
Dim c As Integer
Dim f As Integer
Dim l As Long
Dim n As Integer
 
 
n = 0
For f = 2 To Sheets.Count
With Sheets(f)
    l = 1: c = 1
    Do
        Set sel = .Cells.Find(What:="TO DO", after:=.Cells(l, c), _
            LookIn:=xlValues, LookAt:=xlPart, _
            SearchOrder:=xlByColumns, _
            SearchDirection:=xlNext, MatchCase:=False)
        If sel Is Nothing Then Exit Do
        If sel.Column <= c And sel.Row <= l Then Exit Do
        c = sel.Column
        l = sel.Row
        n = n + 1
 
        Loop
 
End With
Next f
MsgBox n & " dossier(s) à traiter"
 
End Sub

D'avance, je vous en remercie grandement

[umfred]

sel renvoyant la cellule contenant "TO DO" tu peux accéder à la feuille de celle-ci via sel.Parent.Name (tu pourrais aussi lister les adresses des cellules en utilisant sel.AddressLocal(External:=True) (ça donne [nomclasseur]nomFeuille!cellule (ex [classeur1]Feuil01!$A$12)

Cependant dans ton cas, tu parcours les feuilles, donc tu peux y accéder par .Name il faudrait, juste rajouter un test pour ne pas le répéter plusieurs fois

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
 
Sub Bouton3_Cliquer()
 
Dim sel As Object
Dim c As Integer
Dim f As Integer
Dim l As Long
Dim n As Integer
Dim NomsFeuilles as string
Dim oldn as integer 
 
n = 0
For f = 2 To Sheets.Count
With Sheets(f)
    l = 1: c = 1
    oldn=n
    Do
        Set sel = .Cells.Find(What:="TO DO", after:=.Cells(l, c), _
            LookIn:=xlValues, LookAt:=xlPart, _
            SearchOrder:=xlByColumns, _
            SearchDirection:=xlNext, MatchCase:=False)
        If sel Is Nothing Then Exit Do
        If sel.Column <= c And sel.Row <= l Then Exit Do
        c = sel.Column
        l = sel.Row
        n = n + 1
 
        Loop
       if n> oldn Then
           NomsFeuilles= NomsFeuilles  & .Name & ", "
       End If
End With
Next f
NomsFeuilles=Left(NomsFeuilles, Len(NomsFeuilles)-2) ' pour supprimer le ", " surnuméraire
MsgBox n & " dossier(s) à traiter" & " dans les feuilles :" & NomsFeuilles
 
End Sub

[AimKaa]

Que dire à part... Un tout grand merci !
Pile poile ce que je souhaitais. J'ai juste modifié pour que les noms des onglets soient sous forme de liste [+ Chr(13)] dans la msgbox plutôt qu'en enfilade et c'est parfait.

Encore merci