Discussion :

[pamonnier]

Bonjour,

Je cherche à créer une macro pour supprimer toutes les valeurs d'une BDD correspondant au mois affiché dans une feuille

La date sélectionnée se trouve dans une feuille "Planning"

Ma feuille "Data" contient toutes les dates de mes feuilles sur plusieurs années

J'ai du mal avec la ligne If pour que le mois/année actif dans "Planning" soit la référence pour supprimer toutes les dates de ce mois/année dans ma feuille "Data"

J'essaie d'adapter un code trouvé mais je me perds .....

J'ai essayé de copier la date affichée dans Planning dans la feuille data en P1 donc 1,16 pour essayer mais nop

SI quelqu'un a une idée je prends Merci

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
'supprimer uniquement le Mois en cours pour vider la feuille
 
Sub MyDeleteRows()
 
Dim lastrow As Long
Dim i As Long
 
    With Sheets("Data")
        lastrow = Cells(Rows.Count, 2).End(xlUp).Row
        For i = lastrow To 2 Step -1
            If CDate(Cells(i, 5).Value) <= WorksheetFunction.EoMonth(Date, 0) Then Rows(i).EntireRow.Delete
        Next i
    End With
 
End Sub

[Philippe Tulliez]

Bonjour,
Lorsque l'on utilise un bloc With...End With, il y a lieu de relier les objets fils à l'objet parent
Ainsi pour la ligne 7 de votre code il manque le point à l'objet Cells et à la propriété Rows

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

lastrow = .Cells(.Rows.Count, 2).End(xlUp).Row

vous devez le faire pour tous les Cells qui se trouvent dans le bloc

[pamonnier]

Bonsoir merci des corrections

Par contre je n'arrive pas à lui dire de supprimer toutes les dates enregistrées dans "Data" du mois en cours dans "Planning"

Je rappelle mon objectif :

Sur ma feuille planning j'ai un mois de sélectionné sur lequel je travaille si je vois que j'ai oublié certaines modifs à faire en amont j'aimerais vider la base de donnée de ce mois en question qui est dans une feuille "Data". Il faut donc que je sélectionne toutes les dates du mois concernées dans la feuille "Data" et quelles soient supprimées.

Voici mes derniers essais qui vide tout. Je pense que je n'arrive pas à lui dire de supprimer toutes les lignes ayant le même mmmm aaaa que la cellule "P1" par exemple qui est dans "Data" pour mes essais ou carrément une cellule dans la feuille "Planning"

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
'supprimer uniquement le Mois en cours
 
Sub MyDeleteRows()
 
Dim lastrow As Long
Dim i As Long
 
With Sheets("Data")
        lastrow = .Cells(.Rows.Count, 2).End(xlUp).Row
        For i = lastrow To 2 Step -1
            If CDate(.Cells(i, 16).Value) <= WorksheetFunction.EoMonth(Date, 0) Then .Rows(i).EntireRow.Delete
        Next i
End With
 
End Sub

[Philippe Tulliez]

Bonjour,
Dans cette ligne If CDate(.Cells(i, 16).Value) <= WorksheetFunction.EoMonth(Date, 0) Then .Rows(i).EntireRow.Delete, vous supprimez toutes les lignes dont la date située en colonne 16 est inférieure au 30/11/2022 (puisque aujourd'hui nous sommes le 19/11/2022) et sauf erreur de ma part la fonction CDate est parfaitement inutile si vous avez de véritable date dans cette colonne

[pamonnier]

A effectivement ce n'est pas la bonne formule

Ma colonne "A" de la feuille "Data" contient toutes les dates de ma base de donnée

En P1 de la feuille "Data" j'ai rapporté la date du mois affiché dans la feuille "planning"

Donc si je veux supprimer le mois de Novembre, je me mets sur le planning de novembre dans la feuille "planning" ce qui s'affiche en P1 feuille "Data" : Novembre 2022

Et là j'aimerais pouvoir supprimer toutes les dates de novembre 2022 via une macro

Peut être partir sur une sélection de toutes les dates ayant le même mois et année et tout supprimer ?

[Philippe Tulliez]

Bonjour,
Si la date se trouve en P1 et qu'il faut supprimer toutes les lignes qui contiennent en colonne A une date du même mois que la date en P1, je stockerais la valeur du mois de la date de P1 en début de procédure dans une variable (m par exemple) et s'il y a un risque d'avoir des dates de novembre (suivant l'exemple) d'une autre année, il faudrait alors stocker également l'année de P1 dans une variable

Test à effectuer pour supprimer la ligne contenant le mois de novembre d'une autre année
la variable m contient le numéro du mois de la date en cellule P1 (écrit de mémoire mais non testé)

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

If Month(.Cells(i, 1).Value) = m Then .Rows(i).EntireRow.Delete

Exemple ci-dessous avec un tableau structuré nommé t_Planning où l'on supprime toutes les lignes dont la date contenue dans la colonne "Date" est de la même année et du même mois que la date présente en P1

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
Sub DeleteRows()
  Const TableName As String = "t_Planning" ' Nom de la table
  Const LabelName As String = "Date"       ' Nom de la colonne à vérifier
  Dim rng As Range     ' Plage contenant les dates
  Dim sht As Worksheet ' Feuille où se trouve P1 et la table dont on supprime les lignes
  Dim m As Byte        ' N° du mois de la date en P1
  Dim y As Integer     ' N° de l'année de la date en P1
  Dim r As Long        ' N° de ligne
  Set sht = Range(TableName).ListObject.Parent
  Set rng = Range(TableName).ListObject.ListColumns(LabelName).DataBodyRange
  With sht.Range("P1")
    y = Year(.Value): m = Month(.Value)
  End With
  ' Boucle sur colonne Date
  With rng
    For r = .Rows.Count To 1 Step -1
      If m = Month(.Cells(r, 1).Value) And y = Year(.Cells(r, 1).Value) Then
         .ListObject.ListRows(r).Delete
      End If
    Next
  End With
  Set rng = Nothing: Set sht = Nothing
End Sub