Discussion :

[nazzguhl]

Bonjour,

je débute avec les macro Word (j'ai déjà une bonne connaissance en VBA pour excel ...), j'essaye de faire quelque chose qui me semble simple mais impossible de le faire : le résultat de la macro n'est pas ce que je souhaite.

exemple un word de 50 pages pleine de descriptions pour chaque description il y a :
- un titre utilisant le Style 'titre2'
- une première ligne indiquant le sous-titre et le nom, formaté "Titre n - nom du sous-titre"
- le détail sur plusieurs paragraphe et lignes

Pour info tout le texte autre que les titres, est en Police Georgia 9 en italique normal.

je voudrait mettre en valeur cette ligne de sous-titre sans utiliser de style et l'automatiser sur tout le document
voici mon code :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
 
Sub MEPTitre(chaine As String, Police As String, Taille As Integer, Gras As Boolean, Italique As Boolean, Wildcards As Boolean)
 
    Selection.Find.ClearFormatting
    Selection.Find.Replacement.ClearFormatting
    With Selection.Find
        .Text = chaine
        With .Replacement
            .Font.Bold = Gras
            .Font.Italic = Italique
            .Font.Size = Taille
            .Font.Name = Police
        End With
        .ParagraphFormat.SpaceAfter = 6
        .Forward = True
        .Wrap = wdFindContinue
        .Format = True
        .MatchCase = False
        .MatchWholeWord = False
        .MatchWildcards = Wildcards
        .MatchSoundsLike = False
        .MatchAllWordForms = False
    End With
    Selection.Find.Execute Replace:=wdReplaceAll
End Sub
 
Sub Macro1()
'
' Macro1 Macro
'
'
    Call MEPTitre("Titre ? - *", "Times New Roman", 12, True, False, True)
End Sub

Quand je lance Macro1 : sur toutes les lignes sous-titre, j'ai bien "Titre x -" qui est en Times New Roman, en bold et plus d'italique, mais la suite de la ligne n'a pas été modifiée, c'est juste un mot avant la fin de paragraphe et l'ajout de 6 point après chaque ligne ne se fait pas.

Est-ce que quelqu'un peut m'aider à résoudre l'anomalie => je ne sais pas si ce sont les options du find/replace ou ma chaine de recherche ou les 2 qui sont erronés ?

Merci
Alain

[Souriane]

Bonjour,

Voici un code que j'ai fabriqué plutôt rapidement. Il suffirait de l'adapter pour aller avec votre première macro pour pouvoir passer les variables.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
Sub Macro()
 
    selection.HomeKey Unit:=wdStory
 
    With selection
 
        With .Find
            .Text = "^13Titre ([0-9]{1;3}) - " 'Ici, ça va chercher «Titre 1 -» mais aussi «Titre 999 -»
            'Le «^13» c'est pour s'assurer qu'il recherche uniquement si c'est au début d'une ligne.  Si c'est au milieu d'un texte, il ne le formatera pas
            .Forward = True
            .Wrap = wdFindStop
            .MatchWildcards = True
            .Execute
        End With
 
        Do While .Find.Found 'Va exécuter ce qui suit uniquement s'il a trouvé une occurrence
            selection.MoveDown Unit:=wdParagraph, Count:=1, Extend:=wdExtend 'Sélectionne le titre en entier
 
            With selection.ParagraphFormat
                .SpaceBefore = 6
            End With
 
            With selection.Font
                .Name = "Times New Roman"
                .Size = 12
                .Bold = True
                .Italic = True
            End With
            selection.MoveRight Unit:=wdCharacter, Count:=1
 
            .EndKey Unit:=wdLine
            .Find.Execute   'Recherche la prochaine occurence.
        Loop 'Va à la prochaine occurence, sinon, sort du Loop
    End With
 
End Sub

Bonne journnée!

Souriane

[nazzguhl]

Bonjour,
Merci ça fonctionne nickel

Cordialement,
Alain