Discussion :

[tease]

Bonjour les développeurs

Ce script calcule la différence entre 2 dates. Il affiche le résultat en jours ( days) et en heure ( HH:MM:SS ).

Je voudrais savoir comment convertir les jours en date ( DD/MM/YYYY ).

Voici un exemple:

Enter two timestamps in "DD/MM/YYYY HH:MM:SS" format

Enter start timestamp: 08/04/2004 10:12:23

Enter end timestamp: 31/08/2021 07:18:47

Duration: 6353 days and 21:06:24

Appuyez sur une touche pour continuer...

Voici le script:

Code Batch :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
 
@echo off
setlocal EnableDelayedExpansion
 
rem Get elapsed days/time between two timestamps in "DD/MM/YYYY HH:MM:SS" format
rem Antonio Perez Ayala aka Aacini
 
rem Define the "Date in DDMMYYYY format" To "Julian Day Number" conversion "function"
set "DateToJDN(Date)=( a=1Date, y=a%%10000, a/=10000, m=a%%100, d=a/100-100, a=(m-14)/12, (1461*(y+4800+a))/4+(367*(m-2-12*a))/12-(3*((y+4900+a)/100))/4+d-32075 )"
 
echo Enter two timestamps in "DD/MM/YYYY HH:MM:SS" format
echo.
set /P "stamp1=Enter start timestamp:   "
echo.
set /P "stamp2=Enter  end  timestamp:   "
 
for /F "tokens=1-4" %%a in ("%stamp1% %stamp2%") do set "date1=%%a" & set "time1=%%b" & set "date2=%%c" & set "time2=%%d"
 
set /A "days=!DateToJDN(Date):Date=%date2:/=%! - !DateToJDN(Date):Date=%date1:/=%!"
set /A "ss=(((1%time2::=-100)*60+1%-100) - (((1%time1::=-100)*60+1%-100)"
if %ss% lss 0 set /A "ss+=60*60*24, days-=1"
set /A "hh=ss/3600+100, ss%%=3600, mm=ss/60+100, ss=ss%%60+100"
 
echo/
echo Duration: %days% days and %hh:~1%:%mm:~1%:%ss:~1%
echo.
pause

Merci de bien vouloir m'aider.

[ericlm128]

Bonjour,

Je voudrais savoir comment convertir les jours en date ( DD/MM/YYYY )

Je ne comprends pas ce que tu souhaites

[tease]

Bonjour ericlm128

Merci d'avoir lu mon message.

Je reprends le même exemple:

Enter two timestamps in "DD/MM/YYYY HH:MM:SS" format

Enter start timestamp: 08/04/2004 10:12:23

Enter end timestamp: 31/08/2021 07:18:47

Duration: 6353 days and 21:06:24

Appuyez sur une touche pour continuer...

Le script affiche le nombre de jours entre les deux dates données

Duration: 6353 days

Est-il possible de convertir les 6353 jours en nombre d'années, de mois et de jours écoulés pour les afficher au format DD/MM/YYYY ?

[ericlm128]

Et bien tu peux toujours faire le calcul mais je suis contre l'affichage au format J/M/A puisque ce n'est pas une date mais une durée

Code batch :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
set /a "full=6353"
 
set /a "Y=%full%/365"
set /a "reste=%full%%%365"
set /a "M=%reste%/30"
set /a "J=%reste%%%30"
 
echo %J%/%M%/%Y%
 
pause

[tease]

Merci infiniment ericlm128.

Maintenant je peux connaître le nombre d'années, de mois et de jours écoulés (qui est également une durée dans le temps) entre les deux dates.

Ne dit-on pas combien a duré le règne de Louis XIV, la grippe espagnole, la guerre de Troie... ?

Bonne journée, bonne santé et a+ peut-être.

[tease]

Je suis en phase de tests et j'ai remarqué qu'il y a une erreur au niveau des jours si on tient compte des années bissextiles.

Peut-on remédier à cela ?

Merci.

[ericlm128]

Sur le script de base ou sur mon calcul ?

[tease]

L'erreur se trouve sur ton calcul car avec le script de base et la calculatrice de Windows (Affichage -> Calcul de la date), le nombre de jours est identique.

