Discussion :

[xelov]

Bonjour,

Je rencontre un soucis j'ai 4 colonne une avec la valeur l'autre avec l'identifiant, l'une ou je rentre une liste d'itentifiant et dans la dernière je voudrais noter la somme pour tout c'est identifiant.
Je ne vois pas comment faire car le somme.si ne gère pas une liste en tant que critère.

si quelqu'un à une idée.forum.xlsx

[Raccourcix]

Bonjour

l'idée est de chercher la présence des matricules dans la liste en ajoutant des "," avant et après afin de ne pas prendre en compte l'identifiant 10 ou 11 lorsqu'on demandera le 1.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=SOMME(ESTNUM(CHERCHE(","&B2:B11&",";","&C3&","))*A2:A11)

CHERCHE va renvoyer la position de l'identifiant dans la liste
ESTNUM va convertir en VRAI FAUX
en multipliant la valeur associée on aura 0 si FAUX et la valeur si VRAI (ici 53 et 49)
il ne reste plus qu'à en faire la somme.

en matricielle avec CTRL+MAJ+ENTREE suivant la version (non nécessaire avec 365)

ou avec SOMMEPROD

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=SOMMEPROD(N(ESTNUM(CHERCHE(","&B2:B11&",";","&D2&",")));A2:A11)

encore mieux avec un tableau

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=SOMME(ESTNUM(CHERCHE(","&Tableau[Identifiant]&",";","&[@liste]&","))*Tableau[Valeur])

Stéphane

[xelov]

Merci beaucoup pour votre aide la deuxième formule marche très bien chez moi mais j'ai une erreur sur la première.

Je met la discussion comme résolu

[Raccourcix]

Merci de votre retour
vous ne devez pas avoir une version 365 mais pour ceux qui ont déjà la fonction FRANCTIONNER.TEXTE vous pouvez l'utiliser :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=SOMME(INDEX(A2:A11;EQUIV(--FRACTIONNER.TEXTE(C3;",");B2:B11;0)))

ou

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=SOMME(RECHERCHEX(--FRACTIONNER.TEXTE(C3;",");B2:B11;A2:A11))

FRACTIONNER.TEXTE va découper la cellule suivant le séparateur (ici la virgule) pour ensuite récupérer les valeurs associées et les additionner.

Stéphane

[xelov]

Est-ce que avec cette méthode je peux chercher le max plutôt que de faire la somme ?

[Raccourcix]

Bonjour

quelle méthode ?

il suffit de remplacer SOMME par MAX

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=MAX(ESTNUM(CHERCHE(","&B2:B11&",";","&C3&","))*A2:A11)

A valider avec CTRL+MAJ+ENTREE suivant la version (non nécessaire avec 365)

si vous avez Excel 365 et la fonction FRACTIONNER.TEXTE

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=MAX(INDEX(A2:A11;EQUIV(--FRACTIONNER.TEXTE(C3;",");B2:B11;0)))

Stéphane

[xelov]

Est-ce que tu sais si il existe un équivalent dans Google Sheet ?

[Raccourcix]

Désolé, je n'en sais rien , je n'ai jamais utilisé Google Sheet.
Stéphane