Discussion :

[modus57]

Bonsoir,

Voilà j'ai un bout de code qui liste tous les objets CodeName ainsi que le nom des Userform dans la première colonne et les modules dans la colonne adjacente du classeur actif.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
'====================================================================================================
    'Nécessite d'activer la référence "Microsoft Visual basic For Application Extensibility 5.3"
'====================================================================================================
    Dim Ajout As Integer, VBCmp As VBComponent, cdMod As CodeModule, Wb As Workbook, Debut As Long, I, nomTableau
 
    'Indiquez le nom du classeur ouvert
    Set Wb = ThisWorkbook
 
    'Tester que Databodyrange existe ( => que le tableau n'est pas vide avant de le vider)
    If Not Range("ListeModulesProc").ListObject.DataBodyRange Is Nothing Then
        'Efface la liste des procédures
        Range("ListeModulesProc").ListObject.DataBodyRange.Delete
    End If
 
    Ajout = 2
    'Boucle sur tous les modules & les procédures du projet :
    For Each VBCmp In Wb.VBProject.VBComponents
        Set cdMod = VBCmp.CodeModule
        With cdMod
            Debut = .CountOfDeclarationLines + 1
            Do Until Debut >= .CountOfLines
                Cells(Ajout + I, 1) = VBCmp.Name 'listage des modules dans la feuille active du classeur actif
                Cells(Ajout + I, 2) = .ProcOfLine(Debut, vbext_pk_Proc) 'listage des procédures dans la feuille active du classeur actif
                Debut = Debut + .ProcCountLines(.ProcOfLine(Debut, vbext_pk_Proc), vbext_pk_Proc)
                Ajout = Ajout + 1
            Loop
        End With
    Next VBCmp
    ActiveSheet.Range("A:C").Columns.AutoFit
    nomTableau = "ListeModulesProc"
    Range(nomTableau).Sort key1:=Range(nomTableau & "[Nom Module]"), Header:=xlYes, order1:=xlAscending
    Range("E2").Select

Je souhaiterai dans la première colonne concaténer le CodeName et le nom de l'onglet entre crochet ou lister le nom des onglets dans une troisième colonne.

Malgré quelques recherches je n'ai pas trouvé de solution.

Comment intégrer cette possibilité dans ma procédure.

Pourriez-vous m'aider svp, merci d'avance.

[tototiti2008]

Bonsoir

le nom de l'onglet entre crochet ou lister le nom des onglets dans une troisième colonne

C'est quoi "le nom de l'onglet" ? pas sûr de ce à quoi ça fait référence

[modus57]

Bonsoir tototiti2008,

Merci de vous intéresser à cette discussion.

Il s'agit bien du nom de la feuille Excel.

[tototiti2008]

Bonsoir,