[ericlm128]

Peux tu détailler ta démarche avec la calculatrice ?

[tease]

Je lance la calculatrice Windows

1. Je clique sur Affichage
2. Je laisse Standard (Alt+1) coché
3. Je coche Calcul de la date ou je fais Ctrl+E
4. La fenêtre s'affiche à droite de la calculatrice
5. Dans "Sélectionnez un type de calcul sur dates", je déroule et je clique sur "Calculer la différence entre deux dates"
6. Dans de, je tape la 1ère date (JJ/MM/AA) ou je clique sur le calendrier pour sélectionner une date
7. Dans à, je tape la 2ème date (JJ/MM/AA) ou je clique sur le calendrier pour sélectionner une date
8. Enfin, je clique sur Calculer

La calculatrice affiche la différence en :
- (années, mois, semaines, jours)
- (jours)


J'ai pris comme exemple ceci:



https://fr.wikipedia.org/wiki/Louis_XIV

14 mai 1643 – 1er septembre 1715
(72 ans, 3 mois et 18 jours)

26407 jours

[Flammrock]

Si tu veux avoir le même résultat que sur la calculette, tu peux faire comme ça :

Code batch :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
@echo off
 
 
rem les dates
set date1=14/05/1643
set date2=01/09/1715
 
 
 
rem on récupère la différence en jours entre les deux dates
call :Date.DiffenceBetweenDate %date1% %date2% days
 
rem on affiche le calcul
echo;%date2% - %date1% = %days% jours
 
rem on format le résultat
call :Date.DiffenceBetweenDateFormat %date1% %date2% year month week day
 
rem on affiche le résultat
echo;%year% annees; %month% mois; %week% semaines; %day% jours
 
 
 
 
rem les fonctions
pause>nul&exit
:Date.toDays <days> <month> <year> <out:days>
    setlocal enabledelayedexpansion
    set /a d=1%~1+1%~1-2%~1&set /a m=1%~2+1%~2-2%~2&set /a y=1%~3+1%~3-2%~3
    set /a "m=(%m%+9) %% 12"&set /a "y=%y%-!m!/10"
    (endlocal&set /a "%~4=365*%y%+%y%/4-%y%/100+%y%/400+(%m%*306+5)/10+(%d%-1)")
exit /b
:Date.DiffenceBetweenDate <DD/MM/YYYY> <DD/MM/YYYY> <out:days>
    setlocal enabledelayedexpansion
    set date1=%~1&set date2=%~2
    call :Date.toDays !date1:/= ! g1&call :Date.toDays !date2:/= ! g2
    (endlocal&set /a "%~3=%g2%-%g1%")
exit /b
:Date.getFrom <DD/MM/YYYY> <out:year> <out:month> <out:day>
    for /f "tokens=1-3 delims=/,-\ " %%1 in ('echo;%~1') do (
        set /a %~2=1%%~1+1%%~1-2%%~1
        set /a %~3=1%%~2+1%%~2-2%%~2
        set /a %~4=1%%~3+1%%~3-2%%~3
    )
exit /b
:Date.DiffenceBetweenDateFormat <DD/MM/YYYY> <DD/MM/YYYY> <out:year> <out:month> <out:week> <out:day>
    setlocal enabledelayedexpansion
    call :Date.getFrom %~1 d1 m1 y1
    call :Date.getFrom %~2 d2 m2 y2
    set /a "totalmonths=(%y2% - %y1%) * 12 + %m2% - %m1%"
    if %d2% lss %d1% set /a totalmonths-=1
    set /a month=%totalmonths% %% 12 + %m1%
    set /a yeartmp=%totalmonths% / 12
    set /a monthtmp=%totalmonths% %% 12
    set /a y3=%y1%+%yeartmp%
    set /a m3=%m1%+%monthtmp%
    if %m3% gtr 12 (
        set /a m3=%m3%-12
        set /a y3+=1
    )
    call :Date.DiffenceBetweenDate %d1%/%m3%/%y3% %~2 day
    (
        endlocal
        set /a %~3=%totalmonths% / 12
        set /a %~4=%totalmonths% %% 12
        set /a %~5=%day%/7
        set /a %~6=%day% %% 7
    )
