Discussion :

[Malick]

Bonjour,

J'ai ce code que j'utilise pour calculer les Totaux des colonnes F et G de mon tableau.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
Sub SommeDebCred()
    Dim DerLig As Long, i As Long
    DerLig = Range("A" & Rows.Count).End(xlUp).Row + 1  ' Pour ajouter la ligne des Totaux
    With Range("A" & DerLig)
        .Value = "TOTAL au " & DateSerial(Year(Date) - 1, 12, 31)
        .HorizontalAlignment = xlCenter
    End With
    For i = 1 To 2
        With Cells(DerLig, i + 5)
            .Value = Application.WorksheetFunction.Sum(Range(Cells(5, i + 5), Cells(DerLig - 1, i + 5)))
            .NumberFormat = "#,##0"
        End With
    Next i
    Range("A" & DerLig, "G" & DerLig).Font.Bold = True
    Range("A" & DerLig, "D" & DerLig).MergeCells = True  'Fusion de la ligne Total de A à D
 End Sub

Je sollicite votre aide pour compléter le code afin d'ajouter une ligne SOLDE qui sera juste après la ligne TOTAUX (une ligne à sauter). Cette ligne solde obtenu par la différence des deux totaux, sera positionnée dans la cellule F ou G de la même ligne suivant le sens positif ou négatif.

Ci-joint une capture :

[ARTURO83]

Bonjour,

Essayez ceci:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
Sub SommeDebCred()
    Dim DerLig As Long, i As Long, Solde As Double
    DerLig = Range("A" & Rows.Count).End(xlUp).Row + 1  ' Pour ajouter la ligne des Totaux
    With Range("A" & DerLig)
        .Value = "TOTAL au " & DateSerial(Year(Date) - 1, 12, 31)
        .HorizontalAlignment = xlCenter
    End With
    For i = 1 To 2
        With Cells(DerLig, i + 5)
            .Value = Application.WorksheetFunction.Sum(Range(Cells(5, i + 5), Cells(DerLig - 1, i + 5)))
            .NumberFormat = "#,##0"
        End With
    Next i
    Range("A" & DerLig, "G" & DerLig + 2).Font.Bold = True
    Range("A" & DerLig, "D" & DerLig).MergeCells = True  'Fusion de la ligne Total de A à D
    Range("A" & DerLig + 2, "D" & DerLig + 2).MergeCells = True 'Fusion de la ligne Total de A à D
    Range("A" & DerLig + 2, "G" & DerLig + 2).Font.ColorIndex = 3
 
    With Range("A" & DerLig + 2)
        .Value = "SOLDE"
        .HorizontalAlignment = xlCenter
    End With
    Solde = Range("G" & DerLig).Value - Range("F" & DerLig).Value
    If Solde < 0 Then Range("F" & DerLig + 2).Value = Solde Else: Range("G" & DerLig + 2).Value = Solde
    Range("F" & DerLig + 2 & ":G" & DerLig + 2).NumberFormat = "#,##0"
 End Sub

Cdlt

[Malick]

Bonjour ARTURO83,

Super, merci beaucoup ça marche nickel