Discussion :

[Léo Bicounet]

Bonjour,

je voudrais réaliser un tableau pour la création de devis avec des éléments d'une liste de fourniture.
Alors pour expliquer mon idée, je voudrais remplir la feuille SuiviChantier avec les lignes de la BaseFournitures qui aurait le la cellule "QUANTITE" différente de vide.

Je n'arrive pas à traiter la formule qui permet de vérifier la première ligne : si elle est remplie, copier l'intitulé et le prix dans le SuiviChantier ; si faux passer à la ligne suivante
jusqu'à que la première cellule de la première colonne soit vide.

Merci d'avance de votre aide.


Cf le fichier : Suivichantier V1.xlsx

[EricDgn]

Bonjour,

Une façon de faire pour récupérer les lignes où une quantité est mentionnée:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
Sub Fournitures()
    Dim wshFrn As Worksheet, loFrn As ListObject, rFiltr As Range, r As Range
    Dim wshChn As Worksheet, kR As Long
    Set wshFrn = ThisWorkbook.Worksheets("BaseFournitures")
    Set wshChn = ThisWorkbook.Worksheets("SuiviChantier")
    Set loFrn = wshFrn.ListObjects("BaseFrn")
    wshFrn.Select
    '--- filtre sur quantité > 0
    wshFrn.ListObjects("BaseFrn").Range.AutoFilter Field:=4, Criteria1:=">0", Operator:=xlAnd
    Set rFiltr = loFrn.DataBodyRange.SpecialCells(xlCellTypeVisible)
    '--- vérifications préalables
    If rFiltr Is Nothing Then
        MsgBox "Annulé: aucune quantité indiquée !", , "Annulé"
        Exit Sub        '--- EXIT ---
    End If
    If rFiltr.Rows.Count > 29 Then
        MsgBox "Annulé: la feuille SuiviChantier ne peut contenir que 29 fournitures" & vbLf & _
               "et vous en avez indiqué " & rFiltr.Rows.Count, , "Annulé"
        Exit Sub        '--- EXIT ---
    End If
    If MsgBox("Reprendre ces fournitures ?", vbYesNo, "Vérifier avant de copier !") = vbNo Then
        wshFrn.ListObjects("BaseFrn").Range.AutoFilter
        Exit Sub        '--- EXIT ---
    End If
    If wshChn.Range("G9") <> "" Then
        If MsgBox("Supprimer ce qui se trouve déjà dans SuiviChantier?", vbYesNo, "A confirmer") = vbNo Then
            Exit Sub    '--- EXIT ---
        End If
    End If
    '--- report quantités de BaseFournitures à SuiviChantier
    kR = 9
    With wshChn
        .Range("G9:J37").ClearContents  '--- G9:J37 = plage des fournitures
        'Debug.Print rFiltr.Address
        For Each r In rFiltr.Rows
            'Debug.Print r.Address
            .Range("G" & kR) = loFrn.Range(r.Row, 2)        '--- désignation
            .Range("H" & kR) = loFrn.Range(r.Row, 4)        '--- quantité
            .Range("I" & kR) = loFrn.Range(r.Row, 5)        '--- prix unité
            .Range("J" & kR).FormulaR1C1 = "=RC[-2]*RC[-1]" '--- formule calcul
            kR = kR + 1
        Next r
        .Range("J38").FormulaR1C1 = "=SUM(R[-29]C:R[-1]C)"  '--- formule calcul total
    End With
End Sub

Cela dit, vous pourriez regarder si ceci ne vous conviendrait pas mieux:
Apprendre comment composer un devis, analyser la rentabilité du chantier et présenter des statistiques avec Access.

Cordialement.

[Léo Bicounet]

Bonjour,

tout d'abords merci d'avoir pris le temps de m'aider.

vos formules sont très intéressantes, il y a juste la base que je ne décrypte pas bien.
Que signifie : le Wsh ? je ne trouve pas sur internet sa signification ? ainsi que :
rGroupe =
loFrn =
wshFrn =

pouvez-vous m’éclaircir sur ces points ?

Merci d'avance

[Philippe Tulliez]

Bonjour,
Ce que vous énumérez sont des variables.
Pour programmer, on utilise des variables dont le nom doit être le plus explicite possible afin de pouvoir se relire et chacun a sa façon de faire ainsi moi je suffixe les objets "feuille" (Worksheet) par sht et Eric, que je salue au passage, par wsh suivi ensuite par une autre abréviation si l'on utilise plusieurs objets de même type.

D'après votre demande et à la lecture de son code wshFrn représente sans doute la feuille "BaseFournitures" et wshChn la feuille "SuiviChantier"

Un peu de lecture éventuellement Utiliser les variables en VBA Excel

[Léo Bicounet]

Super explication, je vous en remercie également c'est effectivement plus claire pour moi.

encore merci à tous

[Léo Bicounet]

Je comprends le fonctionnement mais lorsque je veux appliquer votre variable à d'autre page j'ai un message d'erreur sur la même ligne :


Set loEmp = wshEmp.ListObjects("BaseEmpl") j'ai ici changé de feuille de Base mais l'erreur

l'indice n'appartient pas à la sélection

revient sur cette ligne.


J'ai pourtant bien renommé ma liste d'objet et le nom de mes variables.

Avez-vous déjà rencontré ce problème ?