Discussion :

[prosper02]

Bonjour,
J’ai bien compris l’utilité des tableaux structurés, mais même après avoir lu et relu les tuto’s conseillés, cela reste pour moi un vrai chemin de croix.
Mon problème :
Je dispose de 2 bases de données dans un même workbook.
- une contenant les données CP et commune,
- l’autre les noms de rue de chaque commune.
-
Pour extraire CP et commune je ne rencontre pas de problème
Pour isoler les rues correspondant aux CP souhaité, j’ai créé une table T_Datas contenant les données que je souhaitais exploiter dans l’immédiat.


Voici une partie du code utilisé.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
Private Sub rue_Change()
 
    Dim ligne As Long
    Dim f2 As ListObject
    Dim lcs As ListColumn
    Dim row As ListRow
    Dim r As Range
    Dim rg As Range
    Dim trouv
 
    Set f2 = Sheets("BDD_rues").ListObjects(1)
    Set lcs = f2.ListColumns(1)
    Set row = f2.ListRows
 
    ligne = lcs.DataBodyRange.Find(what:=CP).row
 
    trouv = False
 
      Do While Cells(ligne, 3).text <> ""
            If Cells(ligne, 3).text = CP Then trouv = True
                If trouv Then
                   If Cells(ligne, 3).text <> CP Then Exit Do
                   Me.rue.AddItem Cells(ligne, 3).text
                End If
            ligne = ligne + 1
      Loop
 
    Me.rue.DropDown
    Set f2 = Nothing
    Set lcs = Nothing
 
 
End Sub

Si je parviens à trouver la première position du CP souhaité dans la colonne » PKANCODE » impossible pour moi de récupérer le nom de la rue situé dans la colonne « STRAATNM » ainsi que toutes les autres rues liées au même code postal.
Je me doute que je dois travailler avec l’objet listrow mais là je bloque ( :-

Merci d’avance pour votre aide

[Philippe Tulliez]

Bonjour,
Pour une recherche multiple, soit on choisi d'effectuer une recherche séquentielle soit on utilise la méthode Find mais alors on utilise FindNext

Un exemple ci-dessous d'une fonction générique nommée FindList qui renvoie la liste des éléments trouvés en fonction des paramètres. Les méthodes utilisées sont Find et FindNext

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
Function FindList(TableName As String, SearchColumn As String, LookUpValue As Variant, ColumnReturn As String) As Variant
  ' Arguments
  '   TableName     Nom de la table
  '   SearchColumn  Nom de la colonne où effectuer la recherche
  '   LookupValue   Valeur cherchée
  '   ColumnReturn  Nom de la colonne où les valeurs à retourner se trouvent
  ' Philippe Tulliez (www.magicoffice.be)
  ' Vers 1.1
  Dim oList As ListObject ' Table structurée
  Dim oRange As Range     ' Plage de recherche
  Dim c As Range          ' Cellule trouvée
  Dim fr As Long          ' Première ligne trouvée
  Dim cr As Long          ' Ligne trouvée
  Dim t As Variant        ' Table renvoyée
  Dim Flag As Boolean
  Dim e As Long
  Set oList = Range(TableName).ListObject
  Set oRange = oList.ListColumns(SearchColumn).DataBodyRange
  '
  With oRange
    Set c = oRange.Find(What:=LookUpValue, After:=.Cells(.Cells.Count), LookAt:=xlWhole, LookIn:=xlValues)
    Do While Not c Is Nothing And Flag = False
       cr = c.row - .row + 1
       If e Then ReDim Preserve t(e) Else ReDim t(e): fr = cr
       t(e) = oList.ListColumns(ColumnReturn).DataBodyRange.Cells(cr).Value
       e = e + 1
       Set c = .FindNext(c)
       Flag = (fr = c.row - .row + 1)
    Loop
  End With
  FindList = t
  Set oList = Nothing: Set oRange = Nothing: Set c = Nothing
End Function

Exemple d'une procédure qui l'invoque
Dans cet exemple nous cherchons la liste des éléments trouvés dans la colonne nommée Rue de la table nommée t_Commune, voir illustration, du code postal 1050 se trouvant dans la colonne nommé Code

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
Sub TestFindList()
  Const SearchValue As Variant = 1050  ' Valeur cherchée
  Dim t As Variant
  Dim e As Long
  Dim Msg As String
  t = FindList("t_Commune", "Code", SearchValue, "Rue")
  Msg = "Liste des rues du code postal : " & SearchValue & vbCrLf
  If IsArray(t) Then
     For e = 0 To UBound(t)
       Msg = Msg & vbCrLf & t(e)
     Next
   Else
     Msg = Msg & vbCrLf & "Pas trouvé le code "
  End If
  MsgBox Msg
End Sub

Illustration de la table nommée t_Commune

[laurent_ott]

Bonjour,
Je n'ai pas de PC sous la main pour tester mais de mémoire Find ne marche pas sur les lignes filtrées (masquées), vous confirmez ?
Et pour travailler avec les tableaux structurés je vous conseille les fonctions génériques du tutoriel que vous trouverez dans ma signature (l'avant dernière).
https://laurent-ott.developpez.com/t...ux-Structures/
Bonne programmation.

[Philippe Tulliez]

Bonjour Laurent,

Je n'ai pas de PC sous la main pour tester mais de mémoire Find ne marche pas sur les lignes filtrées (masquées), vous confirmez ?

Effectivement la recherche avec la méthode Find ne fonctionne pas si la valeur cherchée se trouve dans les lignes masquées par le filtre. En revanche la recherche séquentielle fonctionne.

[prosper02]

Bonjour,

merci à vous deux pour les informations.
Mon problème est résolu, cela n'a pas été sans mal..