à tester (ajout d'une ligne sur la partie centrale)

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
 
With cdMod
            Debut = .CountOfDeclarationLines + 1
            Do Until Debut >= .CountOfLines
                Cells(Ajout + I, 1) = VBCmp.Name 'listage des modules dans la feuille active du classeur actif
                If VBCmp.Type = vbext_ct_Document Then Cells(Ajout + I, 1) = Cells(Ajout + I, 1) & " (" & VBCmp.Properties("Name").Value & ")"
                Cells(Ajout + I, 2) = .ProcOfLine(Debut, vbext_pk_Proc) 'listage des procédures dans la feuille active du classeur actif
                Debut = Debut + .ProcCountLines(.ProcOfLine(Debut, vbext_pk_Proc), vbext_pk_Proc)
                Ajout = Ajout + 1
            Loop
End With

[modus57]

Super tototiti2008

Ça répond exactement à ce que je souhaitais, sauf sur un point : si l'objet CodeName ne comporte pas au moins une ligne de code la ou les feuilles ne sont pas listées ?

Cordialement Modus57.

@+

[modus57]

Bien sûr en ajoutant simplement :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
Option Explicit
Private Sub Worksheet_SelectionChange(ByVal Target As Range)
End Sub

Les objets CodeName sont listés.

C'est moyennement bon, je me contenterait de cette astuce ?

[tototiti2008]

Ah ben oui, c'est ce que fait le code original, il liste les éléments contenant des procédures

[tototiti2008]

Bonsoir,

Si tu veux autre chose que ça renvoie actuellement, va falloir prendre le temps de nous expliquer quoi
Qu'est-ce qu'il doit écrire si la feuille est vide (de code) ?
Qu'est-ce qu'il doit écrire si la feuille contient des procédures ?
Qu'est-ce qu'il doit écrire pour les autres composants VB (Userform, Module de classe, Module...) ? s'il ne contiennent pas de code ou avec des procédures
Bref sans exemple clair du résultat attendu, ça va être difficile de te proposer un code qui le produit magiquement

[modus57]

Bonjour,

Si la feuille ou le ThisWorkbokk est vide (de code) : dans la première colonne le CodeName & le nom de l'onglet
Si la feuille ou le ThisWorkbokk contient une ou des procédures : dans la première colonne le CodeName & le nom de l'onglet et dans la 2ème colonne le ou les noms des procédures.
Pour les autres composants VB (Userform, Module de classe, Module...) s'il ne contiennent pas de code : nom du composant dans la première colonne.
Pour les autres composants VB (Userform, Module de classe, Module...) s'il contiennent du code : nom du composant dans la première colonne et le ou les noms des procédures dans la 2ème colonne.

Voici un montage d'image en exemple.

@+

[tototiti2008]

Bonjour,

à tester

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
Sub ListObj()
 
'====================================================================================================
    'Nécessite d'activer la référence "Microsoft Visual basic For Application Extensibility 5.3"
'====================================================================================================
    Dim Ajout As Integer, VBCmp As VBComponent, cdMod As CodeModule, Wb As Workbook, Debut As Long, I, nomTableau, NbProc As Long, NomC As String
 
    'Indiquez le nom du classeur ouvert
    Set Wb = ThisWorkbook
 
    'Tester que Databodyrange existe ( => que le tableau n'est pas vide avant de le vider)
    If Not Range("ListeModulesProc").ListObject.DataBodyRange Is Nothing Then
        'Efface la liste des procédures
        Range("ListeModulesProc").ListObject.DataBodyRange.Delete
    End If
 
    Ajout = 2
    'Boucle sur tous les modules & les procédures du projet :
    For Each VBCmp In Wb.VBProject.VBComponents
        NbProc = 0
        Set cdMod = VBCmp.CodeModule
        With cdMod
            Debut = .CountOfDeclarationLines + 1
            NomC = VBCmp.Name
            If VBCmp.Type = vbext_ct_Document Then NomC = NomC & " (" & VBCmp.Properties("Name").Value & ")"
            Do Until Debut >= .CountOfLines
                NbProc = NbProc + 1
                Cells(Ajout + I, 1) = NomC 'listage des modules dans la feuille active du classeur actif
                Cells(Ajout + I, 2) = .ProcOfLine(Debut, vbext_pk_Proc) 'listage des procédures dans la feuille active du classeur actif
                Debut = Debut + .ProcCountLines(.ProcOfLine(Debut, vbext_pk_Proc), vbext_pk_Proc)
                Ajout = Ajout + 1
            Loop
        End With
        If NbProc = 0 Then
            Cells(Ajout + I, 1) = NomC
            Ajout = Ajout + 1
        End If
    Next VBCmp
    ActiveSheet.Range("A:C").Columns.AutoFit
    nomTableau = "ListeModulesProc"
    Range(nomTableau).Sort key1:=Range(nomTableau & "[Nom Module]"), Header:=xlYes, order1:=xlAscending
    Range("E2").Select
 
End Sub

[modus57]

Bonsoir tototiti2008 et encore

Ça fonction nickel chrome du tonnerre de Zeus.

Re merci et cordiales salutations.