Discussion :

[epsilon99]

Hello à vous

Dans une feuille Excel je répertorie :
Quelques pronostics pour certaines courses de chevaux (chaque Pronostiqueur a son pronostic dans 1 cellule)
et le Résultat de la course sont dans des cellules séparées
(je mets chaque pronostic dans 1 cellule pour chacun pour gain de place.)

voir cette image :


je souhaiterais, via un bouton,
=> si les 5 cases de "Arrivée" se retrouve dans un des pronostics, celui ci soit surligné en jaune (ou autre couleur peu importe ..)
cela me permettrait de voir tout de suite si un pronostiqueur a fait le bon pronostic

Je saurais le faire si les pronostics étaient dans des cellules séparées mais vu que chaque pronostic est dans une cellule unique, je ne vois pas comment faire...

merci de votre aide par avance

[EricDgn]

Bonjour,

Une façon de faire avec une fonction personnalisée utilisée dans une mise en forme conditionnelle.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
Option Explicit
 
Public Function PTop(cP As Range) As Boolean
    '--- cP: cellule contenant le pronostic
    Dim kR As Long, kC As Long, v As String
    kR = cP.Row
    v = cP.Value & " "      '--- ajout un espace en fin
    PTop = True
    For kC = 6 To 10        '--- n° colonnes arrivées
        If InStr(v, Cells(kR, kC) & " ") = 0 Then
            PTop = False
            Exit For
        End If
    Next kC
End Function

Cordialement.

[epsilon99]

Re EricDgn,

Merci de t'être intéressé au pb .

Possible de me mettre le fichier au format excel 2003 (xls) ?

.. je ne peux pas ouvrir le format .xlsm (suis sous ecsl 2003)

[EricDgn]

En attaché la version .xls
Cordialement.

[Qwazerty]

Salut

Pourquoi ne pas utiliser un MFC (Mise En forme Conditionnelle)?
Plutôt que de chercher à séparer les valeur contenu dans les 3 premières cellules, pourquoi ne pas concaténer les résultats et le comparer au 3 1ères cellules?

C'est sans doute améliorable mais dans l'esprit, ça donnerait un truc comme ça

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=SIERREUR(CHERCHE(CONCATENER(G12;" ";H12;" ";I12;" ";J12;" ";K12);D12);FAUX)

A placer dans la MFC

++
Qwaz

[EricDgn]

Oui c'est tout à fait bon s'il faut considérer le pronostic ok uniquement s'il respecte vraiment l'ordre d'arrivée. Pour ma part j'ai considéré qu'il suffisait que les arrivées soient dans le pronostic, dans l'ordre ou le désordre. On pourrait d'ailleurs surement aussi mettre cela dans une seule formule par 5 CHERCHE() additionnés.

Bien cordialement.

[Arkham46]

Bonjour,

Bonjour,

Une façon de faire avec une fonction personnalisée utilisée dans une mise en forme conditionnelle.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
Option Explicit
 
Public Function PTop(cP As Range) As Boolean
    '--- cP: cellule contenant le pronostic
    Dim kR As Long, kC As Long, v As String
    kR = cP.Row
    v = cP.Value & " "      '--- ajout un espace en fin
    PTop = True
    For kC = 6 To 10        '--- n° colonnes arrivées
        If InStr(v, Cells(kR, kC) & " ") = 0 Then
            PTop = False
            Exit For
        End If
    Next kC
End Function

Cordialement.

Attention, si on gère avec des tests de chaînes de caractères, il faut également ajouter un espace avant.
Sinon un pronostic à 15 avec une arrivée à 5 sera considéré bon.

Note : j'ajouterais également la plage des arrivées à la fonction plutôt que d'avoir en dur les colonnes 6 à 10.

[EricDgn]

Bonjour,

Effectivement, bien vu! Aussi, une version corrigée, avec plage des arrivées.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
Option Explicit
 
Public Function PTop(cP As Range, rA As Range) As Boolean
    '--- cP: cellule contenant le pronostic, rA: plage contenant les arrivées
    Dim kR As Long, kC As Long, v As String
    kR = cP.Row
    v = " " & cP.Value & " "                        '--- ajout espace en fin et en début
    PTop = True
    For kC = 1 To 5                                 '--- n° colonnes arrivées
        If InStr(v, " " & rA(kC) & " ") = 0 Then    '--- idem espace avant et après
            PTop = False
            Exit For
        End If
    Next kC
End Function

Cordialement.