Discussion :

[toutikini]

Bonjour à tous,

Je viens vers vous avec un pb qui m'ai insoluble à ce jour !!
J'essaie de créer un formulaire pour operateur qui rentre des pièces en stock.
il faut imaginer un pc avec cette userform lancé et l'utilisateur s'éloigne de ce dernier avec une douchette Bluetooth à la main. Il scanne dans un premier temps son badge (champs 1), si celui-ci est reconnu (suivant un listing) le champs suivant (2 = Etiquettetextbox) est sélectionné, il scan alors un code barre sur les pièces à rentrer en stock, si celui-ci est reconnu le champs suivant (3 = Chariottextbox) est sélectionné, il scan alors un code barre sur le chariot où il dépose les pièces et on recommence automatiquement la procédure mais à l'étape 2, le scan du badge étant déjà fait!!
l'utilisateur étant assez éloigné du pc, il ne lui est peu possible de valider un bouton à chaque fois … la scannette ne fait que de la saisi de texte, c'est comme si on tapais chaque lettre et que l'on termine par "Enter", sauf qu'elle le fait en 1 seconde !!

A ce jour, le Champs1 fonctionne, puis le Champs2, puis le Champs3, mais c'est aprés que cela se gate, car c'est le champs1 qui se retrouve de nouveau sélectionné et non pas le 2

Classeur1.xlsm

Merci encore pour votre aide

[EricDgn]

Bonjour,

Un début de solution ... à tester (je n'ai pas de douchette!):

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
Option Explicit
 
Dim BadgeName As String
Dim Ligne As Long
 
Private Sub UserForm_Initialize()
    Ligne = Cells(Rows.Count, 5).End(xlUp).Row          '--- n° de la dernière ligne en colonne 5 (E)
    Me.UserNameTextBox.SetFocus
End Sub
 
Private Sub UserForm_Terminate()
    BadgeName = ""
End Sub
 
Private Sub UserNameTextBox_Exit(ByVal Cancel As MSForms.ReturnBoolean)
    Dim BadgeNumber As Long, Rng As Range
    BadgeNumber = UserForm_Douchage.UserNameTextBox.Value
    'Recherche correspondance entre code scanné et Nom Prénom utilisateur du listing
    With Sheets("Datas").Range("B1:B21")
        Set Rng = .Find(What:=BadgeNumber, _
                After:=.Cells(.Cells.Count), _
                LookIn:=xlValues, _
                LookAt:=xlWhole, _
                SearchOrder:=xlByRows, _
                SearchDirection:=xlNext, _
                MatchCase:=False)
    End With
    'Utilisation Résultat de la recherche
    If Not Rng Is Nothing Then
        BadgeName = Sheets("Datas").Cells(Rng.Row, 1).Value
        UserForm_Douchage.UserNameTextBox.Value = BadgeName
        UserForm_Douchage.InfoLabel.Caption = "Bonjour M. " & BadgeName & Chr(10) & Chr(10) & "Merci de Scanner une TO !!"
    Else
        UserForm_Douchage.UserNameTextBox.Value = ""
        UserForm_Douchage.InfoLabel.Caption = "Utilisateur Inconnu !!"
        Cancel = True
    End If
End Sub
 
Private Sub ChariotTextBox_Exit(ByVal Cancel As MSForms.ReturnBoolean)
    If UserForm_Douchage.EtiquetteTextBox.Value = "" Then
        '--- passe --- mais permet d'activer EtiquetteTextBox --- motif inconnu
    Else
        '--- à ajouter: tests valeurs admises ?
        '--- clic 2 fois sur même article ou sur même chariot ?
        Ligne = Ligne + 1
        Sheets("Datas").Cells(Ligne, 5).Value = BadgeName
        Sheets("Datas").Cells(Ligne, 6).Value = UserForm_Douchage.EtiquetteTextBox.Value
        Sheets("Datas").Cells(Ligne, 7).Value = UserForm_Douchage.ChariotTextBox.Value
        Beep
        UserForm_Douchage.EtiquetteTextBox.Value = ""
        UserForm_Douchage.ChariotTextBox.Value = ""
        UserForm_Douchage.EtiquetteTextBox.SetFocus   '--- donne le focus mais sans l'activer ?!
    End If
End Sub

Cordialement.
(reste plus qu'à utiliser des tableaux structurés plutôt que des tableaux simples)

[toutikini]

Merci pour ton efficacité, cela fonctionne à merveille !!