Discussion :

[fredym]

Bonjour,

Je n'arrive pas à peupler la liste déroulante.
La liste que je voudrais afficher fait partie d'un tableau et la plage (colonne partielle) est nommée 'Liste'

Lorsque je clic sur la liste déroulante aucune liste s'affiche...
j'ai modifié les propriétés de la combobox:
- - AutoWordSelect > False
- - LinkedCell > G1 (cellule qui sert de référence pour afficher d’autres données)
- - ShowDropButtonWhen > 2

le code est le suivant:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
Private Sub ComboBox1_Change()
Me.ComboBox1.ListFillRange = "liste"
Me.ComboBox1.DropDown
End Sub

J'ai suivi plusieurs tutos à la lettre mais ce point précis ne fonctionne pas chez moi...
la ligne 2 et 3 devrait afficher la liste contenue dans le tableau!

Merci de votre aide.
Fredym

[Philippe Tulliez]

Bonjour,
La propriété ListFillRange d'un contrôle ActiveX ComboBox attend une chaîne de caractères reprenant le nom de la feuille suivi de l'adresse des cellules comme par exemple "Feuil1!A2:E10" donc si la référence est une plage nommée on utilisera la propriété Address avec l'argument External à True .
Exemple Feuil4.ComboBox1.ListFillRange = Range("t_test").Address(external:=True)

Attention que votre code publié sous-entend que vous avez placé le code dans le module de la feuille et que la référence à une plage nommée comme Range("Nom") n'est reconnue que si le nom est de portée feuille donc si le nom est de portée classeur, il y a lieu de placer le code de la procédure dans un module standard comme l'exemple ci-dessous

Code à placer dans un module standard

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
Sub LoadList()
  Feuil4.ComboBox1.ListFillRange = Range("t_test").Address(external:=True)
End Sub

Code dans la procédure événementielle où se trouve le contrôle ActiveX ComboBox

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
Private Sub Worksheet_Activate()
  LoadList
End Sub

[fredym]

Bj Monsieur Tulliez,

J'ai tenté de reproduire le code que vous me donner ci-dessous mais après maintes manipulations le résultat attendu n'y est pas...
Je voudrais, si vous me le permettez, vous soumettre le fichier excel afin de corriger mes erreurs commises...
Merci de votre aide...
Fredym

[Philippe Tulliez]

Bonjour,
Je vous confirme que cela fonctionne parfaitement. Voir ci-dessous une exemple plus complet avec les explications, le classeur joint ainsi qu'une illustration de celui-ci

Explication
Voici un exemple avec deux contrôles ActiveX nommés respectivement cboKeyList (ComboBox) et lstData (ListBox)
Lorsque l'on sélectionne une ligne dans l'un des deux contrôles, la cellule nommée pLinkedCell, en jaune dans l'illustration, reçoit le numéro de la ligne sélectionnée et ceci grâce à la propriété LinkedCell des deux contrôles et comme c'est la même adresse, cela permet de faire varier la sélection dans ceux-ci

Organisation
Le classeur contient :
Deux feuilles

• [Data] qui contient un tableau structuré nommé t_Data (à gauche dans l'illustration)
• [Démo ListBox] qui contient deux contrôles ActiveX, nommés respectivement cboKeyList (ComboBox) et lstData (ListBox) ainsi que les cellules contenant la formule =SIERREUR(@INDEX(t_Data;pLinkedCell + 1;EQUIV(B13;t_Data[#En-têtes];0));"") permettant d'afficher ce qui a été sélectionné dans l'une des deux listes et ce grâce à la valeur contenue dans la cellule nommée pLinkedCell
  Cette dernière est protégée mais sans mot de passe.

Deux références nommées

• lst_KeyName fait référence à t_Data[KeyName] (colonne nommée KeyName de la table structurée t_Data
• pLinkedCell fait référence 'Démo ListBox'!$C$3 (cellule C3 située dans la feuille nommée Démo ListBox
  

Procédure nommée 'LoadList' placée dans un module standard

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
Sub LoadList()
  ' Philippe Tulliez www.magicoffice.be
  Dim rngData As Range
  Dim RngKey As Range
  Set rngData = Range("t_Data")
  Set RngKey = Range("lst_KeyName")
  With ActiveSheet
    ' Charge les données référenceées par lst_keyName dans le ComboBox nommé cboKeyList
    With .cboKeyList
    .ListFillRange = RngKey.Address(external:=True)  ' Référencement de la liste à afficher
    .ColumnCount = RngKey.Columns.Count              ' Nombre de colonnes à afficher
    .LinkedCell = Range("pLinkedcell").Address       ' Référence la cellule liée
    .BoundColumn = 0                                 ' Renvoyer le n° de la ligne sélectionnée dans la cellule liée
    End With
    ' Charge les données dans le ListBox nommé lstData
    With .lstData
    .ListFillRange = rngData.Address(external:=True) ' Référencement de la liste à afficher
    .ColumnCount = rngData.Columns.Count             ' Nombre de colonnes à afficher
    .ColumnHeads = True                              ' Affiche la ligne des titres
    .LinkedCell = Range("pLinkedcell").Address       ' Référence la cellule liée
    .BoundColumn = 0                                 ' Renvoyer le n° de la ligne sélectionnée dans la cellule liée
    End With
  End With
End Sub

Procédure événementielle qui invoque la procédure 'LoadList', placée dans le module de la feuille [Démo ListBox]

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
Private Sub Worksheet_Activate()
  mMain.LoadList
End Sub

Illustration



[EDIT]
Lorsque j'ai fait le "print screen", je n'avais pas vu qu'il y avait un décalage d'une ligne entre celle qui est sélectionnée dans l'un des contrôles ListBox ou ComboBox et les valeurs renvoyées aux cellules C13:C21 par la formule qui s'y trouve.
La correction a été apportée avant la publication de mon intervention et donc le classeur à télécharger renvoie les bonnes valeurs

[fredym]

Un tout grand merci pour votre intervention.
J'apprécie votre aide précieuse.
Bonne journée.