Discussion :

[Denis_67]

Bonjour,

J'ai un petit problème de syntaxe.

Dans un userform je charge un range pour créer ma colonne de titre d'un listview.

Cela fonctionne quand je déclenche le userform depuis la feuille concernée
mais pas lorsque je l'appelle depuis une autre feuille
J'ai aussi essayé de désigner la ligne de titre du tableau, mais cela ne fonctionne pas non plus.
Je soupçonna que ma variable tblDB devrait etre plus proprement déclarée, mais j'ai essayé plusieurs type et ça ne fonctionne carrément plus.
de plus l'erreur est de type 1004 donc il de reconnait pas le range que je veux charger dans tblDB.

Alors que si j'utilise la selection range en dur cela fonctionne, mais comme le nombre de colonne peux varier, cela ne me convient pas.

MErci pour vos conseils

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
Me.ListView1.ListItems.Clear
With ListView1
        'Définit le nombre de colonnes et Entêtes
        With .ColumnHeaders
            'Supprime les anciens entêtes
            .Clear
            'Ajoute 2 colonnes en spécifiant le nom de l'entête
            'et la largeur des colonnes
            .Add , , "Titre ", 100
            .Add , , "Texte", 500
        End With
.Gridlines = True

Dim tblBD

With ThisWorkbook.Sheets("FNC")

' ne marche pas
'tblBD = ActiveSheet.ListObjects("Tableau1").HeaderRowRange '<== j'avais omis d'enlever Activesheet depuiis ca marche  (corrigé après avoir posté)
' ne marche pas
'tblBD = .Cells(Cells(1, 1), Cells(1, Colo))  'Colo = variable '<==nb de colonnes la syntaxe c'est .Range.(cells (a,b),cells(c,d)) mais ça ne fonctionne pas quand  c'est appelé depuis une autre feuille (corrigé après avoir posté)
' Fonctionne
 tblBD = .Range("A1:BE1")
 
End With
 
 Dim ligne
    ligne = 0
       For i = 1 To UBound(tblBD, 2)
         ligne = ligne + 1
        .ListItems.Add , , tblBD(1, i)
        .ListItems(ligne).ListSubItems.Add , , ThisWorkbook.Sheets("FNC").Cells(Maligne, i)   'tblBD(2, i)
        If .ListItems(ligne).Text = "N°_Avis" Then
        .ListItems(ligne).ListSubItems(1).ForeColor = vbRed
        End If
      Next i
   
End With
    ListView1.View = lvwReport

Merci
Denis

[Philippe Tulliez]

Bonjour,

Cela fonctionne quand je déclenche le userform depuis la feuille concernée
mais pas lorsque je l'appelle depuis une autre feuille

Eternel problème maintes fois expliqués.
Il suffit simplement de définir la parentalité totale de l'objet Range, c'est à dire sa feuille et son classeur

Voir mon billet sur le sujet titré Excel VBA - La parentalité d’un objet

[Denis_67]

Bonjour Philippe,

Sauf que je suis dans une séquence with qui défini mes parents !

En fait à force de faire des essais je m'étais mélangé les pinceaux

La syntaxe qui fonctionne

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
Dim tblBD
With ThisWorkbook.Sheets("FNC")
tblBD = .ListObjects("Tableau1").HeaderRowRange
End With

Par contre je ne comprends toujours pas pourquoi celle ci ne fonctionne pas

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
Dim tblBD
With ThisWorkbook.Sheets("FNC")
tblBD = .Range(Cells(1, 1), Cells(1, Colo))  'colo variable nb colonnes
Eend With

Merci
Denis

[Patrice740]

Par contre je ne comprends toujours pas pourquoi celle ci ne fonctionne pas

Nos posts se sont croisés, regardes mon post précédent (la parentalité !).

[Denis_67]

Merci Patrice,

J'avais oublié un petit point !!!

Maintenant toute les syntaxes fonctionnent !

Justement j'avais fait une F1 sur Worksheets et Sheets suite au message de Philippe mais n'avais pas bien saisi la nuance. Maintenant je vais utiliser worksheets.

L'aide MS dit pour Sheets

Workbook.Sheets, propriété (Excel)
29/05/2019
2 minutes de lecture

Renvoie une collection Sheets qui représente toutes les feuilles du classeur spécifié. Objet Sheets en lecture seule..

Et pour Worksheets

Propriété Workbook.Worksheets (Excel)
29/05/2019
2 minutes de lecture

Renvoie une collection Sheets qui représente toutes les feuilles de calcul du classeur spécifié. Objet Sheets en lecture seule.

Encore merci pour votre patience !
Denis

[Patrice740]

L'aide MS ...
Et pour Worksheets

Propriété Workbook.Worksheets (Excel)
29/05/2019
2 minutes de lecture

Renvoie une collection Sheets qui représente toutes les feuilles de calcul du classeur spécifié. Objet Sheets en lecture seule.

On n'a pas le même Aide MS ???

Objet Worksheets (Excel)
03/04/2019
2 minutes de lecture

Collection de tous les objets Worksheet dans le classeur spécifié ou actif. Chaque objet Worksheet représente un classeur.

Objet Worksheets (Excel) | Microsoft Docs

Sur la page d'aide suivante, il y a une erreur de la part de MS !!!!

Propriété Workbook.Worksheets (Excel) | Microsoft Docs
Il faut lire :

Propriété Workbook.Worksheets (Excel)
29/05/2019
2 minutes de lecture

Renvoie une collection Worksheets qui représente toutes les feuilles de calcul du classeur spécifié. Objet Worksheets en lecture seule.

[Patrice740]

Bonjour le Fil,
Bonjour Philippe,

Ah, la parentalité oui mais ...
... encore faut-t'il se servir correctement du With !!!

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
Sub xxx()
Dim tblBD
' With ThisWorkbook.Sheets("FNC")
  With ThisWorkbook.Worksheets("FNC")
    'tblBD = ActiveSheet.ListObjects("Tableau1").HeaderRowRange
     tblBD = .ListObjects("Tableau1").HeaderRowRange
 
    'tblBD = .Cells(Cells(1, 1), Cells(1, Colo))    'Colo = variable nb de colonnes
     tblBD = .Range(.Cells(1, 1), .Cells(1, Colo))  'Colo = variable nb de colonnes
 
     tblBD = .Range("A1:BE1")
  End With
End Sub

Note : Sheets(xxx).Range() est une mauvaise syntaxe (trop souvent employée).
L'objet Sheets(xxx) hérite d'objets Range() seulement dans la cas où il représente une feuille de calcul.
La syntaxe correcte est Worksheets(xxx).Range(), i.e. 4 caractères supplémentaire pour un code plus propre.