exit /b

[tease]

Bonsoir Flammrock.

Merci infiniment pour ton aide.

Bonne soirée. Bonne santé et a+ peut-être.

[Flammrock]

De rien

Je viens de résoudre un bug. Si tu as la version précédente du script, voici quelques exemples de dates qui permettent de visualiser le bug :
(j'ai mis à jour le code de mon précédent message)

start: 24/9/1775
end:19/1/1811


start: 25/10/2284
end: 30/9/2370


start: 10/4/2484
end: 3/4/2496

J'ai aussi fait tout un tas de tests et de vérifications. Le script est maintenant correcte.
Je remet le script ici :

Code batch :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
@echo off
 
 
rem les dates
set date1=14/05/1643
set date2=01/09/1715
 
 
 
rem on récupère la différence en jours entre les deux dates
call :Date.DiffenceBetweenDate %date1% %date2% days
 
rem on affiche le calcul
echo;%date2% - %date1% = %days% jours
 
rem on format le résultat
call :Date.DiffenceBetweenDateFormat %date1% %date2% year month week day
 
rem on affiche le résultat
echo;%year% annees; %month% mois; %week% semaines; %day% jours
 
 
 
 
rem les fonctions
pause>nul&exit
:Date.toDays <days> <month> <year> <out:days>
    setlocal enabledelayedexpansion
    set /a d=1%~1+1%~1-2%~1&set /a m=1%~2+1%~2-2%~2&set /a y=1%~3+1%~3-2%~3
    set /a "m=(%m%+9) %% 12"&set /a "y=%y%-!m!/10"
    (endlocal&set /a "%~4=365*%y%+%y%/4-%y%/100+%y%/400+(%m%*306+5)/10+(%d%-1)")
exit /b
:Date.DiffenceBetweenDate <DD/MM/YYYY> <DD/MM/YYYY> <out:days>
    setlocal enabledelayedexpansion
    set date1=%~1&set date2=%~2
    call :Date.toDays !date1:/= ! g1&call :Date.toDays !date2:/= ! g2
    (endlocal&set /a "%~3=%g2%-%g1%")
exit /b
:Date.getFrom <DD/MM/YYYY> <out:year> <out:month> <out:day>
    for /f "tokens=1-3 delims=/,-\ " %%1 in ('echo;%~1') do (
        set /a %~2=1%%~1+1%%~1-2%%~1
        set /a %~3=1%%~2+1%%~2-2%%~2
        set /a %~4=1%%~3+1%%~3-2%%~3
    )
exit /b
:Date.DiffenceBetweenDateFormat <DD/MM/YYYY> <DD/MM/YYYY> <out:year> <out:month> <out:week> <out:day>
    setlocal enabledelayedexpansion
    call :Date.getFrom %~1 d1 m1 y1
    call :Date.getFrom %~2 d2 m2 y2
    set /a "totalmonths=(%y2% - %y1%) * 12 + %m2% - %m1%"
    if %d2% lss %d1% set /a totalmonths-=1
    set /a month=%totalmonths% %% 12 + %m1%
    set /a yeartmp=%totalmonths% / 12
    set /a monthtmp=%totalmonths% %% 12
    set /a y3=%y1%+%yeartmp%
    set /a m3=%m1%+%monthtmp%
    if %m3% gtr 12 (
        set /a m3=%m3%-12
        set /a y3+=1
    )
    call :Date.DiffenceBetweenDate %d1%/%m3%/%y3% %~2 day
    (
        endlocal
        set /a %~3=%totalmonths% / 12
        set /a %~4=%totalmonths% %% 12
        set /a %~5=%day%/7
        set /a %~6=%day% %% 7
    )
exit /b

[tease]

Bonjour Flammrock

J'ai testé les exemples de dates qui permettent de visualiser le bug mais je n'ai constaté aucune différence entre le 1er et le 2ème script. J'ai même vérifié cela avec la calculatrice Windows. Les résultats sont identiques.

Pour en être sûre, j'ai comparé le 1er script au second avec Notepad++ et j'ai remarqué qu'ils sont identiques.

Où se trouve donc le bug ?

[Flammrock]

J'ai testé les exemples de dates qui permettent de visualiser le bug mais je n'ai constaté aucune différence entre le 1er et le 2ème script. J'ai même vérifié cela avec la calculatrice Windows. Les résultats sont identiques.

Pour en être sûre, j'ai comparé le 1er script au second avec Notepad++ et j'ai remarqué qu'ils sont identiques.

Où se trouve donc le bug ?

J'ai remplacé tout les scripts que j'ai posté par la nouvelle version pour éviter que d'autres utilisent une version avec un bug.
Donc tout les scripts fonctionnent et n'ont plus le bug.


Voici l'ancien script :
(à ne surtout pas utiliser)

Code Batch :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
@echo off
 
 
rem les dates
set date1=14/05/1643
set date2=01/09/1715
 
 
 
rem on récupère la différence en jours entre les deux dates
call :Date.DiffenceBetweenDate %date1% %date2% days
 
rem on affiche le calcul
echo;%date2% - %date1% = %days% jours
 
rem on format le résultat
call :Date.DiffenceBetweenDateFormat %date1% %date2% year month week day
 
rem on affiche le résultat
echo;%year% annees; %month% mois; %week% semaines; %day% jours
 
 
 
 
rem les fonctions
pause>nul&exit
:Date.toDays <days> <month> <year> <out:days>
    setlocal enabledelayedexpansion
    set /a d=1%~1+1%~1-2%~1&set /a m=1%~2+1%~2-2%~2&set /a y=1%~3+1%~3-2%~3
    set /a "m=(%m%+9) %% 12"&set /a "y=%y%-!m!/10"
    (endlocal&set /a "%~4=365*%y%+%y%/4-%y%/100+%y%/400+(%m%*306+5)/10+(%d%-1)")
exit /b
:Date.DiffenceBetweenDate <DD/MM/YYYY> <DD/MM/YYYY> <out:days>
    setlocal enabledelayedexpansion
    set date1=%~1&set date2=%~2
    call :Date.toDays !date1:/= ! g1&call :Date.toDays !date2:/= ! g2
    (endlocal&set /a "%~3=%g2%-%g1%")
exit /b
:Date.getFrom <DD/MM/YYYY> <out:year> <out:month> <out:day>
    for /f "tokens=1-3 delims=/,-\ " %%1 in ('echo;%~1') do (
        set /a %~2=1%%~1+1%%~1-2%%~1
        set /a %~3=1%%~2+1%%~2-2%%~2
        set /a %~4=1%%~3+1%%~3-2%%~3
    )
exit /b
:Date.DiffenceBetweenDateFormat <DD/MM/YYYY> <DD/MM/YYYY> <out:year> <out:month> <out:week> <out:day>
    setlocal enabledelayedexpansion
    call :Date.getFrom %~1 d1 m1 y1
    call :Date.getFrom %~2 d2 m2 y2
    set /a "totalmonths=(%y2% - %y1%) * 12 + %m2% - %m1%"
    if %d2% lss %d1% set /a totalmonths-=1
    set /a month=%totalmonths% %% 12 + %m1%
    call :Date.DiffenceBetweenDate %d1%/%month%/%y2% %date2% day
    (
        endlocal
        set /a %~3=%totalmonths% / 12
        set /a %~4=%totalmonths% %% 12
        set /a %~5=%day%/7
        set /a %~6=%day% %% 7
    )
exit /b

Voici un screenshot du bug :





Par contre, il marche très bien pour les dates d'exemples que tu as fourni, c'est pour ça que je ne l'avais pas vu au départ :





Et voici les différences : https://www.diffchecker.com/vrp5njlO

Screenshot des différences :

[tease]

Bonjour Flammrock

Je n'ai pas remarqué de différence entre le 1er et le 2ème script car je les ai copiés directement d'ici. Je n'ai pas pensé que tu avais corrigé le 1er script.

Merci donc d'avoir fait des tests qui t'ont permis de constater et de corriger ce bug.

Bonne journée. Bonne santé et a+ peut-être.